Excel'de sayıları İngilizce kelimelere nasıl yazabilir veya dönüştürebilirim?

Excel'de sayıları İngilizce kelime karşılıklarına dönüştürmek, özellikle finansal raporlama, faturalandırma veya çek düzenleme için değerli bir beceri olabilir. Excel'in bu amaç için yerleşik bir işlevi olmasa da, bunu başarmak için birkaç yöntem bulunmaktadır. Bu makale, size Excel'de sayıları kelimelere dönüştürmenin en etkili yollarını gösterecek ve ayrıca optimizasyon ipuçları sunacaktır.

VBA kodu ile sayıları İngilizce kelimelere yazın veya dönüştürün

Kutools for Excel ile sayıları İngilizce kelimelere yazın veya dönüştürün

VBA kodu ile sayıları İngilizce kelimelere yazın veya dönüştürün

Aşağıdaki uzun VBA kodu, sayıları metin dizilerine dönüştürmenize yardımcı olabilir. Aşağıdakileri yapın:

1. "ALT + F11" tuşlarını basılı tutun ve bu işlem "Microsoft Visual Basic for Applications" penceresini açar.

2. "Ekle" > "Modül" seçeneğine tıklayın ve aşağıdaki makroyu Modül penceresine yapıştırın.

VBA: Excel'de para birimi sayılarını İngilizce kelimelere dönüştürme

Function SpellNumberToEnglish(ByVal pNumber)
'Updateby20131113
Dim Dollars, Cents
arr = Array("", "", " Thousand ", " Million ", " Billion ", " Trillion ")
pNumber = Trim(Str(pNumber))
xDecimal = InStr(pNumber, ".")
If xDecimal > 0 Then
    Cents = GetTens(Left(Mid(pNumber, xDecimal + 1) & "00", 2))
    pNumber = Trim(Left(pNumber, xDecimal - 1))
End If
xIndex = 1
Do While pNumber <> ""
    xHundred = ""
    xValue = Right(pNumber, 3)
    If Val(xValue) <> 0 Then
        xValue = Right("000" & xValue, 3)
        If Mid(xValue, 1, 1) <> "0" Then
            xHundred = GetDigit(Mid(xValue, 1, 1)) & " Hundred "
        End If
        If Mid(xValue, 2, 1) <> "0" Then
            xHundred = xHundred & GetTens(Mid(xValue, 2))
        Else
            xHundred = xHundred & GetDigit(Mid(xValue, 3))
        End If
    End If
    If xHundred <> "" Then
        Dollars = xHundred & arr(xIndex) & Dollars
    End If
    If Len(pNumber) > 3 Then
        pNumber = Left(pNumber, Len(pNumber) - 3)
    Else
        pNumber = ""
    End If
    xIndex = xIndex + 1
Loop
Select Case Dollars
    Case ""
        Dollars = "No Dollars"
    Case "One"
        Dollars = "One Dollar"
    Case Else
        Dollars = Dollars & " Dollars"
End Select
Select Case Cents
    Case ""
        Cents = " and No Cents"
    Case "One"
        Cents = " and One Cent"
    Case Else
        Cents = " and " & Cents & " Cents"
End Select
SpellNumberToEnglish = Dollars & Cents
End Function
Function GetTens(pTens)
Dim Result As String
Result = ""
If Val(Left(pTens, 1)) = 1 Then
    Select Case Val(pTens)
        Case 10: Result = "Ten"
        Case 11: Result = "Eleven"
        Case 12: Result = "Twelve"
        Case 13: Result = "Thirteen"
        Case 14: Result = "Fourteen"
        Case 15: Result = "Fifteen"
        Case 16: Result = "Sixteen"
        Case 17: Result = "Seventeen"
        Case 18: Result = "Eighteen"
        Case 19: Result = "Nineteen"
        Case Else
    End Select
Else
Select Case Val(Left(pTens, 1))
    Case 2: Result = "Twenty "
    Case 3: Result = "Thirty "
    Case 4: Result = "Forty "
    Case 5: Result = "Fifty "
    Case 6: Result = "Sixty "
    Case 7: Result = "Seventy "
    Case 8: Result = "Eighty "
    Case 9: Result = "Ninety "
    Case Else
End Select
Result = Result & GetDigit(Right(pTens, 1))
End If
GetTens = Result
End Function
Function GetDigit(pDigit)
Select Case Val(pDigit)
    Case 1: GetDigit = "One"
    Case 2: GetDigit = "Two"
    Case 3: GetDigit = "Three"
    Case 4: GetDigit = "Four"
    Case 5: GetDigit = "Five"
    Case 6: GetDigit = "Six"
    Case 7: GetDigit = "Seven"
    Case 8: GetDigit = "Eight"
    Case 9: GetDigit = "Nine"
    Case Else: GetDigit = ""
End Select
End Function

3. Ardından kodu kaydedin ve çalışma sayfasına geri dönün, bitişik Hücre B2'ye şu formülü girin: =SpellNumberToEnglish(A2), ekran görüntüsüne bakın:

4. Enter tuşuna basın ve C2 hücresini seçin, ardından doldurma tutamacını formülün bulunduğu aralığa sürükleyin. Ve tüm para birimi sayıları İngilizce kelimelere dönüştürülmüş olacaktır. Ekran görüntüsüne bakın:

Kutools for Excel ile sayıları İngilizce kelimelere yazın veya dönüştürün

Excel görevlerinizi kolaylaştırarak üretkenliği artırın ve Kutools for Excel'i kullanın. Güçlü Sayıdan Kelimeye özelliğimiz, 40'tan fazla para birimi dönüştürme seçeneği sunarak, sadece birkaç tıklamayla Amerikan Doları, Çin YUAN veya başka herhangi bir para birimindeki sayıları kelimelere dönüştürmenizi sağlar.

1. Yazmak istediğiniz sayıların bulunduğu aralığı seçin ve "Kutools" > "Metin" > "Sayıdan Kelimeye" seçeneğine tıklayın.

2. Açılan diyalog kutusunda "Diller" bölümünden "İngilizce" seçeneğini seçin. Sağdaki "Önizleme" panelinden sonuçları önizleyebilirsiniz. Ekran görüntüsüne bakın:

3. Ardından Tamam'a veya Uygula'ya tıklayın. Ve tüm fiyat miktarları orijinal aralıkta metin dizilerine dönüştürülmüş olacaktır.

Not: Eğer sadece sayıları İngilizce kelimelere (para birimi değil) dönüştürmek istiyorsanız, lütfen Para birimine dönüştürme seçeneğinin işaretini kaldırın.

Bu kılavuzda belirtilen adımları ve optimizasyonları izleyerek, sayıları kelimelere dönüştürmeyi verimli bir şekilde gerçekleştirebilir ve iş akışınızı hızlandırabilirsiniz. Finansal raporlar hazırlıyor veya faturalar oluşturuyor olsanız da, bu beceriyi öğrenmek zaman ve çaba kazandıracaktır. Daha fazla Excel ipucu ve hilesi keşfetmeye ilgi duyuyorsanız, web sitemiz binlerce öğretici sunmaktadır.