Excel'de tüm olası permütasyonlar nasıl oluşturulur veya listelenir?

Örneğin, üç karakterim var XYZ, şimdi, şu şekilde altı farklı sonuç elde etmek için bu üç karaktere dayalı tüm olası permütasyonları listelemek istiyorum: XYZ, XZY, YXZ, YZX, ZXY ve ZYX. Excel'de, tüm permütasyonları farklı karakter sayılarına göre nasıl hızlı bir şekilde oluşturabilir veya listeleyebilirsiniz?

VBA kodlu karakterlere göre tüm olası permütasyonları oluşturun veya listeleyin

VBA kodlu karakterlere göre tüm olası permütasyonları oluşturun veya listeleyin

Aşağıdaki VBA kodu, tüm permütasyonları belirli harf sayınıza göre listelemenize yardımcı olabilir, lütfen aşağıdaki işlemleri yapın:

1. Basılı tutun ALT + F11 tuşlarını açmak için Uygulamalar için Microsoft Visual Basic pencere.

2. tıklayın Ekle > modülve aşağıdaki kodu modül Pencere.

VBA kodu: Excel'deki tüm olası permütasyonları listeleyin

Sub GetString()
'Updateby Extendoffice
    Dim xStr As String
    Dim FRow As Long
    Dim xScreen As Boolean
    xScreen = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xStr = Application.InputBox("Enter text to permute:", "Kutools for Excel", , , , , , 2)
    If Len(xStr) < 2 Then Exit Sub
    If Len(xStr) >= 8 Then
        MsgBox "Too many permutations!", vbInformation, "Kutools for Excel"
        Exit Sub
    Else
        ActiveSheet.Columns(1).Clear
        FRow = 1
        Call GetPermutation("", xStr, FRow)
    End If
    Application.ScreenUpdating = xScreen
End Sub
Sub GetPermutation(Str1 As String, Str2 As String, ByRef xRow As Long)
    Dim i As Integer, xLen As Integer
    xLen = Len(Str2)
    If xLen < 2 Then
        Range("A" & xRow) = Str1 & Str2
        xRow = xRow + 1
    Else
        For i = 1 To xLen
            Call GetPermutation(Str1 + Mid(Str2, i, 1), Left(Str2, i - 1) + Right(Str2, xLen - i), xRow)
        Next
    End If
End Sub

3. Daha sonra tuşuna basın. F5 Bu kodu çalıştırmak için tuşuna basın ve tüm permütasyonları listelemek istediğiniz karakterleri girmenizi hatırlatmak için bir istem kutusu açılır, ekran görüntüsüne bakın:

4. Karakterleri girdikten sonra ve ardından OK düğmesi, tüm olası permütasyonlar, etkin çalışma sayfasının A sütununda görüntülenir. Ekran görüntüsüne bakın:

not: Girilen karakter uzunluğu 8 karaktere eşit veya daha büyükse, çok fazla permütasyon olduğundan bu kod çalışmayacaktır.