Bir hücre içindeki belirli metni, diğer metne göre nasıl vurgularsınız?

Excel'de, belirli bir metne dayalı olarak hücreleri vurgulamak kolay olabilir. Ancak burada, tüm hücreyi değil sadece hücre içindeki belirli bir metni vurgulamak istiyorum ki bu da dikkat çekici olsun. Bu, çoğu bizim için sorunlu olabilir. Bu makalede, Excel'de bu görevi çözmek için bazı ipuçlarından bahsedeceğim.

Birden fazla hücredeki bir veya daha fazla belirli metni VBA kodu ile vurgulama

Harika bir özellik ile birden fazla hücredeki bir veya daha fazla belirli metni vurgulama

Diğer metne göre bir hücre içindeki belirli metni VBA kodu ile vurgulama

Birden fazla hücredeki bir veya daha fazla belirli metni VBA kodu ile vurgulama

Örneğin, bir dizi metin dizgisi var ve şimdi bu hücrelerde “Sky” adlı belirli metni vurgulamak istiyorum, aşağıdaki ekran görüntülerinde gösterildiği gibi bir sonuç elde etmek için:

Bir hücre içindeki metnin yalnızca bir kısmını vurgulamak için aşağıdaki VBA kodu size yardımcı olabilir.

1. Vurgulamak istediğiniz belirli metin içeren hücreleri seçin ve ardından ALT + F11 tuşlarına basılı tutarak Microsoft Visual Basic for Applications penceresini açın.

2. Ekle > Modül'e tıklayın ve aşağıdaki kodu Modül Penceresine yapıştırın.

VBA Kodu: Bir hücre içindeki metnin bir kısmını vurgulama:

Sub HighlightStrings()
'Updateby Extendoffice
Application.ScreenUpdating = False
Dim Rng As Range
Dim cFnd As String
Dim xTmp As String
Dim x As Long
Dim m As Long
Dim y As Long
cFnd = InputBox("Enter the text string to highlight")
y = Len(cFnd)
For Each Rng In Selection
  With Rng
    m = UBound(Split(Rng.Value, cFnd))
    If m > 0 Then
      xTmp = ""
      For x = 0 To m - 1
        xTmp = xTmp & Split(Rng.Value, cFnd)(x)
        .Characters(Start:=Len(xTmp) + 1, Length:=y).Font.ColorIndex = 3
        xTmp = xTmp & cFnd
      Next
    End If
  End With
Next Rng
Application.ScreenUpdating = True
End Sub

3. Ardından bu kodu çalıştırmak için F5 tuşuna basın ve yalnızca vurgulamak istediğiniz metni girmenizi hatırlatan bir uyarı kutusu açılacaktır, aşağıdaki ekran görüntüsüne bakın:

4. Ve sonra Tamam butonuna tıklayın, belirttiğiniz tüm metinler yalnızca hücreler içinde vurgulanmış olacaktır, aşağıdaki ekran görüntüsüne bakın:

İpuçları: Metin dizelerinden birden fazla anahtar kelimeyi vurgulamanız gerekiyorsa lütfen aşağıdaki kodu uygulayın:
VBA Kodu: Metin dizelerinden birden fazla anahtar kelimeyi vurgulama:

Sub HighlightStrings()
'Updateby Extendoffice
Application.ScreenUpdating = False
Dim Rng As Range
Dim cFnd As String
Dim xTmp As String
Dim x As Long
Dim m As Long
Dim y As Long
Dim xFNum As Integer
Dim xArrFnd As Variant
Dim xStr As String
cFnd = InputBox("Please enter the text, separate them by comma:")
If Len(cFnd) < 1 Then Exit Sub
xArrFnd = Split(cFnd, ",")
For Each Rng In Selection
With Rng
For xFNum = 0 To UBound(xArrFnd)
xStr = xArrFnd(xFNum)
y = Len(xStr)
m = UBound(Split(Rng.Value, xStr))
If m > 0 Then
xTmp = ""
For x = 0 To m - 1
xTmp = xTmp & Split(Rng.Value, xStr)(x)
.Characters(Start:=Len(xTmp) + 1, Length:=y).Font.ColorIndex = 3
xTmp = xTmp & xStr
Next
End If
Next xFNum
End With
Next Rng
Application.ScreenUpdating = True
End Sub

Ardından, açılan kutuda, vurgulamak istediğiniz anahtar kelimeleri girin (kelimeleri virgülle ayırın), aşağıdaki ekran görüntüsüne bakın:

Ve sonra, Tamam butonuna tıklayın, belirtilen kelimeler hemen vurgulanmış olacaktır, aşağıdaki ekran görüntülerine bakın:

Not: Yukarıdaki kodlar büyük/küçük harf duyarlıdır.

Harika bir özellik ile birden fazla hücredeki bir veya daha fazla belirli metni vurgulama

Excel'deki kodlarla ilgili deneyiminiz yoksa, burada size kolay bir araç tanıtacağım - Kutools for Excel, Mark Keyword özelliğini kullanarak hücreler içindeki belirli bir veya daha fazla anahtar kelimeyi hemen vurgulayabilirsiniz.

Kutools for Excel'i yükledikten sonra lütfen şu adımları izleyin:

1. Kutools > Metin > Mark Keyword'a tıklayın, aşağıdaki ekran görüntüsüne bakın:

2. Mark Keyword iletişim kutusunda, lütfen aşağıdaki işlemleri yapın:

• Kullanmak istediğiniz veri aralığını Aralık metin kutusundan seçin;
• Vurgulamak istediğiniz anahtar kelimeleri içeren hücreleri seçin, ayrıca anahtar kelimeleri manuel olarak (virgülle ayırarak) Anahtar Kelime metin kutusuna girebilirsiniz.
• Son olarak, Mark keyword colors seçeneğini işaretleyerek metinleri vurgulamak için bir yazı tipi rengi belirtmelisiniz. (Anahtar kelimeleri içeren tüm hücreleri renklendirmek için, Mark the cell content colors seçeneğini seçin)

3. Ardından, Tamam butonuna tıklayın, tüm belirtilen metinler aşağıdaki ekran görüntüsünde gösterildiği gibi vurgulanacaktır:

Not: Bu özellik büyük/küçük harf duyarlı değildir, eğer metni büyük/küçük harf duyarlı olarak vurgulamak istiyorsanız, lütfen Mark Keyword iletişim kutusunda Match Case'i işaretleyin.

Diğer metne göre bir hücre içindeki belirli metni VBA kodu ile vurgulama

Başka bir durum şu ki, ilk sütunda metin dizeleri olan iki sütunum var ve ikinci sütun ise belirli bir metin. Şimdi, her satır için ikinci sütundaki belirli metne göre ilk sütundaki ilgili metni vurgulamam gerekiyor.

1. ALT + F11 tuşlarına basılı tutarak Microsoft Visual Basic for Applications penceresini açın.

2. Ekle Insert > Modül'e tıklayın ve aşağıdaki kodu Modül Penceresine yapıştırın.

VBA Kodu: Diğer metne göre bir hücre içindeki metnin bir kısmını vurgulama:

Sub highlight()
'Updateby Extendoffice
    Dim xStr As String
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    Dim xChar As String
    Dim I As Long
    Dim J As Long
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
LInput:
    Set xRg = Application.InputBox("please select the data range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    If xRg.Areas.Count > 1 Then
        MsgBox "not support multiple columns"
        GoTo LInput
    End If
    If xRg.Columns.Count <> 2 Then
        MsgBox "the selected range can only contain two columns "
        GoTo LInput
    End If
    For I = 0 To xRg.Rows.Count - 1
        xStr = xRg.Range("B1").Offset(I, 0).Value
        With xRg.Range("A1").Offset(I, 0)
            .Font.ColorIndex = 1
            For J = 1 To Len(.Text)
                If Mid(.Text, J, Len(xStr)) = xStr Then .Characters(J, Len(xStr)).Font.ColorIndex = 3
            Next
        End With
    Next I
End Sub

3. Kodu yapıştırdıktan sonra, F5 tuşuna basarak çalıştırın, bir uyarı kutusu açılacak ve hem metin dizisini hem de vurgulamak ve temel almak istediğiniz belirli metni içeren veri aralığını seçmenizi hatırlatacaktır, aşağıdaki ekran görüntüsüne bakın:

4. Ve sonra Tamam butonuna tıklayın, ikinci sütundaki belirli metne göre ilk sütundaki tüm ilgili metinler aşağıdaki ekran görüntüsünde olduğu gibi kırmızıya boyanacaktır:

Daha fazla ilgili makale: