Çalışma kitabını paylaşmadan değişiklikleri nasıl takip edebilirim?

Normalde, Excel'de Değişiklikleri İzle özelliğini kullandığınızda, çalışma kitabı aynı anda paylaşılacaktır. Bu durum, Excel'deki bazı özelliklerin devre dışı kalacağı için can sıkıcı olacaktır. Çalışma kitabını paylaşmadan değişiklikleri nasıl izleyebilirsiniz? Burada size bir VBA kodu önereceğim.

VBA kodu ile çalışma kitabını paylaşmadan değişiklikleri izleme

Outlook'ta metni tabloya dönüştürme

Bu sorunu çözmek için doğrudan bir yol bulunmamakla birlikte, esnek bir VBA kodu kullanabilirsiniz. Lütfen şu adımları izleyin:

1. Değişiklik yapılan hücreleri izlemek istediğiniz sayfa sekmesine sağ tıklayın ve açılan menüden Görünüm Kodu seçeneğini belirleyin. Açılan Microsoft Visual Basic for Applications penceresinde, aşağıdaki kodu boş Modül'e kopyalayıp yapıştırın:

VBA kodu: Çalışma kitabını paylaşmadan değişiklikleri izleme:

Private Sub Worksheet_Change(ByVal Target As Range)
  'Updateby Extendoffice
    Const xRg As String = "A1:Z1000"
    Dim strOld As String
    Dim strNew As String
    Dim strCmt As String
    Dim xLen As Long
    With Target(1)
        If Intersect(.Cells, Range(xRg)) Is Nothing Then Exit Sub
        strNew = .Text
        Application.EnableEvents = False
        Application.Undo
        strOld = .Text
        .Value = strNew
        Application.EnableEvents = True
        strCmt = "Edit: " & Format$(Now, "dd Mmm YYYY hh:nn:ss") & " by " & _
        Application.UserName & Chr(10) & "Previous Text :- " & strOld
        If Target(1).Comment Is Nothing Then
            .AddComment
        Else
            xLen = Len(.Comment.Shape.TextFrame.Characters.Text)
        End If
        With .Comment.Shape.TextFrame
            .AutoSize = True
            .Characters(Start:=xLen + 1).Insert IIf(xLen, vbLf, "") & strCmt
        End With
    End With
End Sub

Not: Yukarıdaki kodda, A1:Z1000, değişiklikleri izlemek istediğiniz veri aralığıdır.

2. Ardından bu kod penceresini kaydedip kapatın. Şimdi, belirtilen aralıktaki herhangi bir hücredeki değerleri değiştirdiğinizde, çalışma kitabını paylaşmadan değişiklikler izlenecektir. Ekran görüntüsüne bakın: