Excel'de arka plan rengine göre satırları nasıl silersiniz?

Hücreler mavi arka plan rengiyle dolu olan tüm satırları, aşağıdaki ekran görüntüsünde gösterildiği gibi nasıl silebilirsiniz? Bu makalede, Excel'de bu görevi gerçekleştirmek için bazı kodlar bulacaksınız.

Her hücreye göre belirli bir arka plan rengine sahip satırları silme

Bir sütuna göre belirli bir arka plan rengine sahip satırları silme

Her hücreye göre belirli bir arka plan rengine sahip satırları silme

Rastgele bazı hücre renkleriyle doldurulmuş bir veri aralığınız varsa ve aşağıdaki ekran görüntüsünde gösterildiği gibi hücre rengi mavi olan satırları silmeniz gerekiyorsa:

Bu tür satırları silmek için aşağıdaki VBA kodunu kullanabilirsiniz, lütfen şu adımları izleyin:

1. Microsoft Visual Basic for Applications penceresini açmak için ALT + F11 tuşlarına basın.

2. Ekle Insert > Modül'e tıklayın ve aşağıdaki kodu Modül Penceresine yapıştırın.

VBA kodu: Belirli bir dolgu rengine sahip hücreleri içeren satırları silme:

Sub DeleteRows()
'Updateby Extendoffice
    Dim rngCl As Range
    Dim xRows As Long
    Dim xCol As Long
    Dim colorLg As Long
    On Error Resume Next
    Set rngCl = Application.InputBox _
        (Prompt:="Select a cell with the background color to be deleted", _
        Title:="Kutools for Excel", Type:=8)
    On Error GoTo 0
    If rngCl Is Nothing Then
        MsgBox "User cancelled operation." & vbCrLf & _
        "Processing terminated", vbInformation, "Kutools for Excel"
        Exit Sub
    End If
    colorLg = rngCl.Interior.Color
    Application.ScreenUpdating = False
    With ActiveSheet.UsedRange
        For xRows = .Rows.Count To 1 Step -1
            For xCol = 1 To .Columns.Count
                           If .Cells(xRows, xCol).Interior.Color = colorLg Then
                    .Rows(xRows).Delete
                    Exit For
                End If
            Next xCol
        Next xRows
    End With
    Application.ScreenUpdating = True
End Sub

3. Ardından bu kodu çalıştırmak için F5 tuşuna basın ve seçmek istediğiniz dolgu rengine sahip bir hücreyi seçmenizi hatırlatan bir uyarı kutusu açılacaktır, aşağıdaki ekran görüntüsüne bakın:

4. Sonra Tamam'a tıklayın ve belirli bir dolgu rengine sahip hücreler varsa tüm satırlar silinir.

Bir sütuna göre belirli bir arka plan rengine sahip satırları silme

Örneğin, yalnızca bir sütuna göre belirli bir renge sahip satırları silmek istiyorsanız, A sütunundaki mavi renkli satırları silin ve aşağıdaki ekran görüntüsünü elde edin, işinize yarayacak bir VBA kodu da bulunmaktadır.

1. Microsoft Visual Basic for Applications penceresini açmak için ALT + F11 tuşlarına basın.

2. Ekle Insert > Modül'e tıklayın ve aşağıdaki kodu Modül Penceresine yapıştırın.

VBA kodu: Belirli bir dolgu rengine sahip hücrelere göre satırları silme:

Sub deleterow()
'UpdateBY Extendoffice
   Dim xRg As Range, rgDel As Range
    For Each xRg In ThisWorkbook.ActiveSheet.Range("A2:A21")
        If xRg.Interior.ColorIndex = 20 Then
            If rgDel Is Nothing Then
                Set rgDel = xRg
            Else
                Set rgDel = Union(rgDel, xRg)
            End If
        End If
    Next xRg
    If Not rgDel Is Nothing Then rgDel.EntireRow.Delete
End Sub

Not: Yukarıdaki kodda, A2:A21, satırları silmek istediğiniz belirli dolgu rengini içeren sütundur, ColorIndex = 20 komutundaki 20 sayısı ise satırları silmek istediğiniz renk endeksidir. Bunları ihtiyaçlarınıza göre değiştirebilirsiniz.

3. Ardından bu kodu çalıştırmak için F5 tuşuna basın ve A sütunundaki hücrelerde mavi renk bulunan tüm satırlar anında silinir.