Excel'deki bir hücre listesine göre bir klasördeki tüm resim dosyalarını yeniden adlandırmak nasıl yapılır?

Bir Excel sayfasındaki isim listesine göre bir klasördeki birden fazla resmi yeniden adlandırmak zorunda kaldınız mı? Onları tek tek yeniden adlandırmak zaman alıcı olabilir, ancak VBA kodlarının yardımıyla bu süreci hızlıca otomatikleştirebilirsiniz.

Bir klasördeki tüm resim dosyalarını yeniden adlandır

Bir klasördeki tüm resim dosyalarını yeniden adlandır

Belirli bir klasördeki tüm resim dosyalarını yeniden adlandırmak için şu adımları izleyin:

Adım 1: Klasörden orijinal dosya adlarını bir Excel sayfasına aktarın

1. "Alt + F11" tuşlarına basarak "Microsoft Visual Basic for Applications" penceresini açın.

2. "Ekle" > "Modül" seçeneğine tıklayın ve aşağıdaki kodu betiğe yapıştırın.

VBA: Bir Klasörden Resim Adlarını Al

Sub PictureNametoExcel()
'UpdatebyExtendoffice201709027
    Dim I As Long
    Dim xRg As Range
    Dim xAddress As String
    Dim xFileName As String
    Dim xFileDlg As FileDialog
    Dim xFileDlgItem As Variant
    On Error Resume Next
    xAddress = ActiveWindow.RangeSelection.Address
    Set xRg = Application.InputBox("Select a cell to place name list:", "KuTools For Excel", xAddress, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Application.ScreenUpdating = False
    Set xRg = xRg(1)
    xRg.Value = "Picture Name"
    With xRg.Font
    .Name = "Arial"
    .FontStyle = "Bold"
    .Size = 10
    End With
    xRg.EntireColumn.AutoFit
    Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)
    I = 1
    If xFileDlg.Show = -1 Then
        xFileDlgItem = xFileDlg.SelectedItems.Item(1)
        xFileName = Dir(xFileDlgItem & "\")
        Do While xFileName <> ""
            If InStr(1, xFileName, ".jpg") + InStr(1, xFileName, ".png") + InStr(1, xFileName, ".img") + InStr(1, xFileName, ".gif") + InStr(1, xFileName, ".ioc") + InStr(1, xFileName, ".bmp") > 0 Then
                xRg.Offset(I).Value = xFileDlgItem & "\" & xFileName
                I = I + 1
            End If
            xFileName = Dir
        Loop
    End If
    Application.ScreenUpdating = True
End Sub

3. Kodu çalıştırmak için "F5" tuşuna basın ve size ad listesini çıkarmak istediğiniz bir hücre seçmenizi hatırlatan bir iletişim kutusu açılacaktır. Ekran görüntüsüne bakın:

4. "Tamam"a tıklayın ve geçerli çalışma sayfasında listelemek istediğiniz resim adlarına sahip belirli klasörü seçin. Ekran görüntüsüne bakın:

5. "Tamam"a tıklayın. Resim adları etkin çalışma sayfasında listelenmiştir.

Adım 2: Yeni Bir İsim Listesi Temelinde Resim Dosyalarını Yeniden Adlandırın

1. "Alt + F11" tuşlarına basarak "Microsoft Visual Basic for Applications" penceresini açın.

2. "Ekle" > "Modül" seçeneğine tıklayın ve aşağıdaki kodu betiğe yapıştırın.

VBA: Bir Klasördeki Resim Dosyalarını Yeniden Adlandır

Sub RenameFile()
'UpdatebyExtendoffice20170927
    Dim I As Long
    Dim xLastRow As Long
    Dim xAddress As String
    Dim xRgS, xRgD As Range
    Dim xNumLeft, xNumRight As Long
    Dim xOldName, xNewName As String
    On Error Resume Next
    xAddress = ActiveWindow.RangeSelection.Address
    Set xRgS = Application.InputBox("Select Original Names(Single Column):", "KuTools For Excel", xAddress, , , , , 8)
    If xRgS Is Nothing Then Exit Sub
    Set xRgD = Application.InputBox("Select New Names(Single Column):", "KuTools For Excel", , , , , , 8)
    If xRgD Is Nothing Then Exit Sub
    Application.ScreenUpdating = False
    xLastRow = xRgS.Rows.Count
    Set xRgS = xRgS(1)
    Set xRgD = xRgD(1)
    For I = 1 To xLastRow
        xOldName = xRgS.Offset(I - 1).Value
        xNumLeft = InStrRev(xOldName, "\")
        xNumRight = InStrRev(xOldName, ".")
        xNewName = xRgD.Offset(I - 1).Value
        If xNewName <> "" Then
            xNewName = Left(xOldName, xNumLeft) & xNewName & Mid(xOldName, xNumRight)
            Name xOldName As xNewName
        End If
    Next
    MsgBox "Congratulations! You have successfully renamed all the files", vbInformation, "KuTools For Excel"
    Application.ScreenUpdating = True
End Sub

3. Kodu çalıştırmak için "F5" tuşuna basın ve değiştirmek istediğiniz orijinal resim adlarını seçmenizi hatırlatan bir iletişim kutusu açılacaktır. Ekran görüntüsüne bakın:

4. "Tamam"a tıklayın ve ikinci iletişim kutusunda değiştirmek istediğiniz yeni isimleri seçin. Ekran görüntüsüne bakın:

5. "Tamam"a tıklayın, resim adlarının başarıyla değiştirildiğini size hatırlatan bir iletişim kutusu açılacaktır.

6. "Tamam"a tıklayın ve klasördeki resim adları sayfadaki hücrelerdeki yeni isimlerle değiştirilecektir.

İlgili Makaleler:

• Excel'deki hücre değerlerine göre çalışma sayfalarını nasıl yeniden adlandırabilirsiniz?