Excel'de İç İçe IF İfadelerinde Ustalaşın – Adım Adım Rehber

Excel'de, IF fonksiyonu temel mantıksal testler için vazgeçilmez olsa da, karmaşık koşullar genellikle daha gelişmiş veri işleme için iç içe IF ifadeleri gerektirir. Bu kapsamlı rehberde, iç içe IF'in temellerini, sözdiziminden pratik uygulamalara kadar ayrıntılı olarak ele alacağız; ayrıca iç içe IF'in AND/OR koşullarıyla nasıl birleştirilebileceğini de göstereceğiz. Ek olarak, iç içe IF fonksiyonlarının okunabilirliğini artırma yollarını ve bazı ipuçlarını paylaşacak, VLOOKUP, IFS gibi güçlü alternatifleri keşfederek karmaşık mantıksal işlemleri daha kolay ve verimli hale getireceğiz.

• İç içe IF'in sözdizimi
• İç içe IF'in pratik örnekleri
• AND / OR koşulu ile iç içe if

• İç içe IF'i okunabilir hale getirme
• İç içe IF fonksiyonlarının sıralaması
• Sayılar ve metinler farklı şekilde ele alınmalıdır
• İç içe IF'in sınırlamaları

• VLOOKUP Kullanımı
• IFS Kullanımı
• CHOOSE ve MATCH Kullanımı

Excel IF fonksiyonu ile İç İçe IF ifadeleri karşılaştırması

Excel'deki IF fonksiyonu ve iç içe IF ifadeleri benzer amaçlara hizmet eder, ancak karmaşıklık ve uygulama açısından önemli farklılıklar gösterir.

İç içe IF kullanımı

Bu bölümde, Excel'de iç içe IF ifadelerinin temel kullanımı, sözdizimi, pratik örnekleri ve AND veya OR koşullarıyla nasıl kullanılacağı gösterilmektedir.

İç içe IF'in sözdizimi

Bir fonksiyonun sözdizimini anlamak, Excel'de doğru ve etkili bir şekilde uygulamanın temelidir. İç içe if ifadelerinin sözdizimiyle başlayalım.

Sözdizimi:

=IF(koşul1, sonuç1, IF(koşul2, sonuç2, IF(koşul3, sonuç3, sonuç4)))

Argümanlar:

• Koşul1, Koşul2, Koşul3: Test etmek istediğiniz koşullardır. Her koşul, Koşul1'den başlayarak sırayla değerlendirilir.
• Sonuç1: Koşul1 Evet ise döndürülen değerdir.
• Sonuç2: Koşul1 Hayır ve Koşul2 Evet ise döndürülen değerdir. Sonuç2'nin yalnızca Koşul1 Hayır ise değerlendirileceğini unutmayın.
• Sonuç3: Hem Koşul1 hem de Koşul2 Hayır ise ve Koşul3 Evet ise döndürülen değerdir. Yani Sonuç3'ün değerlendirilmesi için önceki koşulların (Koşul1 ve Koşul2) ikisinin de Hayır olması gerekir.
• Sonuç4: Tüm koşullar (Koşul1, Koşul2 ve Koşul3) Hayır ise bu sonuç döndürülür.
  
  Kısacası, bu ifade şu şekilde yorumlanabilir:
  Test et koşul1, Evet ise döndür sonuç1, Hayır ise,
  test et koşul2, Evet ise döndür sonuç2, Hayır ise,
  test et koşul3, Evet ise döndür sonuç3, Hayır ise,
  döndür sonuç4

Unutmayın, iç içe IF yapısında, sonraki her koşul yalnızca önceki tüm koşullar Hayır ise değerlendirilir. Bu sıralı kontrol, iç içe IF'lerin nasıl çalıştığını anlamak için kritiktir.

İç içe IF'in pratik örnekleri

Şimdi, iç içe IF kullanımını iki pratik örnekle inceleyelim.

Örnek1: Not Sistemi

Aşağıdaki ekran görüntüsünde gösterildiği gibi, bir öğrenci puanları listeniz olduğunu ve bu puanlara göre not atamak istediğinizi varsayalım. Bu işlemi iç içe IF ile gerçekleştirebilirsiniz.

Boş bir hücreyi seçin (bu örnekte C2), aşağıdaki formülü girin ve sonucu almak için Enter'a basın. Ardından, diğer sonuçları almak için Doldurma Tutamağını aşağıya sürükleyin.

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))

Örnek2: Satış Komisyonu Hesaplama

Satış temsilcilerinin satış başarılarına göre farklı komisyon oranları aldığı bir senaryo hayal edin. Aşağıdaki ekran görüntüsünde gösterildiği gibi, bir satış temsilcisinin komisyonunu bu farklı satış eşiklerine göre hesaplamak istiyorsunuz ve iç içe IF ifadeleri bu konuda size yardımcı olabilir.

Boş bir hücreyi seçin (bu örnekte C2), aşağıdaki formülü girin ve sonucu almak için Enter'a basın. Ardından, diğer sonuçları almak için Doldurma Tutamağını aşağıya sürükleyin.

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

AND / OR koşulu ile iç içe if

Bu bölümde, yukarıdaki ilk örnek olan "not sistemi"ni, Excel'de iç içe IF'i AND veya OR koşuluyla nasıl birleştirebileceğinizi göstermek için düzenliyorum. Yenilenen notlandırma örneğinde, "Devam oranı"na dayalı ek bir koşul ekledim.

AND koşulu ile iç içe if kullanımı

Bir öğrenci hem puan hem de devam kriterlerini karşılarsa, notu bir seviye yükseltilir. Örneğin, puanı60 veya üzeri ve devam oranı %95 veya üzeri olan bir öğrencinin notu bir seviye yükseltilir; A'dan A+'ya, B'den B+'ya gibi. Ancak, devam oranı %95'in altındaysa, notlandırma orijinal puan kriterlerine göre yapılır. Bu gibi durumlarda, AND koşuluyla iç içe IF ifadesi kullanmamız gerekir.

Boş bir hücreyi seçin (bu örnekte D2), aşağıdaki formülü girin ve sonucu almak için Enter'a basın. Ardından, diğer sonuçları almak için Doldurma Tutamağını aşağıya sürükleyin.

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

OR koşulu ile iç içe if kullanımı

Bu durumda, bir öğrencinin puanı95 veya üzerindeyse ya da devam oranı %95 veya üzerindeyse, notu bir seviye yükseltilir. Bunu, iç içe IF ve OR koşullarıyla nasıl yapabileceğimizi aşağıda görebilirsiniz.

Boş bir hücreyi seçin (bu örnekte D2), aşağıdaki formülü girin ve sonucu almak için Enter'a basın. Ardından, diğer sonuçları almak için Doldurma Tutamağını aşağıya sürükleyin.

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

İç içe IF için ipuçları ve püf noktaları

Bu bölümde, iç içe IF için dört faydalı ipucu ve püf noktası ele alınmaktadır.

İç içe IF'i okunabilir hale getirme

Tipik bir iç içe IF ifadesi kompakt görünebilir ancak çözümlemesi zor olabilir.

Aşağıdaki formülde, özellikle karmaşıklık arttıkça, bir koşulun nerede bittiğini ve diğerinin nerede başladığını hızlıca belirlemek zordur.

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Çözüm: Satır Sonları ve Girinti Ekleme

İç içe IF'i okunabilir hale getirmek için, formülü birden fazla satıra bölebilir ve her iç içe IF'i yeni bir satıra yerleştirebilirsiniz. Formülde, IF'in öncesine imleci getirip Alt + Enter tuşlarına basmanız yeterlidir.

Yukarıdaki formül satırlara bölündüğünde aşağıdaki gibi görünecektir:

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

Bu biçim, her koşulun ve karşılık gelen çıktının nerede olduğunu daha net gösterir ve formülün okunabilirliğini artırır.

İç içe IF fonksiyonlarının sıralaması

İç içe IF formülündeki mantıksal koşulların sırası çok önemlidir; çünkü Excel'in bu koşulları nasıl değerlendirdiğini ve dolayısıyla formülün nihai sonucunu belirler.

Doğru formül

Not Sistemi örneğinde, puanlara göre not atamak için aşağıdaki formül kullanılır.

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Excel, iç içe IF formülündeki koşulları sırayla, ilk koşuldan son koşula kadar değerlendirir. Bu formül, en yüksek puan eşiğini önce kontrol eder ("A" için >=90) ve ardından daha düşük eşiklere geçer. Böylece bir puan, hak ettiği en yüksek notla karşılaştırılır. İlk koşul doğruysa (A2>=90), "A" döndürülür ve başka koşullar değerlendirilmez.

Yanlış sıralanmış formül

Koşulların sırası tersine çevrilirse ve en düşük eşikle başlanırsa, yanlış sonuçlar döndürülür.

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

Bu yanlış formülde,95 puan hemen ilk koşul olan B2>=60'ı karşılar ve yanlışlıkla "D" notu atanır.

Sayılar ve metinler farklı şekilde ele alınmalıdır

Bu bölümde, iç içe IF ifadelerinde sayıların ve metinlerin nasıl farklı şekilde ele alındığı gösterilecektir.

Sayılar

Sayılar, aritmetik karşılaştırmalar ve hesaplamalar için kullanılır. İç içe IF ifadelerinde, sayıları doğrudan >, <, =, >= ve <= gibi operatörlerle karşılaştırabilirsiniz.

Metin

İç içe IF ifadelerinde, metinler çift tırnak içine alınmalıdır. Aşağıdaki formüldeki A, B, C, D ve F'ye bakınız:

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

İç içe IF'in sınırlamaları

Bu bölümde, iç içe IF'in birkaç sınırlaması ve dezavantajı listelenmektedir.

Karmaşıklık ve Okunabilirlik:

Excel'de64'e kadar farklı IF fonksiyonunu iç içe kullanabilirsiniz, ancak bunu yapmak kesinlikle tavsiye edilmez. İç içe seviye arttıkça formül daha karmaşık hale gelir. Bu da formüllerin okunmasını, anlaşılmasını ve bakımını zorlaştırabilir.

Hata Eğilimi:

Ayrıca, karmaşık iç içe IF ifadeleri hata yapmaya daha yatkın hale gelir ve hata ayıklama veya düzenleme açısından zorluk çıkarabilir.

Genişletmek veya Ölçeklendirmek Zor:

Mantığınız değişirse veya daha fazla koşul eklemeniz gerekirse, derin iç içe IF'leri değiştirmek veya genişletmek zor olabilir.

Bu sınırlamaları anlamak, Excel'de iç içe IF ifadelerini etkili şekilde kullanmanın anahtarıdır. Genellikle, iç içe IF'leri diğer fonksiyonlarla birleştirmek veya alternatif yaklaşımlar aramak daha verimli ve sürdürülebilir çözümler sunabilir.

İç İçe IF'e Alternatifler

Bu bölümde, Excel'de iç içe IF ifadelerine alternatif olarak kullanılabilecek birkaç fonksiyon listelenmektedir.

VLOOKUP Kullanımı

Yukarıdaki iki pratik örneği gerçekleştirmek için iç içe IF ifadeleri yerine VLOOKUP fonksiyonunu kullanabilirsiniz. İşte nasıl yapacağınız:

Örnek1: VLOOKUP ile Not Sistemi

Burada, puanlara göre not atamak için VLOOKUP kullanımını göstereceğim.

Adım1: Notlar için bir Arama Tablosu Oluşturun

Öncelikle, puan aralığı ve karşılık gelen notlar için bir arama tablosu (bu örnekte E1:F6 gibi) oluşturmanız gerekir. Not: Tabloyun ilk sütunundaki puanlar artan sırada olmalıdır.

Adım2: VLOOKUP fonksiyonunu uygulayarak notları atayın

Boş bir hücreyi seçin (bu örnekte C2), aşağıdaki formülü girin ve ilk notu almak için Enter'a basın. Bu formül hücresini seçin ve Doldurma Tutamağını aşağıya sürükleyerek diğer notları alın.

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

Örnek2: VLOOKUP ile Satış Komisyonu Hesaplama

Excel'de satış komisyonu hesaplamasını da VLOOKUP ile gerçekleştirebilirsiniz. Lütfen aşağıdaki adımları izleyin.

Adım1: Notlar için bir Arama Tablosu Oluşturun

Öncelikle, satışlar ve karşılık gelen komisyon oranı için bir arama tablosu oluşturmanız gerekir, bu örnekte E2:F4 gibi. Not: Tabloyun ilk sütunundaki satışlar artan sırada olmalıdır.

Adım2: VLOOKUP fonksiyonunu uygulayarak notları atayın

Boş bir hücreyi seçin (bu örnekte C2), aşağıdaki formülü girin ve ilk komisyonu almak için Enter'a basın. Bu formül hücresini seçin ve Doldurma Tutamağını aşağıya sürükleyerek diğer sonuçları alın.

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

IFS Kullanımı

IFS fonksiyonu, iç içe kullanıma gerek bırakmadan işlemi basitleştirir ve formüllerin okunmasını ve yönetilmesini kolaylaştırır. Okunabilirliği artırır ve birden fazla koşullu kontrolün yönetimini kolaylaştırır. IFS fonksiyonunu kullanmak için Excel2019 veya daha yeni bir sürüm ya da Office365 aboneliğiniz olmalıdır. Şimdi pratik örneklerde nasıl uygulanabileceğine bakalım.

Örnek1: IFS ile Not Sistemi

Öncekiyle aynı notlandırma kriterlerini varsayarsak, IFS fonksiyonu şu şekilde kullanılabilir:

C2 gibi boş bir hücre seçin, aşağıdaki formülü girin ve ilk sonucu almak için Enter'a basın. Sonuç hücresini seçin ve Doldurma Tutamağını aşağıya sürükleyerek diğer sonuçları alın.

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

Örnek2: IFS ile Satış Komisyonu Hesaplama

Satış komisyonu hesaplama senaryosu için, IFS fonksiyonu şu şekilde uygulanır:

C2 gibi boş bir hücre seçin, aşağıdaki formülü girin ve ilk sonucu almak için Enter'a basın. Sonuç hücresini seçin ve Doldurma Tutamağını aşağıya sürükleyerek diğer sonuçları alın.

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

CHOOSE ve MATCH Kullanımı

CHOOSE ve MATCH yaklaşımı, iç içe IF ifadelerine kıyasla daha verimli ve yönetimi kolay olabilir. Bu yöntem, formülü basitleştirir ve güncellemeleri veya değişiklikleri daha kolay hale getirir. Aşağıda, bu makaledeki iki pratik örneği CHOOSE ve MATCH fonksiyonlarının kombinasyonuyla nasıl ele alacağınızı göstereceğim.

Örnek1: CHOOSE ve MATCH ile Not Sistemi

Farklı puanlara göre not atamak için CHOOSE ve MATCH fonksiyonlarının kombinasyonunu kullanabilirsiniz.

Adım1: Arama değerleriyle bir Arama Dizisi oluşturun

Öncelikle, MATCH'in arayacağı eşik değerlerini içeren bir hücre aralığı oluşturmanız gerekir; bu örnekte $E$2:$E$6 gibi. Not: Bu aralıktaki sayılar, MATCH fonksiyonu yaklaşık eşleşme türüyle doğru çalışabilmesi için artan sırada olmalıdır.

Adım2: CHOOSE ve MATCH ile notları atayın

Boş bir hücreyi seçin (bu örnekte C2), aşağıdaki formülü girin ve ilk notu almak için Enter'a basın. Bu formül hücresini seçin ve Doldurma Tutamağını aşağıya sürükleyerek diğer sonuçları alın.

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

Örnek2: IFS ile Satış Komisyonu Hesaplama

Satış Komisyonu Hesaplaması için CHOOSE ve MATCH kombinasyonunu kullanmak da etkili olabilir, özellikle komisyon oranları belirli satış eşiklerine dayalıysa. Nasıl yapabileceğimize bakalım.

Adım1: Arama değerleriyle bir Arama Dizisi oluşturun

Öncelikle, MATCH'in arayacağı eşik değerlerini içeren bir hücre aralığı oluşturmanız gerekir; bu örnekte $E$2:$E$4 gibi. Not: Bu aralıktaki sayılar, MATCH fonksiyonu yaklaşık eşleşme türüyle doğru çalışabilmesi için artan sırada olmalıdır.

Adım2: CHOOSE ve MATCH ile sonuçları alın

Boş bir hücreyi seçin (bu örnekte C2), aşağıdaki formülü girin ve ilk notu almak için Enter'a basın. Bu formül hücresini seçin ve Doldurma Tutamağını aşağıya sürükleyerek diğer sonuçları alın.

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

Sonuç olarak, Excel'de iç içe IF ifadelerini ustalıkla kullanmak, veri analizi ve karar verme süreçlerinde karmaşık mantıksal senaryoları yönetme yeteneğinizi artırır. İç içe IF'ler karmaşık mantıksal işlemler için güçlüdür, ancak sınırlamalarının farkında olmak önemlidir. VLOOKUP, IFS ve CHOOSE ile MATCH gibi daha basit alternatifler, bazı durumlarda daha pratik ve sürdürülebilir çözümler sunabilir. Bu bilgilerle artık veri analiz görevlerinizde en uygun Excel tekniklerini güvenle uygulayabilir, tablolarınızda açıklık, doğruluk ve verimlilik sağlayabilirsiniz. Excel'in yeteneklerini daha derinlemesine keşfetmek isteyenler için sitemizde çok sayıda eğitim bulunmaktadır. Daha fazla Excel ipucu ve püf noktası için buraya göz atın.

İlgili Makaleler