Excel'de bir veri listesinden birden fazla klasör ve alt klasör oluşturma

Bir çalışma sayfası aralığında personel isimlerinden oluşan bir liste olduğunu ve her birinin bilgilerini saklamak için bireysel klasörler oluşturmak istediğinizi varsayalım. Her klasörü manuel olarak oluşturmak zaman alıcı olabilir. Ancak bu süreci hızlandırmak için etkili yöntemler mevcuttur. Bu rehberde, belirtilen hücre değerlerine göre klasörleri hızlıca oluşturmanın birkaç yaklaşımını paylaşacağım.

Hücre değerlerine göre klasör oluşturun

• MD komutu ve Not Defteri kullanarak
• Güçlü bir özellik kullanarak – Kutools for Excel
• VBA kodu kullanarak

Hücre değerlerine göre VBA koduyla klasör ve alt klasör oluşturma

Hücre değerlerine göre klasör oluşturun

Bu bölümde, hücre değerleri listesine göre klasörleri hızlı ve zahmetsizce oluşturmanın çeşitli yöntemlerini ayrıntılı olarak inceleyecek ve adım adım kapsamlı talimatlar sunacağız.

MD komutu ve Notepad kullanarak listeden klasör oluşturma

Excel'den bir listeyi MD komutu ve Notepad kullanarak klasörlere dönüştürmek, basit toplu iş betiklerini Excel’in düzenli yapıyı koruma yeteneğiyle akıllıca birleştirerek zamandan tasarruf sağlayan pratik bir püf noktasıdır. Bu yöntem, çok sayıda klasörü manuel olarak oluşturmak zorunda kalmadan hızlıca üretmek için idealdir. Aşağıda bu görevi gerçekleştirmek için adım adım bir kılavuz yer almaktadır:

Adım 1: Klasör oluşturmak için MD komutunu kullanın

Copy or enter the following formula into a blank cell next to your first cell value (B1, for instance) ve ardından tüm Liste Öğesi hücrelerinize formülü uygulamak için doldurma tutamacını aşağı doğru sürükleyin.

="MD "&A1

Adım 2: Formülleri bir Notepad dosyasına kopyalayıp yapıştırın

1. MD formülünü içeren hücreleri kopyalamak için "Ctrl + C" tuşlarına basın.
2. Not Defteri'ni açın ve komutları bir Oluşturulan Dosya içine yapıştırmak için Ctrl+V tuşlarına basın.
   

Adım 3: Notepad dosyasını .bat dosyası olarak kaydedin

Notepad'de "Dosya" sekmesinden "Farklı Kaydet" seçeneğine tıklayın. "Farklı Kaydet" iletişim kutusunda, birden fazla klasör oluşturmak istediğiniz dizini seçin ve dosyaya .bat uzantısıyla bir ad verin. Son olarak, "Kaydet" düğmesine tıklayın. Ekran görüntüsüne bakın:

Adım 4: Birden fazla klasör oluşturmak için .bat dosyasına çift tıklayın

1. Notepad dosyasını kapatın ve daha önce .bat dosyasını kaydettiğiniz klasöre gidin.
2. Şimdi sihri gözlemleyin: Dosyaya çift tıkladığınızda, birden fazla klasörün aynı anda oluşturulduğunu göreceksiniz. Aşağıdaki demoyu inceleyin:
   

Güçlü bir araç olan Kutools for Excel kullanarak listeden klasör oluşturma

Güçlü Kutools for Excel’in “Aralığa Dayalı Klasör Oluştur” özelliğiyle artık Excel listesinden kolayca ve hızlıca klasör oluşturabilirsiniz. Bu özellik yalnızca temel klasörlerle sınırlı kalmaz; Kutools aynı zamanda tek seferde çok seviyeli alt klasörlerden oluşan karmaşık yapılar bile oluşturmanıza olanak tanır. Sadece birkaç basit adım, Excel’deki verilerinizi düzenli bir klasör sistemine dönüştürerek üretkenliğinizi önemli ölçüde artırır.

Kutools for Excel'yi yükledikten sonra lütfen "KUTOOLS PLUS" > "İçe/Dışa Aktar" > "Aralığa Dayalı Klasör Oluştur" seçeneğine tıklayarak Aralığa Dayalı Klasör Oluştur iletişim kutusunu açın:

1. Klasör oluşturmak istediğiniz hücre değerlerini seçin;
2. Ardından, klasörleri kaydetmek istediğiniz hedef klasörü belirtmek için düğmesine tıklayın;
3. Son olarak, Tamam düğmesine tıklayın.
   

Sonuç:

Kutools, sayfanızdaki listeyi işleyecek ve belirtilen hedef konumda her bir giriş için ayrı bir klasör oluşturacaktır. Sonucu görmek için hedef klasöre göz atın. Ekran görüntüsüne bakın:

VBA kodu kullanarak listeden klasör oluşturma

Excel'de VBA kodu kullanmak, listeden klasör oluşturma gibi sıkıcı görevleri hızlı ve otomatik bir sürece dönüştürebilir. Bu bölümde, klasör oluşturmak için VBA kodunun nasıl uygulanacağını göstereceğiz.

Adım 1: VBA modül düzenleyicisini açın ve kodu kopyalayın

1. Excel'de "ALT + F11" tuşlarına basılı tutun; böylece "Microsoft Visual Basic for Applications" penceresi açılır.
2. "Ekle" > "Modül" seçeneğine tıklayın ve aşağıdaki kodu Modül Penceresine yapıştırın.
   VBA kodu: Hücre değerlerine göre klasör oluşturma

   Sub CreateFoldersFromSelection()
   'Updateby Extendoffice
       Dim FolderPath As String
       Dim Cell As Range
       Dim SelectedRange As Range
       Dim FolderName As String
       On Error Resume Next
       Set SelectedRange = Application.InputBox("Select the range with folder names", "Kutools for Excel", Type:=8)
       If SelectedRange Is Nothing Then Exit Sub
       On Error GoTo 0
       
       With Application.FileDialog(msoFileDialogFolderPicker)
           .Title = "Select the destination Folder"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           FolderPath = .SelectedItems(1) & "\"
       End With
       
       For Each Cell In SelectedRange
           FolderName = FolderPath & Cell.Value
           If Cell.Value <> "" And Not FolderExists(FolderName) Then
               MkDir FolderName
           End If
       Next Cell
   End Sub
   
   Function FolderExists(ByVal Path As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(Path) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

Adım 2: Kodu çalıştırın

1. Bu kodu yapıştırdıktan sonra çalıştırmak için lütfen F5 tuşuna basın. İstem kutusunda, klasör oluşturmak istediğiniz hücre değerlerini seçin ve ardından Tamam’a tıklayın.
   
2. Ardından, açılan “Hedef Klasörü Seçin” penceresinde oluşturulan klasörlerin çıktısının alınacağı hedef yolu belirleyin ve Tamam düğmesine tıklayın (ekran görüntüsüne bakın):
   

Sonuç:

VBA kodunu çalıştırdıktan sonra sonucu görüntülemek için hedef dizine gidin. Excel listenizdeki her öğe için yeni oluşturulan klasörleri orada göreceksiniz. Ekran görüntüsüne göz atın:

Hücre değerlerine göre VBA koduyla klasör ve alt klasör oluşturma

Bazen yalnızca klasörleri değil, aynı zamanda bunların ilgili alt klasörlerini de Excel hücrelerindeki verilere göre oluşturmanız gerekebilir. Bu görevi gerçekleştirmek için size bir VBA kodu tanıtacağım.

Adım 1: Verileri hazırlayın

Öncelikle aşağıdaki ekran görüntüsünde gösterildiği gibi verileri girin: Ana klasör adını ilk sütuna, alt klasör adlarını ise ikinci sütuna yerleştirin.

Adım 2: VBA modül düzenleyicisini açın ve kodu kopyalayın

1. Excel'de "ALT + F11" tuşlarına basın; böylece "Microsoft Visual Basic for Applications" penceresi açılır.
2. "Ekle" > "Modül" seçeneğine tıklayın ve aşağıdaki kodu Modül Penceresine yapıştırın.
   VBA kodu: Hücre değerlerine göre klasör ve alt klasör oluşturma

   Sub CreateFoldersAndSubfoldersWithUserInput()
   'Updateby Extendoffice
       Dim Rng As Range
       Dim Cell As Range
       Dim basePath As String
       Dim fldrPicker As FileDialog
       Dim FolderPath As String, subfolderPath As String
       On Error Resume Next
       Set Rng = Application.InputBox("Select the range of cells (two columns: one is folder column, another s subfolder column):", "Kutools for Excel", Type:=8)
       If Rng Is Nothing Then Exit Sub
       On Error GoTo 0
       Set fldrPicker = Application.FileDialog(msoFileDialogFolderPicker)
       With fldrPicker
           .Title = "Select the Base Folder Path"
           .AllowMultiSelect = False
           If .Show <> -1 Then Exit Sub
           basePath = .SelectedItems(1)
       End With
       If Right(basePath, 1) <> "\" Then basePath = basePath & "\"
       For Each Cell In Rng.Columns(1).Cells
           If Not Cell.Value = "" Then
               FolderPath = basePath & Cell.Value
               If Not FolderExists(FolderPath) Then MkDir FolderPath
               If Not Cell.Offset(0, 1).Value = "" Then
                   subfolderPath = FolderPath & "\" & Cell.Offset(0, 1).Value
                   If Not FolderExists(subfolderPath) Then MkDir subfolderPath
               End If
           End If
       Next Cell
   End Sub
   
   Function FolderExists(FolderPath As String) As Boolean
       On Error Resume Next
       FolderExists = (GetAttr(FolderPath) And vbDirectory) = vbDirectory
       On Error GoTo 0
   End Function
   

Adım 3: Kodu çalıştırın

1. Bu kodu yapıştırdıktan sonra çalıştırmak için lütfen F5 tuşuna basın. İstem kutusunda, klasör oluşturmak istediğiniz hücre değerlerini seçin ve ardından Tamam’a tıklayın.
   
2. Açılan pencerede, oluşturulan klasörlerin çıktısının alınacağı hedef yolu belirtin ve ardından Tamam düğmesine tıklayın (ekran görüntüsüne bakın):
   

Sonuç:

VBA kodunu çalıştırdıktan sonra sonucu görüntülemek için hedef dizine gidin. Aşağıdaki ekran görüntüsünde gösterildiği gibi, hücre değerlerine göre belirlenen klasörlerin ve ilgili alt klasörlerinin başarıyla oluşturulduğunu göreceksiniz:

İlgili Makaleler: