Outlook'ta klasör adını kullanarak klasörün tam dosya yolunu nasıl bulabilirim?

Outlook'ta VBA kullanarak klasör adıyla klasör aramak için lütfen aşağıdaki adımları izleyin.

1. "Microsoft Visual Basic for Applications" penceresini açmak için "Alt" + "F11" tuşlarına aynı anda basın.

2. "Ekle" > "Modül" seçeneğine tıklayıp aşağıdaki VBA kodunu yeni modül penceresine yapıştırın.

VBA: Outlook'ta Klasör Adı kullanarak klasörleri arayın ve Klasörü Aç

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. Bu VBA kodunu çalıştırmak için "F5" tuşuna basın veya "Çalıştır" düğmesine tıklayın.

4. Açılan "Klasör Ara" iletişim kutusuna, aramak istediğiniz klasörün adını girin ve "Tamam" düğmesine tıklayın.

Not: Bu VBA yıldız (*) joker karakterini destekler. Örneğin, adına "tes" ile başlayan tüm klasörleri bulmak için "tes*" yazabilirsiniz.

5. Şimdi, bulunan klasörün dosya yolunu gösteren bir iletişim kutusu açılır. Bulunan klasörü açmak istiyorsanız "Evet" düğmesine tıklayın.

Ve şimdi bulunan klasör, aşağıdaki ekran görüntüsünde gösterildiği gibi Gezinme açılıyor:

Not: Belirtilen isimde birden fazla klasör varsa, bu VBA yalnızca bir tanesini bulup açabilir.

"Kutools for Outlook" yüklüyse, belirli bir klasör adıyla tüm klasörleri anında bulun ve bulduğunuz herhangi birini kolayca açmak için "Git" özelliğini kullanın!

1. Bu özelliği etkinleştirmek için "KUTOOLS PLUS" > "Git" seçeneğine tıklayın.

"Git" iletişim kutusunda, "Ara" kutusuna belirtilen klasör adını girin, arama sonuçlarından bir klasör seçin ve "Tamam" düğmesine tıklayın.

Artık belirli bir Klasör Adı içeren klasör anında bulunup açılır.