Outlook’ta e-posta mesajını JPG veya TIFF gibi resim formatında nasıl kaydedebilirim?

Outlook’ta bir e-posta mesajını JPG veya TIFF gibi bir resim formatında kaydetmeyi denediniz mi? Bu makale, bu sorunu çözmenize yardımcı olacak pratik bir yöntem sunar.

E-posta mesajını VBA koduyla resim formatında kaydedin

---

E-posta mesajını VBA koduyla resim formatında kaydedin

Outlook’ta bir e-posta mesajını resim formatında kaydetmek için lütfen aşağıdaki adımları izleyin.

1. Resim olarak kaydetmek istediğiniz bir e-postayı seçin ve ardından Alt + F11 tuşlarına aynı anda basarak Microsoft Visual Basic for Applications penceresini açın.

2. Microsoft Visual Basic for Applications penceresinde, lütfen Ekle > UserForm seçeneğine tıklayın. Ekran görüntüsüne bakın:

3. Aşağıdaki ekran görüntüsünde gösterildiği gibi bir UserForm oluşturun.

4. jpg Seçeneği düğmesini seçin ve sol taraftaki opbJPG öğesini Özellikler bölmesinde yeniden adlandırın.

5. Diğer seçenek düğmesini opbTIFF olarak yeniden adlandırmak için yukarıdaki 4. adımı tekrarlayın. Ayrıca Tamam komut düğmesini ve İptal komut düğmesini sırasıyla cdbOk ve cdbCancel olarak yeniden adlandırın.

Not: Özellikler bölmesi Microsoft Visual Basic for Applications penceresinde görünmüyorsa, bölmeyi açmak için lütfen F4 tuşuna basın.

6. UserForm üzerindeki boş bir alana çift tıklayarak Kod penceresini açın. Tüm kodu aşağıdaki VBA betiğiyle değiştirin ve ardından Kod penceresini kapatın.

VBA kodu 1: E-posta mesajını resim olarak kaydetme

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7. UserForm1 öğesini seçin ve aşağıdaki ekran görüntüsünde gösterildiği gibi FrmPicType olarak yeniden adlandırın Özellikler bölmesinde.

8. Ekle > Modül seçeneğine tıklayın ve ardından aşağıdaki VBA kodunu Modül penceresine kopyalayın.

VBA kodu 2: E-posta mesajını resim olarak kaydetme

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9. Araçlar > Referanslar seçeneğine tıklayın, Microsoft PowerPoint Nesne Kitaplığı kutusunu işaretleyin ve ardından Tamam düğmesine tıklayın. Ekran görüntüsüne bakın:

10. Kodu çalıştırmak için F5 tuşuna basın. Ardından UserForm1 iletişim kutusu görüntülenecek. Lütfen bir resim türü seçin ve Tamam düğmesine tıklayın. Ekran görüntüsüne bakın:

11. Klasör Seç iletişim kutusunda, resmi kaydetmek için bir klasör belirleyin ve ardından Tamam düğmesine tıklayın.

12. Son olarak, kaydetme işleminin tamamlandığını bildirmek için bir Microsoft Outlook iletişim kutusu görüntülenecektir. Lütfen Tamam düğmesine tıklayın.

Seçilen e-postalar başarıyla JPG veya TIFF görüntüsüne dönüştürüldü ve belirtilen klasöre kaydedildi.

---

İlgili Makaleler:

• Outlook’ta birden fazla e-postadaki tüm ekleri aynı klasöre nasıl kaydedebilirim?
• Outlook'ta bir e-postadaki tüm ekleri nasıl kaldırabilirim?