Outlook'ta e-posta gövdesine tüm alıcı isimlerini nasıl eklerim?

Author: Xiaoyang Last Modified: 2025-08-07

Bazen, Outlook'ta e-posta yazarken mesaj gövdesine tüm alıcıların isimlerini eklemeniz gerekebilir. Elbette, isimleri teker teker gövdeye kopyalayıp yapıştırabilirsiniz. Ancak, yapıştırılması gereken onlarca alıcı ismi varsa bu oldukça sıkıcı bir işlem olabilir. Bu makalede, Outlook'ta bu işi çözmek için kolay bir yol hakkında konuşacağım.

Outlook'ta VBA kodu ile e-posta gövdesine tüm alıcı isimlerini ekleme

Outlook'ta VBA kodu ile e-posta gövdesine tüm alıcı isimlerini ekleme

Aşağıdaki VBA kodu, Alıcılar alanındaki tüm alıcı isimlerini mesaj gövdesine eklemenize yardımcı olabilir, lütfen şu adımları izleyin:

1. Outlook'u başlatın ve ardından Microsoft Visual Basic for Applications penceresini açmak için ALT + F11 tuşlarına basılı tutun.

2. Ekle > Modül seçeneğine tıklayın ve aşağıdaki kodu Modül Penceresine yapıştırın.

VBA Kodu: Alıcı isimlerini mesaj gövdesine ekleme:

Sub InsertRecipientNamesToBody()
Dim xMailItem As Outlook.MailItem
Dim xRecipient As Outlook.Recipient
Dim xRecipAddress, xRecipNames, xRecipName, xFilterAddr As String
Dim xItems As Outlook.Items
Dim i As Integer
Dim xFoundContact As Outlook.ContactItem
Dim xDoc As Word.Document
On Error Resume Next
Set xMailItem = Outlook.ActiveInspector.CurrentItem
xMailItem.Recipients.ResolveAll
For Each xRecipient In xMailItem.Recipients
    xRecipAddress = xRecipient.Address
    Set xItems = Application.Session.GetDefaultFolder(olFolderContacts).Items
    For i = 1 To 3
        xFilterAddr = "[Email" & i & "Address] = " & xRecipAddress
        Set xFoundContact = xItems.Find(xFilterAddr)
        If Not (xFoundContact Is Nothing) Then
           xRecipNames = xRecipNames & xFoundContact.FullName & Chr(10)
           Exit For
        End If
    Next
    If (xFoundContact Is Nothing) Then
       xRecipName = Split(xRecipAddress, "@")(0)
       xRecipNames = xRecipNames & xRecipName & Chr(10)
    End If
Next
Set xDoc = xMailItem.GetInspector.WordEditor
xDoc.Content.InsertAfter xRecipNames
Set xMailItem = Nothing
Set xRecipient = Nothing
Set xItems = Nothing
Set xFoundContact = Nothing
End Sub

3. Ve hala Microsoft Visual Basic for Applications penceresinde iken, Araçlar > Referanslar'a tıklayarak Referanslar-Proje1 iletişim kutusuna gidin ve Kullanılabilir Referanslar listesinden Microsoft Word Nesne Kitaplığı seçeneğini işaretleyin, aşağıdaki ekran görüntüsüne bakın:

the screenshot of step about inserting all recipient names to email body in outlook 1

4. Ardından iletişim kutusunu kapatmak için Tamam'a tıklayın, şimdi bu kodu Hızlı Erişim Araç Çubuğu'na eklemelisiniz.

5. Yeni E-posta'ya tıklayarak yeni bir ileti oluşturun, İleti penceresinde Hızlı Erişim Araç Çubuğu simgesini özelleştir'i tıklayın ve Daha Fazla Komut seçeneğini seçin, aşağıdaki ekran görüntüsüne bakın: