Outlook’ta birden fazla taslağı aynı anda nasıl gönderirsiniz?

Taslaklar klasörünüzde birden fazla taslak mesajınız varsa ve bunları tek tek değil, hepsini aynı anda göndermek istiyorsanız, bu işlemi Outlook’ta nasıl hızlı ve kolay bir şekilde gerçekleştirebilirsiniz?

Outlook'ta VBA kodu ile tüm taslak mesajları aynı anda gönderin

---

Outlook'ta VBA kodu ile tüm taslak mesajları aynı anda gönderin

Aşağıdaki VBA kodları, Taslaklar klasöründeki tüm ya da seçili taslak e-postaları aynı anda göndermenize olanak tanır. Lütfen aşağıdaki adımları izleyin:

1. Microsoft Visual Basic for Applications penceresini açmak için ALT + F11 tuşlarına basılı tutun.

2. Ardından Ekle > Modül seçeneğine tıklayın ve aşağıdaki kodu açılan boş modüle kopyalayıp yapıştırın; ekran görüntüsüne bakın:

VBA kodu: Outlook'ta tüm taslak e-postaları aynı anda gönderme:

Sub SendAllDraftEmails()
Dim xAccount As Account
Dim xDraftFld As Folder
Dim xItemCount As Integer
Dim xCount As Integer
Dim xDraftsItems As Outlook.Items
Dim xPromptStr As String
Dim xYesOrNo As Integer
Dim i As Long
Dim xCurFld As Folder
Dim xTmpFld As Folder
On Error Resume Next
xItemCount = 0
xCount = 0
Set xTmpFld = Nothing
Set xCurFld = Application.ActiveExplorer.CurrentFolder
For Each xAccount In Outlook.Application.Session.Accounts
    Set xDraftFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
    xItemCount = xItemCount + xDraftFld.Items.Count
    If xDraftFld.EntryID = xCurFld.EntryID Then
        Set xTmpFld = xCurFld.Parent
    End If
Next xAccount
Set xDraftFld = Nothing
If xItemCount > 0 Then
   xPromptStr = "Are you sure to send out all the drafts?"
    xYesOrNo = MsgBox(xPromptStr, vbQuestion + vbYesNo, "Kutools for Outlook")
    If xYesOrNo = vbYes Then
        If Not xTmpFld Is Nothing Then
            Set Application.ActiveExplorer.CurrentFolder = xTmpFld
        End If
        VBA.DoEvents
        For Each xAccount In Outlook.Application.Session.Accounts
            Set xDraftFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
            Set xDraftsItems = xDraftFld.Items
            For i = xDraftsItems.Count To 1 Step -1
                If xDraftsItems.Item(i).Recipients.Count <> 0 Then
                    xDraftsItems.Item(i).sEnd
                    xCount = xCount + 1
                End If
            Next
        Next xAccount
        VBA.DoEvents
        Set Application.ActiveExplorer.CurrentFolder = xCurFld
        MsgBox "Successfully sent " & xCount & " messages", vbInformation, "Kutools for Outlook"
    End If
Else
    MsgBox "No Drafts!", vbInformation + vbOKOnly, "Kutools for Outlook"
End If
End Sub

3. Ardından kodu kaydedin ve çalıştırmak için F5 tuşuna basın. Tüm taslakların gönderileceği konusunda sizi uyaran bir uyarı kutusu açılacak; Evet seçeneğine tıklayın; ekran görüntüsüne bakın:

4. Kaç adet taslak e-postanın gönderildiğini gösteren bir iletişim kutusu açılacak; ekran görüntüsüne bakın:

5. Ardından Tamam düğmesine tıklayın; böylece Taslaklar klasöründeki tüm e-postalar aynı anda gönderilecektir. Ekran görüntüsüne bakın:

Notlar:

1. Yukarıdaki kod, Outlook’ta bulunan tüm hesaplardaki taslak e-postaları gönderecektir.

2. Yalnızca Taslaklar klasöründeki belirli e-postaları göndermek istiyorsanız, lütfen aşağıdaki VBA kodunu uygulayın:

VBA kodu: Taslaklar klasöründen seçili e-postaları gönderme:

Sub SendSelectedDraftEmails()
Dim xSelection As Selection
Dim xPromptStr As String
Dim xYesOrNo As Integer
Dim i As Long
Dim xAccount As Account
Dim xCurFld As Folder
Dim xDraftsFld As Folder
Dim xTmpFld As Folder
Dim xArr() As String
Dim xCount As Integer
Dim xMail As MailItem
On Error Resume Next
xCount = 0
Set xTmpFld = Nothing
Set xCurFld = Application.ActiveExplorer.CurrentFolder
For Each xAccount In Outlook.Application.Session.Accounts
    Set xDraftsFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderDrafts)
    If xDraftsFld.EntryID = xCurFld.EntryID Then
        Set xTmpFld = xCurFld.Parent
    End If
Next xAccount
If xTmpFld Is Nothing Then
    MsgBox "The current folder is not a draft folder", vbInformation, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection.Count > 0 Then
    xPromptStr = "Are you sure to send out the selected " & xSelection.Count & " draft item(s)?"
    xYesOrNo = MsgBox(xPromptStr, vbQuestion + vbYesNo, "Kutools for Outlook")
    If xYesOrNo = vbYes Then
        ReDim xArr(xSelection.Count - 1)
        For i = 1 To xSelection.Count
            xArr(i - 1) = xSelection.Item(i).EntryID
        Next
        Set Application.ActiveExplorer.CurrentFolder = xTmpFld
        VBA.DoEvents
        For i = 0 To UBound(xArr)
            Set xMail = Application.Session.GetItemFromID(xArr(i))
            If xMail.Recipients.Count <> 0 Then
                xMail.sEnd
                xCount = xCount + 1
            End If
        Next
        VBA.DoEvents
        Set Application.ActiveExplorer.CurrentFolder = xCurFld
        MsgBox "Successfully sent " & xCount & " messages", vbInformation, "Kutools for Outlook"
    End If
Else
    MsgBox "No items selected!", vbInformation, "Kutools for Outlook"
End If
End Sub

---

---

İlgili Makaleler:

Outlook’ta bir e-postayı aynı anda birden fazla alıcıya bireysel olarak nasıl gönderirsiniz?

Excel’deki bir listeden Outlook üzerinden kişiselleştirilmiş toplu e-postalar nasıl gönderilir?

Outlook’ta bir takvimi aynı anda birden fazla alıcıya bireysel olarak nasıl gönderirsiniz?

Outlook’ta alıcıların birbirlerini bilmeden aynı anda birden fazla kişiye e-posta nasıl gönderilir?