Outlook klasör yapısını masaüstüne veya Windows gezginine kopyalamak için lütfen aşağıdaki adımları izleyin.

1. Gezinti Bölmesinde, klasör yapısını kopyalayacağınız belirtilen klasörü vurgulamak için lütfen tıklayın ve Ara Toplam + F11 Microsoft Visual Basic for Applications penceresini açmak için tuşlar.

2. tık Tools > Referanslar Referanslar iletişim kutusunu açmak için. Ardından iletişim kutusunda kontrol edin Microsoft Komut Dosyası Çalışma Zamanı seçeneğini tıklayın ve OK buton. Ekran görüntüsüne bakın:

3. tık Ekle > modülve yeni modül penceresine VBA kodunun altına kopyalayıp yapıştırın.

VBA: Outlook klasör yapısını Windows gezginine kopyalayın

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. Basın F5 anahtarı veya tıklayın koşmak Bu VBA'yı çalıştırmak için düğmesine basın.

5. Klasöre Gözat iletişim kutusunu açarak, lütfen kopyalanan klasör yapısını yerleştireceğiniz belirtilen klasörü seçin ve OK buton. Ekran görüntüsüne bakın:

Şimdi belirtilen klasöre gidin, klasör yapısının belirtilen sabit diske kopyalandığını göreceksiniz. Ekran görüntüsüne bakın:

not: e-postalar, randevular, görevler vb. gibi klasör öğeleri de sabit diskteki ilgili klasörlere kopyalanır.

Outlook'ta klasör yapısını yeni pst veri dosyasına nasıl kopyalayabilirim?