Outlook’ta mesajlar veya görevlerdeki konu metnini nasıl Bul ve Değiştir yapabilirsiniz?

Outlook’ta birden fazla mesaj veya görevin konusunu belirttiğiniz metinle değiştirmeniz gerekiyorsa, elbette tek tek düzenleyebilirsiniz; ancak bu işlemi Outlook’ta bir seferde tamamlayabileceğiniz daha hızlı bir yol var mı?

VBA kodu kullanarak birden fazla mesaj içindeki konu metnini Bul ve Değiştir

VBA kodu kullanarak birden fazla görev içindeki konu metnini Bul ve Değiştir

---

VBA kodu kullanarak birden fazla mesaj içindeki konu metnini Bul ve Değiştir

Birden fazla mesajın konusunda belirli bir metni bulun ve onu başka bir metinle değiştirin. Aşağıdaki VBA kodu bu işlemde size yardımcı olabilir. Lütfen aşağıdaki adımları izleyin:

1. Konu metnini Bul ve Değiştir istediğiniz e-postaları seçin, ardından "ALT + F11" tuşlarına basarak "Microsoft Visual Basic for Applications" penceresini açın.

2. Ardından "Ekle" > "Modül" seçeneğine tıklayıp, aşağıda verilen kodu açılan boş modüle kopyalayın ve yapıştırın (ekran görüntüsüne bakın):

VBA kodu: Birden fazla mesaj içindeki konu metnini Bul ve Değiştir:

Option Explicit
Sub FindAndReplaceInSubject()
Dim xItem As Object
Dim xNewSubject As String
Dim xMailItem As MailItem
Dim xExplorer As Explorer
Dim i As Integer
On Error Resume Next
Set xExplorer = Outlook.Application.ActiveExplorer
For i = xExplorer.Selection.Count To 1 Step -1
    Set xItem = xExplorer.Selection.Item(i)
    If xItem.Class = olMail Then
        Set xMailItem = xItem
        With xMailItem
            xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")
            .Subject = xNewSubject
            .Save
        End With
    End If
Next
End Sub

Notlar: Yukarıdaki kodda; `xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")` ifadesinde, "kte" aradığınız Eski Metin, "Kutools for Excel" ise yerine koymak istediğiniz Yeni Metin'dir. Bu değerleri kendi ihtiyaçlarınıza göre güncelleyin.

3. Ardından bu kodu çalıştırmak için "F5" tuşuna basın. Mesaj konularında belirtilen metin, ihtiyaç duyduğunuz şekilde Yeni Metin ile değiştirilir (ekran görüntüsüne bakın):

---

VBA kodu kullanarak birden fazla görev içindeki konu metnini Bul ve Değiştir

Görevlerdeki konu metnini Bul ve Değiştir özelliğini kullanarak değiştirmeniz gerekiyorsa, aşağıdaki VBA kodu size yardımcı olabilir.

1. "Microsoft Visual Basic for Applications" penceresini açmak için "ALT + F11" tuşlarına basın.

2. Ardından "Ekle" > "Modül" seçeneğine tıklayıp aşağıda verilen kodu açılan boş modüle kopyalayın ve yapıştırın (ekran görüntüsüne bakın):

VBA kodu: Tüm görevlerdeki konu metnini Bul ve Değiştir:

Option Explicit
Sub FindReplaceTextsInAllTaskSubjects()
Dim xPane As NavigationPane
Dim xModule As TasksModule
Dim xGroup As NavigationGroup
Dim xNavFolder As NavigationFolder
Dim xTaskItem As Outlook.TaskItem
Dim i, k As Integer
Dim xFindStr, xReplaceStr As String
Dim xTotalCount As Long
On Error Resume Next
xFindStr = InputBox("Type the words to find:", "Kutools for Outlook", xFindStr)
If Len(Trim(xFindStr)) = 0 Then Exit Sub
xReplaceStr = InputBox("Type the words to replace:", "Kutools for Outlook", xReplaceStr)
If Len(Trim(xReplaceStr)) = 0 Then Exit Sub
xTotalCount = 0
Set xPane = Outlook.Application.ActiveExplorer.NavigationPane
Set xModule = xPane.Modules.GetNavigationModule(olModuleTasks)
Set xGroup = xModule.NavigationGroups.Item(1)
For i = xGroup.NavigationFolders.Count To 1 Step -1
    Set xNavFolder = xGroup.NavigationFolders.Item(i)
    For k = xNavFolder.Folder.Items.Count To 1 Step -1
        Set xTaskItem = xNavFolder.Folder.Items(k)
        If InStr(xTaskItem.Subject, xFindStr) > 0 Then
            xTaskItem.Subject = Replace(xTaskItem.Subject, xFindStr, xReplaceStr)
            xTaskItem.Save
            xTotalCount = xTotalCount + 1
        End If
    Next
Next
MsgBox xTotalCount & " task subjects have been changed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub

3. Ardından bu kodu çalıştırmak için "F5" tuşuna basın. Bir uyarı kutusu açılacak; buraya, görev konularında aramak istediğiniz metni yazın (ekran görüntüsüne bakın):

4. "Tamam" düğmesine tıklayın. Karşınıza yeni bir uyarı kutusu çıkacak; lütfen yerine koymak istediğiniz Yeni Metni girin (ekran görüntüsüne bakın):

5. Ardından "Tamam" düğmesine tıklayın. Kaç konunun değiştirildiğini gösteren bir iletişim kutusu açılacaktır (ekran görüntüsüne bakın):

6. "Tamam" düğmesine tıklayın. Görev konularındaki Eski Metin, yeni metinlerle değiştirilecektir (ekran görüntüsüne bakın):