Outlook’ta alıcıya göre imzayı otomatik olarak nasıl değiştirebilirim?

Varsayılan olarak Outlook, kullanıcıların e-postaları farklı e-posta hesapları aracılığıyla gönderirken imzayı otomatik olarak değiştirmesine olanak tanıyan yerleşik bir özelliğe sahiptir. Ancak bu yazımızda bir adım öteye giderek, Outlook’ta **Alıcılar** alanına girilen farklı alıcılara göre imzanın nasıl otomatik olarak değiştirileceğini göstereceğiz.

Alıcılara göre imzayı VBA koduyla otomatik olarak değiştirme

---

Alıcılara göre imzayı VBA koduyla otomatik olarak değiştirme

Outlook’ta e-posta gönderirken farklı alıcılara uygun farklı imzaları otomatik olarak uygulamak için aşağıdaki adımları izleyin.

1. İlk olarak, Outlook'taki otomatik eklenen imza özelliğini devre dışı bırakmanız gerekir. Bunu yapmak için Dosya > Seçenekler seçeneğine tıklayarak Outlook Seçenekleri penceresini açın.

2. Outlook Seçenekleri penceresinde, sol bölmeden Posta bölümünü seçin, ardından İmzalar düğmesine İleti oluşturma bölümünde tıklayın. Ekran görüntüsüne bakın:

3. İmzalar ve Kişisel Belgeler iletişim kutusunda, E-posta İmzası sekmesi altında Varsayılan imzayı seçin bölümüne gidin, E-posta hesabı açılır liste kutusundan bir e-posta hesabı seçin ve ardından (hiçbiri) seçeneğini hem Yeni iletiler hem de Yanıtlar/iletme açılır liste kutularından seçin. Tüm hesaplar için bu ayarlar (hiçbiri) olana kadar bu adımları tekrarlayın. Ardından Tamam düğmesine tıklayın.

Not: Gerekli imzalarınızı bu İmzalar ve Kişisel Belgeler iletişim kutusunda da oluşturabilirsiniz.

4. Tamam düğmesine tıklayarak Outlook Seçenekleri penceresine dönün.

5. Alt+F11 tuşlarına basarak Microsoft Visual Basic for Applications penceresini açın.

6. Microsoft Visual Basic for Applications penceresinde, sol bölmede yer alan ThisOutlookSession öğesine çift tıklayarak Kod penceresini açın ve aşağıdaki VBA kodunu pencereye kopyalayın. Ekran görüntüsüne bakın:

VBA kodu: Outlook'ta alıcılara göre imzayı otomatik olarak değiştirme

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by ExtendOffice 2022/08/01
Dim xMailItem As MailItem
Dim xRecipients As Recipients
Dim xRecipient As Recipient
Dim xRcpAddress As String
Dim xSignatureFile, xSignaturePath As String
Dim xFSO As Scripting.FileSystemObject
Dim xDoc As Document
Dim xFindStr As String
On Error Resume Next
Set xFSO = New Scripting.FileSystemObject
If Item.Class <> olMail Then Exit Sub
Set xMailItem = Item
Set xRecipients = xMailItem.Recipients
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
For Each xRecipient In xRecipients
    If xRecipient.AddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Then
        xRcpAddress = xRecipient.AddressEntry.GetExchangeUser.PrimarySmtpAddress
    Else
        xRcpAddress = xRecipient.AddressEntry.Address
    End If
    Select Case xRcpAddress
        Case "Email Address 1"
            xSignatureFile = xSignaturePath & "aaa.htm"
            Exit For
        Case "Email Address 2", "Email Address 3"
            xSignatureFile = xSignaturePath & "bbb.htm"
            Exit For
        Case "Email Address 4"
            xSignatureFile = xSignaturePath & "ccc.htm"
            Exit For
    End Select
Next
VBA.DoEvents
Set xDoc = xMailItem.GetInspector.WordEditor
xFindStr = "From: " & xMailItem.Recipients.Item(1).Name & " <" & xRcpAddress & ">"
If VBA.InStr(1, xMailItem.Body, xFindStr) <> 0 Then
    xDoc.Application.Selection.HomeKey Unit:=wdStory, Extend:=wdMove
    With xDoc.Application.Selection.Find
        .ClearFormatting
        .Text = xFindStr
        .Execute Forward:=True
    End With
    With xDoc.Application.Selection
        .MoveLeft wdCharacter, 2
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
Else
    With xDoc.Application.Selection
        .EndKey Unit:=wdStory, Extend:=wdMove
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
End If
xDoc.Application.Selection.InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
End Sub

Notlar:

• 1). VBA kodunda lütfen "E-posta Adresi 1/2/3/4" ifadesini alıcıların gerçek e-posta adresleriyle değiştirin.
• 2). "aaa.htm", "bbb.htm" ve "ccc.htm" ifadeleri, ilgili alıcılara göndereceğiniz belirtilen imzalardır.
• 3). Bu durumda, "aaa" imzası "E-posta Adresi 1" adresine; "bbb" imzası ise "E-posta Adresi 2" ve "E-posta Adresi 3" adreslerine gönderilecek. "E-posta Adresi 4" ise "ccc" imzasını içeren e-postayı alacaktır. Lütfen bunları ihtiyaçlarınıza göre özelleştirin.
• 4). Bir e-postada birden fazla alıcı varsa, sistem yalnızca ilk alıcıyı dikkate alır; bu durumda diğer alıcılar da ilk alıcıyla aynı imzaya sahip e-postaları alır.

7. Ardından Araçlar > Başvurular seçeneğine tıklayarak Başvurular - Proje iletişim kutusuna gidin. İletişim kutusunda hem Microsoft Word Nesne Kitaplığı hem de Microsoft Scripting Runtime seçeneklerini işaretleyin ve ardından Tamam düğmesine tıklayın. Ekran görüntüsüne bakın:

8. Alt+Q tuşlarına basarak Microsoft Visual Basic for Applications penceresini kapatın.

Artık bir e-posta oluşturup Gönder düğmesine bastıktan sonra, ilgili imza, Alıcılar alanındaki alıcının e-posta adresine göre e-posta gövdesinin sonuna otomatik olarak eklenecektir.

---