Outlook'tan Excel'e klasör yapısı nasıl dışa aktarılır?

Bu makalede, bir hesabın Klasör Yapısı’nı Outlook’tan Excel dosyasına nasıl dışa aktaracağınızı adım adım anlatacağım. Lütfen işlemi gerçekleştirmek için bu makalenin ayrıntılarını dikkatle takip edin.

Bir hesabın Klasör Yapısı'ni Outlook'tan VBA kodu kullanarak Excel'e dışa aktarma

---

Bir hesabın Klasör Yapısı'ni Outlook'tan VBA kodu kullanarak Excel'e dışa aktarma

Aşağıdaki VBA kodu size yardımcı olabilir; lütfen aşağıdaki adımları uygulayın:

1. Excel'i etkinleştirin ve ALT + F11 tuşlarına basarak Microsoft Visual Basic for Applications penceresini açın.

2. Ekle > Modül seçeneğine tıklayın ve aşağıdaki kodu Modül penceresine yapıştırın.

VBA kodu: Bir hesabın Klasör Yapısı'ni Outlook'tan Excel'e dışa aktarma:

Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMainFolderCount As Long
Sub OutlookExportFolderStructureToExcel()
    Dim xFolder As Folder
    Dim xExcelFile As String
    Dim xFileDialog As FileDialog
    On Error Resume Next
    Set xFolder = Outlook.Application.Session.PickFolder
    If xFolder Is Nothing Then Exit Sub
    Set xExcelApp = New Excel.Application
    Set xWb = xExcelApp.Workbooks.Add
    Set xWs = xWb.Sheets(1)
    With xWs.Range("A1", "A1")
         .Value = "Folder Structure"
         .Font.Size = 14
         .Font.Bold = True
    End With
    xMainFolderCount = Len(xFolder.FolderPath) - Len(Replace(xFolder.FolderPath, "\", "")) + 1
    Call ExportToExcel(xFolder.FolderPath, xFolder.Name)
    Call ProcessFolders(xFolder.Folders)
    xWs.Columns("A").AutoFit
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogSaveAs)
    With xFileDialog
        .AllowMultiSelect = False
        .FilterIndex = 1
        If .Show = 0 Then
            xWb.Close False
            xExcelApp.Quit
            Set xExcelApp = Nothing
            Exit Sub
        End If
        xExcelFile = .SelectedItems.Item(1)
    End With
    xWb.Close True, xExcelFile
    MsgBox "Export complete!", vbExclamation, "Kutools for Outlook"
End Sub

Sub ProcessFolders(ByVal xFlds As Folders)
    Dim xSubFolder As Folder
    For Each xSubFolder In xFlds
        If xSubFolder.Name <> "Conversation Action Settings" And xSubFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(xSubFolder.FolderPath, xSubFolder.Name)
           Call ProcessFolders(xSubFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef xFolderPath As String, xFolderName As String)
    Dim i, n As Long
    Dim xPrefix As String
    Dim xLastRow As Integer
    i = Len(xFolderPath) - Len(Replace(xFolderPath, "\", "")) - xMainFolderCount
    For n = 0 To i
        xPrefix = xPrefix & "-"
    Next
    xFolderName = xPrefix & xFolderName
    xLastRow = xWs.UsedRange.Rows.Count + 1
    xWs.Range("A" & xLastRow) = xFolderName
End Sub

3.Hâlâ Microsoft Visual Basic for Applicationspenceresindeyken,Araçlar>Başvurularseçeneğine tıklayarak Başvurular - Project1iletişim kutusuna gidin ve Microsoft Excel Nesne Kitaplığıseçeneğini Kullanılabilir Başvurularlistesinden işaretleyin; ekran görüntüsüne bakın:

4. Ardından Tamam düğmesine tıklayın ve bu kodu çalıştırmak için F5 tuşuna basın. Karşınıza Klasör Seç iletişim kutusu çıkacaktır. Lütfen dışa aktarmak istediğiniz e-posta hesabını ve ilgili Klasör Yapısı’nı seçin; ekran görüntüsüne bakın:

5. Daha sonra Tamam düğmesine tıklayın; bir Dosya Kaydet penceresi görüntülenecektir. Lütfen dışa aktarılan dosya için bir konum ve dosya adı belirtin; ekran görüntüsüne bakın:

6. Son olarak, Kaydet düğmesine tıklayın ve dışa aktarılan Klasör Yapısı’nı kaydettiğiniz Excel çalışma kitabına giderek görüntüleyebilirsiniz; ekran görüntüsüne bakın: