Outlook’ta görevleri kategoriye göre nasıl yazdırabilirsiniz?

Diyelim ki Outlook görev listenizde çeşitli Renk Kategorileri var ve şimdi bu görevleri kategorilere göre ayrı sayfalarda yazdırmak istiyorsunuz. Outlook’ta bunu nasıl yapabilirsiniz?

Görevleri kategorilere göre farklı sayfalarda tek tek elle yazdırma

Görevleri kategorilere göre farklı sayfalarda VBA koduyla yazdırma

---

Görevleri kategorilere göre farklı sayfalarda tek tek elle yazdırma

Outlook’ta görevleri farklı kategorilere göre ayrı sayfalarda tek tek elle yazdırabilirsiniz. Aşağıdaki adımları izleyin:

1. Outlook'u başlatın, Görev bölmesine gidin ve yazdırmak istediğiniz görev klasörünü seçin. Ardından Ctrl + E tuşlarına basarak Arama kutusunu etkinleştirin. Daha sonra Arama sekmesinde Kategorilenmiş simgesine tıklayın ve yazdırmak istediğiniz renkli kategoriyi seçin (ekran görüntüsüne bakın):

2. Ardından, belirtilen renk kategorisine sahip tüm görevler anında listelenir (ekran görüntüsüne bakın):

3. Aşağıdaki ekran görüntüsünde gösterildiği gibi bu görev listesini yazdırmak için Dosya > Yazdır seçeneğine tıklayın:

4. Görev listelerini Diğer Renk Kategorisi ile yazdırmak için yukarıdaki adımları tek tek tekrarlayın.

---

Görevleri kategorilere göre farklı sayfalarda VBA koduyla yazdırma

Aşağıdaki VBA kodu, farklı sayfalarda kategoriye göre görevleri aynı anda yazdırmanıza yardımcı olabilir. Lütfen aşağıdaki adımları izleyin:

1. Görev bölmesine gidin ve yazdırmak istediğiniz görev klasörünü seçin.

2. Ardından, ALT + F11 tuşlarına basarak Microsoft Visual Basic for Applications penceresini açın.

3. Ardından, Ekle > Modül seçeneğine tıklayın ve aşağıdaki kodu açılan boş modüle kopyalayıp yapıştırın:

VBA kodu: Görevleri kategorilere göre farklı sayfalarda yazdırma:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Ardından, Araçlar > Başvurular seçeneğine tıklayın. Açılan Microsoft Visual Basic for Applications penceresindeki Başvurular - Proje1 iletişim kutusunda, Microsoft Excel Nesne Kitaplığı ve Microsoft Scripting Runtime seçeneklerini Kullanılabilir Başvurular listesinden işaretleyin (ekran görüntüsüne bakın):

5. Ardından, Tamam düğmesine tıklayın. Şimdi, bu kodu çalıştırmak için F5 tuşuna basın. Kod tamamlandığında, farklı kategorilere sahip görev listeleri ayrı sayfalarda yazdırılacaktır.