Outlook’ta gönderilen toplantı davetlerini otomatik olarak belirli bir klasöre nasıl taşıyabilirim?

Normalde e-postalarınızla toplantı davetiyeleriniz gönderildikten sonra her ikisi de Gönderilen Öğeler klasörüne kaydedilir. Bu da klasörünüzü gereğinden fazla kalabalıklaştırır ve kullanımı zor hale getirir. Bu makalede, gönderdiğiniz toplantı davetlerinin otomatik olarak başka bir klasöre taşınmasını sağlayacak pratik bir yöntemi sizinle paylaşacağım.

Gönderilen toplantıları VBA koduyla otomatik olarak belirli bir klasöre taşıma

---

Gönderilen toplantıları VBA koduyla otomatik olarak belirli bir klasöre taşıma

Tüm gönderilen toplantı davetlerini otomatik olarak başka bir klasöre taşımak için aşağıdaki kod size yardımcı olabilir. Lütfen aşağıdaki adımları izleyin:

1. Microsoft Visual Basic for Applications penceresini açmak için ALT + F11 tuşlarına basılı tutun.

2. Microsoft Visual Basic for Applications penceresinde, modu açmak için ThisOutlookSession öğesine Project1 (VbaProject.OTM) bölmesinden çift tıklayın ve ardından aşağıdaki kodu boş modüle kopyalayıp yapıştırın.

VBA kodu: Gönderilen toplantıları otomatik olarak belirli bir klasöre taşıma

Private WithEvents GExplorer As Outlook.Explorer
Public WithEvents GSentFolder As Outlook.Folder
Public WithEvents GSentItems As Outlook.Items
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
Dim xFolder As Folder, xRootFolder As Folder
Dim xRootFldName As String
Dim xPos As Integer
    On Error Resume Next
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    xPos = VBA.InStr(3, xFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, Len(xFolder.FolderPath) - 2)
    End If
    Set xRootFolder = Outlook.Application.Session.Folders(xRootFldName)
    Set GSentFolder = xRootFolder.Folders("Sent Items")
    Set GSentItems = GSentFolder.Items
End Sub
Private Sub GSentItems_ItemAdd(ByVal Item As Object)
    Dim xMeetingItem As Outlook.MeetingItem
    Dim xTargetFolder As Outlook.Folder
    On Error Resume Next
    If Item.Class <> olMeetingRequest Then Exit Sub
    Set xMeetingItem = Item
    Set xTargetFolder = GSentFolder.Folders("Meetings")
    If xTargetFolder Is Nothing Then
        Set xTargetFolder = GSentFolder.Folders.Add("Meetings")
    End If
    xMeetingItem.Move xTargetFolder
End Sub

3. Ardından, Kaydet ve Kapat düğmesine tıklayarak kod penceresini kapatın. Artık bir toplantı e-postası gönderildiğinde, otomatik olarak Gönderilen Öğeler klasörünün altına Meetings adlı yeni bir klasöre taşınacaktır. Ekran görüntüsüne bakın: