Outlook: Yanıt gelmezse e-postayı otomatik olarak yeniden gönderme

Bir meslektaşınıza, iş ortağınıza veya başka birine acil yanıt almanız gereken bir e-posta gönderirken, belirlenen süre içinde yanıt gelmezse e-postanın otomatik olarak yeniden gönderilmesini ayarlayabilirsiniz.

Yanıt gelmezse otomatik yeniden gönderim için Hatırlatıcı ve VBA kullanma

---

Yanıt gelmezse otomatik yeniden gönderim için Hatırlatıcı ve VBA kullanma

Bölüm 1: Belirtilen zamanda hatırlatıcı ayarlama

1. Yanıt alamazsanız, e-postayı yeniden göndermek için Gönderilen Öğeler klasöründen ilgili e-postaya sağ tıklayın ve açılan içerik menüsünden “Takip Et” > “Hatırlatıcı Ekle” seçeneğini seçin.

2. Açılan "Özel" iletişim kutusunda "Hatırlatıcı" onay kutusunun işaretli olduğundan emin olun. Ardından aşağıdaki açılır kutulardan yanıtın gelmesini istediğiniz tarih ve saati seçin veya doğrudan bu alanlara tarih ve saati yazabilirsiniz. Son olarak, "Tamam" düğmesine tıklayın.

Bölüm 2: Belirtilen sürede yanıt gelmezse e-postaları yeniden göndermek için bir VBA ekleyin

3. "Microsoft Visual Basic for Applications" penceresini açmak için "Alt" + "F11" tuşlarına basın.

4. Boş bir betik oluşturmak için "Proje – Project1" bölmesindeki "ThisOutlookSession" öğesine çift tıklayın ve aşağıdaki VBA kodunu bu boş betiğe kopyalayıp yapıştırın.

VBA: Yanıt gelmezse e-postayı yeniden gönder

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet received the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & " as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. Kodu kaydedin ve ana arayüze dönün. "Dosya" > "Seçenekler" yolunu izleyin. Açılan "Outlook Seçenekleri" penceresinde sol bölmeden "Güven Merkezi"ni seçin, ardından "Güven Merkezi Ayarları"na tıklayarak ilgili pencereyi açın. "Makro Ayarları" bölümüne gidin ve sağ tarafta yer alan "Tüm makroları etkinleştir (önerilmez; potansiyel olarak tehlikeli kodlar çalışabilir)" seçeneğinin işaretli olduğundan emin olun. Son olarak, "Tamam" > "Tamam" butonlarına tıklayarak değişiklikleri kaydedin.

6. Artık, hatırlatıcısı ayarlanmış gönderilen e-postanın belirtilen zamanı geldiğinde hâlâ yanıt almadıysanız, e-postayı yeniden gönderip göndermeyeceğinizi soran bir iletişim kutusu açılır.

7. "Evet"e tıklarsanız, önceki e-postayı içeren yeni bir ileti penceresi açılır; gövdeyi istediğiniz gibi düzenleyebilir ve e-postayı yeniden göndermek için "Gönder"e tıklayabilirsiniz.

8. "Hayır" seçeneğine tıklarsanız, hatırlatıcı silinir.

Not: Belirtilen zamandan önce e-postaya yanıt verilirse, hatırlatıcı VBA tarafından otomatik olarak kaldırılır.