Outlook'ta e-posta konusunu ek adıyla otomatik olarak nasıl doldurabilirsiniz?

Author: Siluvia Last Modified: 2025-06-10

Outlook'ta e-posta konusu olarak ek adını kullanmaya alışkın olanlar için, her seferinde konu satırına ek adını manuel olarak yazmak zaman alıcı olacaktır. Aşağıdaki gif'te gösterildiği gibi, bir ek eklediğinizde e-posta konu satırını ek adıyla otomatik olarak doldurmak istiyorsanız, bu eğitimdeki VBA yöntemi size yardımcı olacaktır.

VBA kodu ile e-posta konusunu ek adıyla otomatik olarak doldurma

Lütfen Outlook'ta eklenen ek adıyla e-posta konusunu otomatik olarak doldurmak için aşağıdaki VBA kodunu çalıştırın.

1. Outlook'unuzu başlatın ve Microsoft Visual Basic for Applications penceresini açmak için Alt + F11 tuşlarına basın.

2. Microsoft Visual Basic for Applications penceresinde, ThisOutlookSession (Kod) düzenleyicisini açmak için Project1 (VbProject.OTM) > Microsoft Outlook Nesneleri > ThisOutlookSession öğesine çift tıklayın.

3. Ardından aşağıdaki VBA kodunu ThisOutlookSession (Kod) düzenleyicisine kopyalayın.

VBA Kodu: E-posta konusunu ek adıyla otomatik doldurma

Public WithEvents GExplorer As Explorer
'Updated by Extendoffice 20220926
Public WithEvents GInspectors As Inspectors
Public WithEvents GMail As MailItem

Private Sub Application_Startup()
  Set GExplorer = Application.ActiveExplorer
  Set GInspectors = Application.Inspectors
End Sub

Private Sub GExplorer_InlineResponse(ByVal Item As Object)
  Set GMail = Item
End Sub

Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
  Dim xItem As Object
  Set xItem = Inspector.CurrentItem
  If xItem.Class <> olMail Then Exit Sub
  Set GMail = xItem
End Sub

Private Sub GMail_AttachmentAdd(ByVal Att As Attachment)
  Dim xFileName As String
  On Error Resume Next
  If VBA.Trim(GMail.Subject) <> "" Then Exit Sub
  If MsgBox("Do you want to use the attachment name as the subject?", vbYesNo + vbInformation, "Kutools for Outlook") = vbNo Then Exit Sub
  xFileName = Att.DisplayName
  xFileName = Left$(xFileName, VBA.InStrRev(xFileName, ".") - 1)
  GMail.Subject = xFileName
End Sub

doc-autofill-subject-line-with-attachment-name-2

4. Şimdi kodu kaydetmeniz ve Outlook'u yeniden başlatmanız gerekiyor.

5. Artık, henüz bir konu doldurulmamış bir e-postaya ek eklediğinizde, ek adını konu olarak kullanmak isteyip istemediğinizi soran bir Kutools for Outlook iletişim kutusu açılacak, Evet düğmesine tıklayın.

doc-autofill-subject-line-with-attachment-name-3

Ardından, konu satırı, eklenen ek adıyla otomatik olarak doldurulacaktır.

doc-autofill-subject-line-with-attachment-name-4

Notlar:

1) Eğer konuyu zaten doldurduysanız, ek ekleme işlemi iletişim kutusunu açmayacaktır.

2) Eğer mevcut konuyu geçerli e-postadan kaldırırsanız ancak imleç hala konu satırında görünüyorsa, ek ekleme işlemi iletişim kutusunu açmayacaktır. Konuyu kaldırdıktan sonra, kodun çalışması için ileti kutusunu yenilemek üzere konu satırından başka bir yere tıklamanız gerekir.

3) Aynı anda birden fazla ek eklerseniz, yalnızca ilk ek adı e-posta konusu olarak kullanılabilir.

Outlook'daki AI Mail Asistanı: Daha Akıllı Yanıtlar, Daha Açık İletişim (tek tıklama sihirbazlığı!) ÜCRETSİZ

Kutools for Outlook'un AI Mail Asistanı ile günlük Outlook görevlerinizi kolaylaştırın. Bu güçlü araç, geçmiş e-postalarınızdan öğrenerek size akıllı ve doğru yanıtlar sunar, e-posta içeriğinizi optimize eder ve mesaj taslaklarını hazırlamada ve geliştirmede size yardımcı olur.

Bu özellik şunları destekler:

Akıllı Yanıtlar: Geçmiş konuşmalarınızdan oluşturulan, kişiselleştirilmiş, kesin ve kullanıma hazır yanıtlar alın.
Geliştirilmiş İçerik: E-posta metniniz otomatik olarak netlik ve etki için iyileştirilir.
Kolay Taslak Oluşturma: Sadece anahtar kelimeler sağlayın ve AI'nın gerisini halletmesine izin verin; birden fazla yazım stiliyle.
Akıllı Genişletmeler: Bağlam farkındalığına sahip önerilerle düşüncelerinizi genişletin.
Özetleme: Uzun e-postaların kısa ve öz bir özetini anında alın.
Küresel Kapsam: E-postalarınızı herhangi bir dile kolayca çevirin.

Bu özellik şunları destekler: