Outlook'ta belirli bir etki alanına göre e-posta adresleri nasıl dışa aktarılır?

Outlook'unuzdaki tüm kişilerden belirli bir etki alanına sahip e-posta adreslerini dışa aktarmak istiyorsanız, lütfen aşağıda gösterilen ekran görüntüsü gibi belirli bir etki alanındaki tüm e-posta adreslerini bir metin dosyasına çıkarmak için bir VBA kodu uygulamanıza yardımcı olacak bu öğreticiyi okuyun. .

VBA koduyla Outlook'ta belirli etki alanına dayalı olarak e-posta adreslerini dışa aktarın

Tüm kişilerden belirli bir etki alanına sahip tüm e-posta adreslerini çıkarmak için lütfen aşağıdaki adımları uygulayın:

1. Yeni bir metin dosyası oluşturun ve ona bir ad verin, ekran görüntüsüne bakın:

2. Basılı tutun ALT + F11 tuşlarını açmak için Uygulamalar için Microsoft Visual Basic pencere.

3. Daha sonra, Ekle > modülve aşağıdaki kodu Modül Penceresine yapıştırın.

VBA kodu: E-posta adreslerini belirli bir alana göre dışa aktarın

Dim GDomain As String
Dim GFileSystem As Object
Dim GFilePath As String
Dim GFileObj As Object
Private Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, _
  ByVal ipOperation As String, ByVal lpFile As String, _
  ByVal lpParameters As String, ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long

Sub ExportListOfEmailAddressesInSpecificDomain()
'Updateby ExtendOffice
Dim xStore As Store
Dim xFolder As Folder
On Error Resume Next
GDomain = InputBox("Enter domain(@***.com):", "Kutools for Outlook")
If Len(GDomain) <> 0 Then
  GFilePath = "C:\Users\skyyang\Desktop\Email Addresses with specific domain.txt" 'Specify the file path
  Set GFileSystem = CreateObject("Scripting.FileSystemObject")
  Set GFileObj = GFileSystem.CreateTextFile(GFilePath, True)
  For Each xStore In Application.Session.Stores
    For Each xFolder In xStore.GetRootFolder.Folders
      If xFolder.DefaultItemType = olContactItem Then
        Call ProcessFolders(xFolder)
      End If
    Next
  Next
  GFileObj.Close
  ShellExecute 0&, vbNullString, GFilePath, vbNullString, vbNullString, 1
End If
End Sub

Sub ProcessFolders(ByVal Fld As Outlook.Folder)
Dim xContactItems As Items
Dim I As Long
Dim xContact As ContactItem
Dim xSubFolder As Folder
On Error Resume Next
Set xContactItems = Fld.Items
For I = xContactItems.Count To 1 Step -1
  If xContactItems(I).Class = olContact Then
    Set xContact = xContactItems(I)
    If InStr(xContact.Email1Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email1Address & vbCrLf)
    ElseIf InStr(xContact.Email2Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email2Address & vbCrLf)
    ElseIf InStr(xContact.Email3Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email3Address & vbCrLf)
    End If
  End If
Next
If Fld.Folders.Count > 0 Then
  For Each xSubFolder In Fld.Folders
    If xSubFolder.DefaultItemType = olContactItem Then
      Call ProcessFolders(xSubFolder)
    End If
  Next
End If
End Sub

not: Yukarıdaki kodda dosya yolunu değiştirin "C:\Users\skyyang\Desktop\Belirli domain.txt ile E-posta Adresleri" kendi başına.

4. Ve sonra F5 Bu kodu çalıştırmak için anahtar. Bir istem kutusu açılır, lütfen e-posta adreslerini temel alarak dışa aktarmak istediğiniz e-posta alanını yazın, ekran görüntüsüne bakın: