Outlook: Toplantıyı iptal ettikten sonra takvimde düzenleyici olarak nasıl bırakılır?

Outlook’ta bir Toplantı Düzenleyicisi olarak bir toplantıyı iptal ettiğinizde, bu toplantı otomatik olarak takviminizden silinir. Ancak bazı durumlarda, iptal edilen toplantıları takvimde işaretli olarak saklamak isteyebilirsiniz. Ne yazık ki Outlook’un bu işlevi yerine getirebilecek yerleşik bir özelliği yoktur. Bu eğitimde, toplantıyı iptal ederken aynı zamanda randevu olarak takvimde saklamanızı sağlayacak iki VBA kodu sunulmaktadır.

İptal edilen toplantıyı randevu olarak kopyalamak için VBA kodları

---

İptal edilen toplantıyı randevu olarak kopyalamak için VBA kodları

Toplantıyı iptal ederken aynı anda kopyalayıp randevu olarak yapıştırmak için burada iki kod bulunuyor.

Not: Kodu etkinleştirmeden önce aşağıdaki iki seçeneğin işaretli olduğundan emin olun:

Outlook'u açın, Dosya > Seçenekler öğesine tıklayın. Outlook Seçenekleri penceresinde, Güven Merkezi sekmesine tıklayın ve ardından Güven Merkezi Ayarları'na tıklayın. Güven Merkezi penceresinde, Makro Ayarları sekmesine tıklayıp Tüm makroları etkinleştir (önerilmez; potansiyel olarak tehlikeli kodlar çalışabilir) ve Makro güvenlik ayarlarını yüklü eklentilere uygula seçeneklerini işaretleyin. Ardından Tamam > Tamam'a tıklayarak bu pencereyi kapatın. Outlook'u yeniden başlatın.

1. Outlook Takvim görünümüne geçin ve iptal etmek istediğiniz toplantıyı seçin. Microsoft Visual Basic for Applications penceresini açmak için Alt+F11 tuşlarına basın.

2. Yeni bir boş modül eklemek için Ekle > Modül seçeneğine tıklayın. Ardından aşağıdaki kodu kopyalayıp yapıştırın.

Kod: Toplantıyı randevu olarak kopyala ve iptal et

Sub CopyMeetingAsAppointmentBeforeCancel()
'UpdatebyExtendoffice20221129
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move Application.ActiveExplorer.CurrentFolder
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

3. Çalıştır düğmesine tıklayın veya F5 tuşuna basın. Artık seçili toplantı iptal edilmiş ve «Canceled & Subject» adında bir randevu oluşturulmuştur.

Toplantıyı başka bir takvimde randevu olarak kopyalayıp yapıştırmak ve ardından toplantıyı iptal etmek istiyorsanız aşağıdaki kodu kullanın:

Kod: Toplantıyı başka bir takvimde randevu olarak kopyala ve iptal et

Sub CopyMeetingAsAppointmentToCalenderBeforeCancel()
'Updatebyextendoffice20221129
Dim xDestCalendar As Outlook.MAPIFolder
Dim xNameSpace As Outlook.NameSpace
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xNameSpace = Application.GetNamespace("MAPI")
Set xDestCalendar = xNameSpace.PickFolder
If xDestCalendar.DefaultItemType <> olAppointmentItem Then
  MsgBox "Please Select calendar folder. ", vbOKOnly + vbInformation, "Kutools for Outlook"
  Exit Sub
End If
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move xDestCalendar
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xDestCalendar = Nothing
Set xNameSpace = Nothing
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

Çalıştır düğmesine tıklayın veya F5 tuşuna basın. Randevuyu yapıştırmak için bir takvim klasörü seçmenizi sağlayacak bir Klasör Seç iletişim kutusu açılacaktır; ardından Tamam’a tıklayın.

Toplantı artık iptal edilmiş ve seçtiğiniz takvim klasörüne randevu olarak kopyalanıp yapıştırılmıştır.