Ana içeriğe atla

Benzersiz ve farklı değerleri kolayca sayın – 7 örnek

Yazar: Xiaoyang Son Değiştirilme Tarihi: 2023-11-10

Normalde, Excel'de benzersiz değerler, herhangi bir yineleme olmadan listede yalnızca bir kez görünen değerlerdir ve farklı değerler, tüm farklı değerlerdir (benzersiz değerler + 1. yinelenen oluşumlar). Büyük bir veri kümesi üzerinde çalışırken, aşağıda gösterilen ekran görüntüsü gibi bir hücre listesinden kopyalar arasındaki benzersiz ve farklı değerlerin sayısını saymanız gerekebilir. Bu öğretici, Excel'deki benzersiz ve farklı değerleri saymak için bazı hızlı püf noktaları tanıtacaktır.

Excel'de benzersiz değerleri sayın

Excel'de farklı değerleri sayın (benzersiz ve 1. yinelenen oluşumlar)

Örnek dosyayı indirin

Benzersiz farklı değerleri sayın

Excel'de benzersiz değerleri sayın

Bu bölüm, bir listedeki metinler ve sayılar dahil olmak üzere benzersiz değerlerin sayısını saymak için bazı formül örneklerinden bahsedecektir.

Benzersiz değerleri formüllerle sayın

Diyelim ki, isim listesinde bazı yinelenen isimler içeren bir isim listem var. Şimdi, aşağıda gösterilen ekran görüntüsü gibi yalnızca (sarı renkle doldurulmuş) benzersiz adların sayısını almam gerekiyor:

Bu sorunu çözmek için aşağıdaki dizi formülü size bir iyilik yapabilir:

1. Adım: Formülü girin

Aşağıdaki formülü, sonucun çıktısını almak istediğiniz boş bir hücreye girin veya kopyalayın:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
 not: Yukarıdaki formülde, A2: A12 benzersiz saymak istediğiniz veri listesidir.

Adım 2: Basın Ctrl + Üst Karakter + Enter Doğru sonucu almak için tuşlar:

İpuçları:

  1. Hücre listeniz sayılar, Boolean'lar, hata değerleri vb. gibi başka veri türleri içeriyorsa, yukarıdaki formülü uygularken, veri türünden bağımsız olarak benzersiz değerlerin sayısını alır.
  2. Veri listesi boş hücreler içerdiğinde, bu formül boş hücreleri hariç tutar.
  3. için yalnızca benzersiz metin değerlerini say başka veri türü varsa, lütfen aşağıdaki dizi formülünü uygulayın ve ardından Ctrl + Üst Karakter + Enter sonucu döndürmek için tuşlar: 
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. için yalnızca benzersiz sayıları say herhangi bir türde veri içeren bir hücre listesinden, lütfen aşağıdaki dizi formülünü kullanın ve ardından Ctrl + Üst Karakter + Enter sonucu döndürmek için tuşlar: 
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Kutools for Excel tarafından birkaç tıklamayla benzersiz değerleri sayın

Bir dahaki sefere uygulamanız gerektiğinde formülleri hatırlamanız size acı verebilir. Ama eğer varsa Kutools for Excel, Onun ile Benzersiz Değerleri Say seçeneği Formül Yardımcısı, sadece birkaç tıklama ile sonuca ulaşabilirsiniz. Aşağıdaki demoya bakın:

  1. Sonucu çıkarmak için bir hücreye tıklayın;
  2. tıklayarak bu özelliği etkinleştirin Kutools > Formül Yardımcısı > Formül Yardımcısı > Istatistiksel > Benzersiz değerleri sayın;
  3. Veri listesini seçin > OK.
İpuçları:
  1. Bu özelliği uygulamak için yapmanız gerekenler indir ve yükle birinci olarak.
  2. The Formül Yardımcısı özelliği, 40'tan fazla yaygın olarak kullanılan formülü toplar, örneğin Benzersiz değerleri çıkarın, Benzersiz değerlere sahip hücreleri ayıklayın (ilk kopyaları dahil edin), Virgülle ayrılmış değerlerin sayısını sayın, Aynı metne dayalı toplam, ve dahası...

Formüllerle Excel 365/2021'de benzersiz değerleri sayın

Excel 365 veya Excel 2021 kullanıyorsanız, bir veri kümesindeki benzersiz değerleri saymak için daha basit formüller oluşturmanıza yardımcı olabilecek yeni bir UNIQUE işlevi vardır.

Örneğin, A2:A12 aralığındaki benzersiz adların sayısını saymak için lütfen aşağıdaki formülü girin:

1. Adım: Aşağıdaki formülü kopyalayın veya girin

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
not: Bu formülde, A2: A12 benzersiz değerleri saymak istediğiniz veri listesidir.

Adım 2: Basın Keşfet sonucu almanın anahtarı:

İpuçları:

  1. Veri listesi metin, sayılar, Boolean'lar, hata değerleri vb. gibi başka veri türleri içeriyorsa, bu formül, veri türünden bağımsız olarak benzersiz değerlerin sayısını alır.
  2. Yukarıdaki formül, boş hücreler dahil olmak üzere benzersiz değerleri sayar, boşlukları hariç tutmak istiyorsanız, lütfen aşağıdaki formülü uygulayın ve sadece tuşuna basmanız yeterlidir. Keşfet anahtar: 
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Excel'de farklı değerleri sayın (benzersiz ve 1. yinelenen oluşumlar)

Bir hücre listesindeki farklı değerleri (benzersiz değerler ve 1. yinelenen oluşumlar) saymak için burada, bu görevi gerçekleştirmek için başka formüller tanıtacağım.

Formüllerle farklı değerleri sayın

Excel'de, farklı değerlerin sayısını döndürmek için aşağıdaki formüllerden herhangi birini uygulayabilirsiniz.

1. Adım: Aşağıdaki formüllerden herhangi birini girin

Formül 1: Formülü girdikten sonra tuşuna basın. Keşfet tuşuna basın.

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

Formül 2: Formülü girdikten sonra tuşuna basın. Ctrl + Üst Karakter + Enter anahtarlar.

=SUM(1/COUNTIF(A2:A12,A2:A12))
not: Bu formüllerde, A2: A12 farklı değerleri saymak istediğiniz veri listesidir.

Sonuç:

İpuçları:

  1. Veri listesi sayılar, Boolean'lar, hata değerleri vb. gibi başka veri türleri içeriyorsa, bu formül, veri türünden bağımsız olarak farklı değerleri alır.
  2. Yukarıdaki formülü kullanırken, veri listesi boş hücreler içeriyorsa #DIV/0 hata değeri alırsınız. Boş hücreleri düzeltmek ve yoksaymak için, aşağıdaki formüllerden birini uygulamalısınız:
    Formula 1: Formülü girdikten sonra tuşuna basın. Keşfet tuşuna basın. 
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    Formula 2: Formülü girdikten sonra tuşuna basın. Ctrl + Üst Karakter + Enter anahtarlar. 
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

  3. için yalnızca farklı metin değerlerinin sayısını al bir veri listesinde, lütfen aşağıdaki dizi formülünü uygulayın ve Ctrl + Üst Karakter + Enter sonucu almak için tuşlar: 
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. için yalnızca farklı sayısal değerleri say, lütfen aşağıdaki dizi formülünü kullanın ve Ctrl + Üst Karakter + Enter sonucu almak için tuşlar: 
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Kutools for Excel tarafından birkaç tıklama ile farklı değerleri sayın

Çalışma kitabınızda formülleri sık sık uygulamanız gerekiyorsa, bir dahaki sefere uygulamanız gerektiğinde formülleri hatırlamak sizin için acı verici olabilir. Ama eğer varsa Kutools for Excel, Onun ile Benzersiz değerlere sahip hücreleri sayın (ilk kopyayı dahil edin) seçeneği Formül Yardımcısı, sonucu yalnızca birkaç tıklamayla alabilirsiniz. Aşağıdaki demoya bakın:

  1. Sonucu çıkarmak için bir hücreye tıklayın;
  2. tıklayarak bu özelliği etkinleştirin Kutools > Formül Yardımcısı > Istatistiksel > Benzersiz değerlere sahip benzersiz hücreleri sayın (ilk kopyayı dahil edin);
  3. Veri listesini seçin > OK.
İpuçları:
  1. Bu özelliği uygulamak için yapmanız gerekenler indir ve yükle birinci olarak.
  2. The Formül Yardımcısı özelliği, 40'tan fazla yaygın olarak kullanılan formülü toplar, örneğin Benzersiz değerleri çıkarın, Benzersiz değerlere sahip hücreleri ayıklayın (ilk kopyaları dahil edin), Virgülle ayrılmış değerlerin sayısını sayın, Aynı metne dayalı toplam, ve dahası...

PivotTable ile farklı değerleri sayın

Excel'de PivotTable, bir veri listesinden farklı değerlerin sayısını almanıza da yardımcı olabilir, lütfen aşağıdaki adımları izleyin:

1. Adım: Bir pivot tablo oluşturun

  1. Veri listesini seçin ve ardından Ekle > Pivot tablo şeritten, ekran görüntüsüne bakın:
  2. Dışarı fırladı Pivot tablo tablodan veya aralık iletişim kutusundan:
    (1). Pivot tabloyu yerleştirmek istediğiniz yeni bir çalışma sayfası veya mevcut çalışma sayfası seçin;
    (2). Sonra kontrol et Bu verileri Veri Modeline ekleyin onay kutusunu işaretleyin.
    (3). Sonra tıklayın OK düğmesine basın.

2. Adım: Alanı düzenleyin ve Farklı Sayı seçeneğini belirleyin

  1.  A Özet Tablo Alanları bölmesi görüntülenir, sürükleyin İsimler için alan Değerler alan, aşağıdaki demoya bakın:
  2. Sonra, tıklayın İsim Sayısı açılır ve seçin Değer Alanı Ayarları, ekran görüntüsüne bakın:
  3. Ve sonra Değer Alanı Ayarları iletişim kutusu açılacak, seçin Ayırt Edici Sayım altındaki liste kutusundan Değeri Özetle sekmesini tıklayın ve tıklayın. OK düğmesi, ekran görüntüsüne bakın:

Sonuç:

Şimdi, oluşturulan pivot tablo, aşağıda gösterilen ekran görüntüsü gibi veri listesinin farklı sayısını gösterecektir:

İpuçları:

  1. Kaynak verilerinizi güncellerseniz, en son sayıyı almak için pivot tabloya sağ tıklamanız ve Yenile seçeneği.
  2. Bu Ayırt Edici Sayım seçeneği yalnızca Excel 2013 ve sonrasında mevcuttur.

Formüllerle Excel 365/2021'de farklı değerleri sayın

Excel 365 veya Excel 2021'de, kolay bir formül oluşturmak için yeni UNIQUE işlevini normal COUNTA işleviyle birlikte kullanabilirsiniz.

Lütfen aşağıdaki formülü kopyalayın veya boş bir hücreye girin ve tuşuna basın. Keşfet sonucu almanın anahtarı:

=COUNTA(UNIQUE(A2:A12))
not: Bu formülde, A2: A12 farklı değerleri saymak istediğiniz veri listesidir.

İpuçları:

  1. Veri listesi metin, sayılar, Boolean'lar, hata değerleri vb. gibi başka veri türleri içeriyorsa, bu formül, veri türünden bağımsız olarak farklı değerlerin sayısını sayar.
  2. Yukarıdaki formül, boş hücreler de dahil olmak üzere farklı değerleri sayacaktır, boşlukları hariç tutmak istiyorsanız, lütfen aşağıdaki formülü uygulayın ve tuşuna basın. Keşfet sonucu almanın anahtarı: 
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

İlgili Makaleler:

  • Pivot tablodaki benzersiz değerleri sayın
  • Varsayılan olarak, bazı yinelenen değerler içeren bir dizi veriye dayalı bir pivot tablo oluşturduğumuzda, tüm kayıtlar da sayılacaktır, ancak bazen, doğru olanı elde etmek için tek bir sütuna göre benzersiz değerleri saymak istiyoruz ekran görüntüsü sonucu. Bu yazımda pivot tablodaki benzersiz değerlerin nasıl sayılacağından bahsedeceğim.
  • Filtrelenmiş bir sütundaki benzersiz değerleri sayın
  • Filtrelenmiş bir sütunda bazı kopyalarla doldurulmuş bir ad listeniz varsa ve şimdi, benzersiz adların sayısını yalnızca bu filtrelenmiş listeden saymak istiyorsunuz. Excel'de bu işle hızlı bir şekilde başa çıkmak için iyi bir çözümünüz var mı?
  • Birden çok ölçüte sahip benzersiz değerleri sayın
  • İşte birkaç isim, proje ve konum içeren bir dizi veri ve yapılması gereken, listedeki kriterlere uyan isimleri bulmak ve ardından her eşleşen isimleri yalnızca aşağıda gösterilen ekran görüntüsü gibi bir kez saymak. Bu işi çözmek için herhangi bir numaranız var mı? Bu yazıda püf noktaları tanıtacağım.
  • Benzersiz değerleri birleştirme
  • Bazı yinelenen verilerle doldurulmuş uzun bir değerler listem varsa, şimdi yalnızca benzersiz değerleri bulmak ve ardından bunları tek bir hücreye birleştirmek istiyorum. Excel'de bu sorunu hızlı ve kolay bir şekilde nasıl çözebilirim?
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Guest
Posting as Guest
×
Rate this post:
Reset
0   Characters
Suggested Locations