Bir sütundaki benzersiz sayısal değerleri veya tarihleri sayma

Diyelim ki, bazı yinelenenler içeren bir sayı listesi var ve bu listedeki benzersiz değerlerin sayısını veya yalnızca bir kez görünen değerleri aşağıdaki ekran görüntüsünde gösterildiği gibi saymak istiyorsunuz. Bu makalede, Excel'de bu görevi hızlı ve kolay bir şekilde çözmek için kullanabileceğiniz bazı faydalı formüllerden bahsedeceğiz.

• Excel 2019, 2016 ve önceki sürümlerde bir sütundaki benzersiz sayısal değerleri veya tarihleri sayma
  • Bir sütundaki benzersiz sayısal değerleri veya tarihleri sayma
  • Bir sütunda yalnızca bir kez görünen benzersiz sayısal değerleri veya tarihleri sayma
• Excel 365'te bir sütundaki benzersiz sayısal değerleri veya tarihleri sayma
  • Bir sütundaki benzersiz sayısal değerleri veya tarihleri sayma
  • Bir sütunda yalnızca bir kez görünen benzersiz sayısal değerleri veya tarihleri sayma

Excel 2019, 2016 ve önceki sürümlerde bir sütundaki benzersiz sayısal değerleri veya tarihleri sayma

Excel 2019, 2016 ve daha eski sürümleri kullanıyorsanız, benzersiz değerlerin sayısını veya yalnızca bir kez görünen değerleri elde etmek için normal SUM, FREQUENCY, IF, COUNTIF, ISNUMBER fonksiyonlarını uygulayabilirsiniz.

Bir sütundaki benzersiz sayısal değerleri veya tarihleri sayma

Bir listeden benzersiz sayıları saymak için, SUM ve FREQUENCY fonksiyonları işinizi görebilir, genel sözdizimi şu şekildedir:

• range: Benzersiz değerleri saymak istediğiniz veri sütunu.

Lütfen sonucu almak için aşağıdaki formülü boş bir hücreye girin veya kopyalayın ve ardından Enter tuşuna basın:

Formül açıklaması:

=SUM(--(FREQUENCY(A2:A12,A2:A12)>0))

• FREQUENCY(A2:A12,A2:A12): FREQUENCY fonksiyonu, A2:A12 listesindeki her sayısal değerin sayısını döndürür ve şu şekilde bir dizi elde eder: {1;2;0;2;0;1;1;3;0;0;1;0}. Dizideki sayılar, değerlerin sütunda kaç kez göründüğünü gösterir. Dizideki 0'lar, sayıların zaten veri aralığında göründüğünü gösterir.
• --(FREQUENCY(A2:A12,A2:A12)>0=--({1;2;0;2;0;1;1;3;0;0;1;0})>0: Dizideki her değer sıfırla karşılaştırılır: eğer sıfırdan büyükse, TRUE görüntülenir, aksi takdirde FALSE görüntülenir. Ardından, çift negatif işaret, TRUE ve FALSE'ları 1 ve 0'lara dönüştürür, böylece şu sonucu döndürür: {1;1;0;1;0;1;1;1;0;0;1;0}.
• SUM(--(FREQUENCY(A2:A12,A2:A12)>0))=SUM({1;1;0;1;0;1;1;1;0;0;1;0}): Son olarak, SUM fonksiyonu dizideki tüm değerleri toplar ve sonucu elde eder: 7.

Bir sütunda yalnızca bir kez görünen benzersiz sayısal değerleri veya tarihleri sayma

Bir listeden yalnızca bir kez görünen benzersiz sayısal değerleri saymak için, formülü oluşturmak üzere SUM, IF, ISNUMBER ve COUNTIF fonksiyonlarını birleştirmeniz gerekir, genel sözdizimi şu şekildedir:

• range: Benzersiz değerleri saymak istediğiniz veri sütunu.

Şimdi lütfen aşağıdaki formülü boş bir hücreye girin veya kopyalayın ve ardından doğru sonucu almak için Ctrl + Shift + Enter tuşlarına aynı anda basın:

Formül açıklaması:

=SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

• ISNUMBER(A2:A12): Bu ISNUMBER fonksiyonu, A2:A12 listesindeki değerlerin sayı olup olmadığını kontrol etmek için kullanılır. Bir hücre sayısal bir değer içeriyorsa TRUE, değilse FALSE döndürür. Böylece şu şekilde bir dizi elde edersiniz: {TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}.
• COUNTIF(A2:A12,A2:A12): COUNTIF fonksiyonu, belirli bir aralıkta her değerin kaç kez göründüğünü sayar, şu sonucu döndürür: {1;2;2;2;2;1;1;3;3;3;1}.
• ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)= {TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}* {1;2;2;2;2;1;1;3;3;3;1}: Bu iki ifade çarpılarak şu sonuç elde edilir: {1;2;2;2;2;1;1;3;3;3;1}.
• IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0)=IF({1;2;2;2;2;1;1;3;3;3;1}=1,1,0): Burada IF fonksiyonu, dizideki her değeri 1'e eşit olup olmadığını kontrol eder: Eğer evetse, 1 sayısı döndürülür; değilse, 0 sayısı görüntülenir. Sonuç şu şekilde olacaktır: {1;0;0;0;0;1;1;0;0;0;1}.
• SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))=SUM({1;0;0;0;0;1;1;0;0;0;1}): Son olarak, SUM fonksiyonu dizideki değerleri toplar ve benzersiz değerlerin toplam sayısını döndürür: 4.

Excel 365'te bir sütundaki benzersiz sayısal değerleri veya tarihleri sayma

Excel 365'te, UNIQUE adında yeni ve kolay bir fonksiyon bulunmaktadır. Bu fonksiyonu COUNT fonksiyonu içinde kullanarak bu görevi hızlı bir şekilde gerçekleştirebilirsiniz.

Bir sütundaki benzersiz sayısal değerleri veya tarihleri sayma

Excel 365'te benzersiz sayısal değerleri veya tarihleri saymak için genel sözdizimi şu şekildedir:

• range: Benzersiz değerleri saymak istediğiniz veri sütunu.

Lütfen aşağıdaki formülü boş bir hücreye girin veya kopyalayın ve sonucu almak için Enter tuşuna basın, ekran görüntüsüne bakınız:

Formül açıklaması:

=COUNT(UNIQUE(A2:A12))

• UNIQUE(A2:A12): Bu UNIQUE fonksiyonu, listeden tüm benzersiz değerleri çıkarır ve şu şekilde bir dizi listesi elde edersiniz: {258;560;774;801;985;990;1569}.
• COUNT(UNIQUE(A2:A12))=COUNT({258;560;774;801;985;990;1569}): Bu COUNT fonksiyonu sayısal değerlerin sayısını sayar ve sonucu döndürür: 7.

Bir sütunda yalnızca bir kez görünen benzersiz sayısal değerleri veya tarihleri sayma

Bu UNIQUE fonksiyonu ayrıca bir listeden tam olarak bir kez görünen benzersiz değerleri de çıkarabilir, genel sözdizimi şu şekildedir:

• range: Benzersiz değerleri saymak istediğiniz veri sütunu.

Sonucu döndürmek istediğiniz hücreye aşağıdaki formülü girin veya kopyalayın ve ardından Enter tuşuna basın, ekran görüntüsüne bakınız:

Formül açıklaması:

=COUNT(UNIQUE(A2:A12,0,1))

• UNIQUE(A2:A12,0,1): Bu UNIQUE fonksiyonu, listeden yalnızca bir kez görünen benzersiz değerleri çıkarır ve şu şekilde bir dizi listesi elde edersiniz: {258;801;985;1569}.
• COUNT(UNIQUE(A2:A12,0,1))=COUNT({258;801;985;1569}): Bu COUNT fonksiyonu sayısal değerlerin sayısını sayar ve sonucu döndürür: 4.

İpuçları: Yukarıdaki tüm formüller, bir sütundaki benzersiz tarihleri saymak için kullanılabilir.

İlgili kullanılan fonksiyonlar:

Daha fazla makale: