Excel'de bir yoldan dosya adını çıkarma

Bu öğretici, Excel'de belirli bir hücredeki dosya yolundan uzantılı ya da uzantısız dosya adlarını ayıklamak için formüllerin nasıl kullanılacağını gösterir.

Yoldan uzantılı dosya adını çıkarma
Yoldan uzantısız dosya adını çıkarma

Yoldan uzantılı dosya adını çıkarma

Aşağıdaki ekran görüntüsünde gösterildiği gibi, farklı dosya yollarını içeren bir liste bulunmaktadır; yalnızca uzantılı dosya adlarını çıkarmak istiyorsanız aşağıdaki formül bu sorunu çözmenize yardımcı olacaktır.

Genel formül

=MID(A1,FIND("*",SUBSTITUTE(A1,"\","*",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1))

Bağımsız değişkenler

Bu formülü nasıl kullanırsınız?

1. Dosya adının görüntüleneceği boş bir hücre seçin. Bu örnekte D3 hücresini seçtik.

2. Aşağıdaki formülü girin ve Enter tuşuna basın. Sonuç hücresini seçtikten sonra, diğer hücrelere uygulamak için Dolgu Kulpu’nu aşağıya doğru sürükleyin.

=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))

Artık belirtilen dosya yolu içindeki tüm uzantılı dosya adları, yukarıdaki ekran görüntüsünde gösterildiği gibi çıkarılmıştır.

Notlar:

• Bu formülde B3 hücresi, dosya yolunu içerir. Gerekirse bunu güncelleyin.
• Dosya adı uzunluğu 99 karakteri geçmiyorsa, sorunu çözmek için aşağıdaki daha kısa formülü de kullanabilirsiniz. Aşağıdaki ekran görüntüsünü inceleyin.
  =TRIM(RIGHT(SUBSTITUTE(A2,"\",REPT(" ",100)),99))
  

Bu formül nasıl işler?

=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))

1. FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))

• LEN(B3): LEN işlevi, "D:\\files\work\Q1\Jan\text.txt" içindeki toplam uzunluğu hesaplar ve sonucu 30 olarak döndürür;
• LEN(SUBSTITUTE(B3,"\",""))SUBSTITUTE işlevi, "\" karakterini hiçbir şeyle değiştirerek "D:filesworkQ1Jantext.txt" sonucunu verir. Ardından LEN işlevi, "D:filesworkQ1Jantext.txt" ifadesinin uzunluğunu hesaplar ve 24 sonucunu döndürür.
• SUBSTITUTE(B3,"\","*",30-24)SUBSTITUTE işlevi, "D:\\files\work\Q1\Jan\text.txt" yolundaki üçüncü "\" işaretini (30 - 24 = 6. konumda) tek bir "*" karakteriyle değiştirir; sonuç olarak "D:\\files\work\Q1\Jan*text.txt" elde edilir.
• FIND("*","D:\\files\work\Q1\Jan*text.txt")FIND işlevi, "D:\\files\\work\\Q1\\Jan*text.txt" içinde "*" karakterinin konumunu belirler ve sonuç olarak 22 değerini döndürür. Bu da "*" karakterinin ilgili dosya yolundaki 22. konumda bulunduğu anlamına gelir.

2. =MID(B3,22+1,LEN(B3))

• Yukarıdaki açıklamada gösterildiği gibi, LEN(B3) fonksiyonu 30 sonucunu verir; bu durumda MID fonksiyonu =MID("D:\\files\work\Q1\Jan\text.txt",23,30) şeklinde ifade edilebilir. Bu, MID fonksiyonunun "D:\\files\work\Q1\Jan\text.txt" metninin 23. karakterinden başlayarak 30 karakterini alması anlamına gelir. Sonuç ise “text.txt”tir.

Yoldan uzantısız dosya adını çıkarma

Başka bir senaryoda, aşağıdaki ekran görüntüsünde gösterildiği gibi dosya yolundan yalnızca uzantısız dosya adını çıkarmanız gerekebilir. Bu bölüm, bu işlemi gerçekleştirmenize yardımcı olacak kapsamlı bir formül sunar.

Genel formül

=IFERROR(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(A1,".",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))-1),"")

Bağımsız değişkenler

Bu formülü nasıl kullanırsınız?

1. Uzantısız dosya adının görüntüleneceği boş bir hücre seçin.

2. Aşağıdaki formülü girin ve Entertuşuna basın. Sonuç hücresini seçtikten sonra, diğer hücrelere uygulamak için Dolgu Kulpu'nı aşağıya doğru sürükleyin.

=IFERROR(MID(B4,FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(B4,".",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,".",""))))-FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))-1),"")

Not: Bu formülde B3 hücresi, dosya yolunu içerir. Gerekirse bunu güncelleyin.

İlgili işlevler

İlgili formüller