{"segments": ["KutoolsforOffice — Tek çözüm, beş güçlü araç."]}{"segments": ["Daha az çabayla daha fazlasını başarmak."]}

Metni Çıkart metin dizelerinde ilk ve ikinci virgül arasında

YazarXiaoyang Değiştirme Tarihi

Bu öğretici, metin dizelerinden ilk ile ikinci virgül veya ikinci ile üçüncü virgül arasındaki metni çıkarmak için Excel’de kullanılabilecek bazı formülleri tanıtacaktır.

doc-extract-text-between-two-commas-1

Metni Çıkart metin dizesinde ilk ve ikinci virgül veya diğer sınırlayıcılar arasında

İlk ve ikinci virgül (veya diğer sınırlayıcılar) arasındaki metni çıkarmak istiyorsanız, MID ve SEARCH işlevleri bu görevde size yardımcı olabilir. Genel söz dizimi şu şekildedir:

=MID(cell, SEARCH("char",cell) + 1, SEARCH("char",cell, SEARCH("char",cell)+1) - SEARCH("char",cell) - 1)
  • cell: Metni çıkaracağınız hücre başvurusu veya metin dizesi.
  • char: Metni ayırmak istediğiniz özel sınırlayıcı.

Lütfen aşağıdaki formülü, sonucu almak istediğiniz boş bir hücreye kopyalayın veya girin:

=MID(A2, SEARCH(",",A2) + 1, SEARCH(",",A2,SEARCH(",",A2)+1) - SEARCH(",",A2) - 1)

Ardından, bu formülü uygulamak istediğiniz hücrelere kadar doldurma tutamacını aşağı sürükleyin; böylece ilk ve ikinci virgül arasındaki tüm metinler otomatik olarak çıkarılır. Ekran görüntüsüne göz atın:

doc-extract-text-between-two-commas-2

Formül açıklaması:

1. SEARCH(",",A2) + 1: Bu SEARCH işlevi, A2 hücresindeki ilk virgülün konumunu bulur; buna 1 eklemek, çıkarımın hemen sonraki karakterden başlamasını sağlar. Sonuç 14’tür ve bu değer, MID işlevinde start_num bağımsız değişkeni olarak kullanılır.

2. SEARCH(",",A2,SEARCH(",",A2)+1) - SEARCH(",",A2) – 1: Bu kısım, MID işlevinde num_chars bağımsız değişkeni olarak kullanılır.

  • SEARCH(",",A2,SEARCH(",",A2)+1): Bu formül parçası, ikinci virgülün konumunu bulmak için kullanılır ve sonuç olarak 21 değerini verir.
  • SEARCH(",", A2): Bu SEARCH işlevi, A2 hücresindeki ilk virgülün konumunu verir ve sonuç 13’tür.
  • SEARCH(",", A2, SEARCH(",", A2)+1) - SEARCH(",", A2)-1=21-13-1: İkinci virgülün konumundan ilk virgülün konumunu çıkarın ve sonuçtan 1'i çıkarın; bu, virgül karakterini hariç tutmak içindir. Sonuç 7'dir.

3. MID(A2, SEARCH(",",A2) + 1, SEARCH(",",A2,SEARCH(",",A2)+1) - SEARCH(",",A2) - 1)=MID(A2, 14, 7): Son olarak, MID işlevi, A2 hücresinin içinden on dördüncü karakterden başlayarak 7 karakterlik bir metin çıkarır.

Notlar:

1. Metin dizeleriniz farklı sınırlayıcılarla ayrılmışsa, formüldeki virgülleri ihtiyacınıza uygun diğer sınırlayıcılarla değiştirmeniz yeterlidir.

2. İşte size yardımcı olabilecek başka bir basit formül daha:

=TRIM(MID(SUBSTITUTE(A2,",",REPT(" ",100)),100,100))

doc-extract-text-between-two-commas-3

Metni Çıkart metin dizesinde ikinci ve üçüncü virgül veya diğer sınırlayıcılar arasında

Bazen ikinci ve üçüncü virgül arasındaki metni çıkarmak gerekebilir. Bu durumda MID, FIND ve SUBSTITUTE işlevlerinin birleşimi işinizi görebilir. Genel söz dizimi şu şekildedir:

=MID(cell, FIND("#",SUBSTITUTE(cell,"char","#",2))+1, FIND("#",SUBSTITUTE(cell,"char","#",3)) - FIND("#",SUBSTITUTE(cell,"char","#",2))-1)
  • cell: Üzerinden Metni Çıkart istediğiniz hücre başvurusu veya metin dizesi.
  • char: Üzerinden Metni Çıkart istediğiniz özel sınırlayıcı.

Lütfen aşağıdaki formülü boş bir hücreye kopyalayın veya yazın:

=MID(A2, FIND("#",SUBSTITUTE(A2,",","#",2))+1, FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1)

Formülü yapıştırdıktan sonra, bu formülü uygulamak istediğiniz hücrelere kadar doldurma tutamacını aşağı sürükleyin; böylece ikinci ve üçüncü virgül arasındaki tüm metinler aşağıdaki ekran görüntüsünde gösterildiği gibi çıkarılmış olur:

doc-extract-text-between-two-commas-4

Formül açıklaması:

1. FIND("#",SUBSTITUTE(A2,",","#",2))+1: Bu kısım, MID işlevindeki start_num bağımsız değişkeni olarak kullanılır.

  • SUBSTITUTE(A2,",","#",2): Bu SUBSTITUTE işlevi, A2 hücresindeki ikinci virgülü # karakteriyle değiştirir ve şu sonucu verir: "Apple-3000 KG,Houston#Texas,US".
  • FIND("#",SUBSTITUTE(A2,",","#",2))+1: SUBSTITUTE işlevinin döndürdüğü metin dizesindeki "#" karakterinin konumunu bulmak için FIND işlevini kullanın. 1 eklemek, çıkarmanın bir sonraki karakterden başlamasını sağlar. Bu işlem sonucunda 22 değeri elde edilir.

2. FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1: Bu kısım, MID işlevinde num_chars bağımsız değişkeni olarak kullanılır.

  • FIND("#",SUBSTITUTE(A2,",","#",3)): Bu formül, üçüncü virgülün konumunu bularak 27 sonucunu verir.
  • FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1= 27-21-1: Üçüncü virgülün konumundan ikinci virgülün konumunu çıkarın ve sonuçtan 1 çıkartın; bu, virgül karakterini dahil etmemek içindir. Sonuç 5’tir.

3. MID(A2, FIND("#",SUBSTITUTE(A2,",","#",2))+1, FIND("#",SUBSTITUTE(A2,",","#",3)) - FIND("#",SUBSTITUTE(A2,",","#",2))-1) = MID(A2, 22, 5): Son olarak, MID işlevi, A2 hücresinin içinden yirmi ikinci karakterden itibaren 5 karakter alır.

Notlar:

1. Metin dizeleriniz farklı sınırlayıcılarla ayrılmışsa, formüldeki virgülleri ihtiyacınıza uygun diğer sınırlayıcılarla değiştirmeniz yeterlidir.

2. İkinci ve üçüncü virgül arasındaki metni çıkarmak için kullanabileceğiniz başka bir basit formül daha:

=TRIM(MID(SUBSTITUTE(A2,",",REPT(" ",100)),200,100))

doc-extract-text-between-two-commas-5

Kullanılan ilgili işlevler:

  • MID:
  • MID işlevi, belirtilen metin dizesinin ortasından istenen sayıda karakteri almak ve döndürmek için kullanılır.
  • FIND:
  • FIND işlevi, bir dizenin başka bir dize içindeki konumunu belirlemek ve bu dizenin başlangıç noktasını döndürmek için kullanılır.
  • SEARCH:
  • SEARCH işlevi, belirtilen metin dizesindeki bir karakterin veya alt dizenin konumunu bulmanıza olanak tanır.
  • SUBSTITUTE:
  • Excel’deki SUBSTITUTE işlevi, bir metin dizesindeki belirli bir metni veya karakterleri başka bir metin ya da karakterle değiştirir.

Daha fazla makale:

  • Bir Hücreden Birden Fazla Satırı Çıkarın
  • Satır sonu karakterleriyle (metni girerken Alt + Enter tuşlarına basıldığında oluşan) ayrılmış metin dizeleriniz varsa ve bu satırları aşağıdaki ekran görüntüsünde gösterildiği gibi birden fazla hücreye ayırmak istiyorsanız, Excel’de bunu bir formülle nasıl gerçekleştirebilirsiniz?
  • Excel'de Metin Dizisinden N. Kelimeyi Çıkarın
  • Metin dizeleri veya cümlelerden oluşan bir listeniz varsa ve aşağıdaki ekran görüntüsünde gösterildiği gibi listeden belirli n. kelimeyi çıkarmak istiyorsanız, bu makalede Excel’de bu görevi gerçekleştirmenize yardımcı olacak bazı yöntemleri tanıtacağım.
  • Metni Çıkart Metin Dizesinde Parantezler Arasında
  • Metin dizesi içinde parantezlerle çevrelenmiş bir bölüm varsa ve aşağıdaki ekran görüntüsünde gösterildiği gibi parantezler arasındaki tüm metinleri çıkarmak istiyorsanız, bu görevi Excel’de hızlı ve kolayca nasıl halledebilirsiniz?
  • Metni Çıkart Belirli Bir Karakterin Son Örneğinden Sonra
  • Elinizde, hücre verileri içinde tireler, virgül ve boşluklar gibi çeşitli sınırlayıcılar içeren karmaşık metin dizelerinden oluşan bir liste varsa ve bu dizelerde tire işaretinin son olarak geçtiği konumu bularak hemen sonrasındaki alt dizeyi çıkarmak istiyorsanız, bu makalede söz konusu görevi gerçekleştirmenize yardımcı olacak bazı formüller tanıtacağım.

En İyi Office Verimlilik Araçları

Kutools for Excel – Kalabalıktan Sizi Ayırmanıza Yardımcı Olur

🤖KUTOOLS AI Yardımcısı: Şunu temel alarak Veri Analizi'i devrimleştirin:Akıllı Yürütme   |  Kod Oluştur|  özel formüller Oluştur  |  Verileri Analiz Et ve Grafikler Oluştur|  Geliştirilmiş İşlevler Çağır…
Popüler Özellikler:Bul, Vurgula veya Yinelenenleri İşaretle  |  Boş Satırları Sil  |  Veri Kaybetmeden Sütunları Birleştir veya Hücreleri  |  Formül kullanmadan yuvarlama…
Süper VLookup:Çoklu Kriter  |  Çoklu Değer  |  Çoklu Sayfalarda  |  Bulanık Eşleme…
Gelişmiş Açılır Liste:Kolay Açılır Liste  |  Bağımlı Açılır Liste  |  Çoklu Seçimli Açılır Liste…
Sütun Yöneticisi:Belirli Sayıda Sütun Ekle  |  Sütunları Taşı  |  Gizli Sütunların Görünürlük Durumunu Değiştir  |Sütunları Karşılaştırarak Aynı/Farklı Hücreleri Seç…
Öne Çıkan Özellikler:Izgara Odaklama  |  Tasarım Görünümü  |  Gelişmiş formül çubuğu  |  Çalışma Kitabı ve Sayfa Yöneticisi|Kaynaklar(Otomatik Metin)|  Tarih Seçici  |  Çalışma Sayfalarını Birleştir  |  Şifrele/Hücreleri Şifre Çöz  |  Listeye Göre E-posta Gönder  |  Süper Filtre  |  Özel Filtre(Kalın Yazılı Hücreleri Filtrele/italik/üstü çizili…) …
15 Araç Setlerinin Zirvesi:12 MetinAraçları(Metin Ekle,Belirli Karakterleri Sil…)|  50+GrafikTürleri(Gantt Grafiği…)|  40+ Pratik Formüller(Doğum tarihine dayanarak yaş hesapla…)|  19 EklemeAraçları(QR Kodu Ekle,Yoldan Resim Ekle…)|  12 DönüştürmeAraçları(Kelimeye Dönüştür,Döviz Kuru Dönüşümü…)|  7 Birleştir ve AyırAraçları(Gelişmiş Satırları Birleştir,Excel Hücrelerini Böl…)|… ve daha fazlası
Kutools'u tercih ettiğiniz dilde kullanın – İngilizce, İspanyolca, Almanca, Fransızca, Çince ve 40+ diğer dilleri destekler!

Kutools for Excel 300’den Fazla Özelliğe Sahiptir,İhtiyacınız Olan Şeyin Sadece Bir Tık Uzakta Olduğundan Emin Olun…

Office Tab – Microsoft Office'te (Excel dahil) Sekmeli Okuma ve Düzenlemeyi Etkinleştirir

  • Onlarca açık belge arasında geçiş yapmak için sadece bir saniye!
  • Günde yüzlerce fare tıklamasını sizin için azaltır; fareye elveda deyin.
  • Birden fazla belgeyi görüntüleyip düzenlerken verimliliğinizi %50 artırır.
  • Chrome, Edge ve Firefox gibi tarayıcılar, Excel dahil olmak üzere Office'e verimlilik kazandırır.