KutoolsforOffice — Tek çözüm, beş güçlü araç.Daha az çabayla daha fazlasını başarmak.

Metin dizelerinden ilk veya son özel karakterden önceki veya sonraki metni kaldırma

YazarXiaoyang Değiştirme Tarihi

Bu öğretici, Excel’de bir metin dizesi listesinde ilk veya son özel karakterden (örneğin boşluk, virgül) önceki ya da sonraki metnin nasıl kaldırılacağını adım adım gösterir.

doc-remove-after-first-space-01

Metin dizelerinden ilk özel karakterden önceki veya sonraki metni kaldırma

İlk özel karakterden (örneğin boşluk, virgül) önceki metni kaldırma

Metin dizelerinden ilk özel karakterden önceki metni kaldırmak için SAĞ, UZUNLUK ve BUL işlevleri size yardımcı olabilir; genel söz dizimi şöyledir:

=RIGHT(cell, LEN(cell)-FIND("char", cell))
  • cell: Kaldırmak istediğiniz hücre başvurusu veya metin dizesi.
  • char: Metni kaldırmak için dayanmak istediğiniz özel ayırıcı.

Lütfen aşağıdaki formülü, sonucu görüntülemek istediğiniz boş bir hücreye girin veya kopyalayın:

=RIGHT(A2,LEN(A2)-FIND(" ",A2))

Ardından, bu formülü uygulamak istediğiniz hücrelere kadar doldurma tutamacını aşağı sürükleyin; böylece metin dizelerinden ilk boşluktan önceki tüm metinler kaldırılmış olacaktır; ekran görüntüsüne bakın:

doc-remove-after-first-space-02

Formülün açıklaması:

1. LEN(A2)-FIND(" ",A2): Formülün bu kısmı, SAĞ işlevindeki karakter_sayısı bağımsız değişkeni olarak kullanılır.

  • FIND(" ",A2): BUL işlevi, ilk boşluğun konumunu belirlemek için kullanılır ve sonuç olarak 11 değerini döndürür.
  • LEN(A2): Bu UZUNLUK işlevi, A2 hücresindeki toplam karakter sayısını verir. Sonuç olarak 27 sayısını elde edersiniz.
  • LEN(A2)-FIND(" ",A2)=27-11: A2 hücresinin toplam karakter uzunluğundan ilk boşluğun konumunu çıkararak, ilk boşluktan sonraki karakter sayısını elde edersiniz.

2. RIGHT(A2,LEN(A2)-FIND(" ",A2))=RIGHT(A2, 16): Son olarak, bu SAĞ işlevi, A2 hücresindeki metin dizesinin sağ tarafından 16 karakter çıkarır.

İlk özel karakterden (örneğin boşluk, virgül) sonraki metni kaldırma

Excel’de SOLDAN ve BUL işlevlerini birleştirerek ilk özel karakterden sonraki metni hızla kaldırabilirsiniz. Genel söz dizimi şu şekildedir:

=LEFT(cell,FIND("char",cell)-1)
  • cell: Kaldırmak istediğiniz hücre başvurusu veya metin dizesi.
  • char: Metni kaldırmak için dayanmak istediğiniz özel ayırıcı.

Lütfen aşağıdaki formülü boş bir hücreye uygulayın:

=LEFT(A2,FIND(" ",A2)-1)

Ardından, bu formülü diğer hücrelere uygulamak için doldurma tutamacını aşağı sürükleyin; böylece ilk boşluktan sonraki tüm metinler tek seferde kaldırılmış olacaktır; ekran görüntüsüne bakın:

doc-remove-after-first-space-03

Formülün açıklaması:

1. FIND(" ",A2)-1: Bu BUL işlevi, A2 hücresindeki ilk boşluğun konumunu belirler; bundan 1 çıkarılması, boşluk karakterini dahil etmemek içindir. Sonuç 10’dur ve bu değer, SOL işlevindeki karakter_sayısı olarak kullanılır.

2. LEFT(A2,FIND(" ",A2)-1)=LEFT(A2, 10): Bu SOL işlevi, A2 hücresindeki metin dizesinin solundan 10 karakteri alır.

Metin dizelerinden son özel karakterden önceki veya sonraki metni kaldırma

Son özel karakterden (örneğin boşluk, virgül) önceki metni kaldırma

Son özel karakterden önceki tüm metni kaldırmak ve yalnızca o karakterden sonraki alt dizeyi korumak istiyorsanız, SAĞ, UZUNLUK, ARA ve YERİNEKOY işlevleri tam da ihtiyacınız olanlardır. Genel söz dizimi şu şekildedir:

=RIGHT(cell,LEN(cell)-SEARCH("#",SUBSTITUTE(cell,"char","#",LEN(cell)-LEN(SUBSTITUTE(cell,"char","")))))
  • cell: Kaldırmak istediğiniz hücre başvurusu veya metin dizesi.
  • char: Metni kaldırmak için dayanmak istediğiniz özel ayırıcı.

Bu görevi çözmek için lütfen aşağıdaki formülü boş bir hücreye kopyalayın veya yazın:

=RIGHT(A2,LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))))

Ardından, bu formülü ihtiyaç duyduğunuz diğer hücrelere doldurmak için doldurma tutamacını sürükleyin; artık son boşluktan önceki tüm metinler silinmiş ve yalnızca son boşluktan sonraki metinler korunmuştur; ekran görüntüsüne bakın:

doc-remove-after-first-space-04

Formülün açıklaması:

1. LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))):

  • YERİNEKOY(A2;" ";""): Bu YERİNEKOY işlevi, A2 hücresindeki tüm boşluk karakterlerini hiçbir şeyle değiştirerek “Tom-Grade1HoustonTexasUS” sonucunu verir.
  • UZUNLUK(YERİNEKOY(A2;" ";""): Bu UZUNLUK işlevi, YERİNEKOY işlevinin boşlukları kaldırarak döndürdüğü metnin karakter sayısını verir. Sonuç olarak 24 sayısını elde edersiniz.
  • LEN(A2)-UZUNLUK(YERİNEKOY(A2;" ";"")=27-24): A2 hücresinin toplam uzunluğundan boşluksuz karakter sayısını çıkararak, metin dizesindeki boşluk sayısını elde edersiniz. Bu işlem sonucunda 3 sayısı bulunur.
  • YERİNEKOY(A2;" ";"#";LEN(A2)-LEN(SUBSTITUTE(A2," ","")))= SUBSTITUTE(A2," ","#", 3): Bu YERİNEKOY işlevi, son boşluk karakterini özel bir # karakteriyle değiştirir; sonuç: “Tom-Grade1 Houston Texas#US”.
  • SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))= SEARCH("#", "Tom-Grade1 Houston Texas#US"): Bu ARA işlevi, YERİNEKOY işlevi tarafından döndürülen metin dizesindeki özel # karakterinin konumunu bulur ve sonuç olarak 25 sayısını verir.
  • LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))=27-25: A2 hücresindeki metnin toplam uzunluğundan son boşluğun konumu çıkarıldığında, son boşluktan sonraki karakter sayısını elde edersiniz. Bu işlem sonucunda 2 sayısı bulunur.

2. RIGHT(A2,LEN(A2)-SEARCH("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ","")))))=RIGHT(A2, 2): Son olarak, bu SAĞ fonksiyonu, A2 hücresindeki metin dizesinin sağ tarafından 2 karakter alır.

Son belirli karakterden (örneğin boşluk, virgül) sonraki metni kaldırma

Son belirli karakterden sonraki metni kaldırmak için SOLDAN, BUL, DEĞİŞTİR ve UZUNLUK fonksiyonları size yardımcı olabilir; genel sözdizimi şöyledir:

=LEFT(cell,FIND("#",SUBSTITUTE(cell,"char","#",LEN(cell)-LEN(SUBSTITUTE(cell,"char",""))))-1)
  • cell: Kaldırmak istediğiniz hücre başvurusu veya metin dizesi.
  • char: Metni kaldırmak için dayanmak istediğiniz özel ayırıcı.

Lütfen aşağıdaki formülü boş bir hücreye girin veya kopyalayın:

=LEFT(A2,FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1)

Ardından, bu formülü uygulamak istediğiniz hücrelere kadar doldurma tutamacını aşağı doğru sürükleyin; aşağıdaki ekran görüntüsünde gösterildiği gibi sonucu alacaksınız:

doc-remove-after-first-space-05

Formülün açıklaması:

1. FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1:

  • YERİNEKOY(A2;" ";""): Bu YERİNEKOY işlevi, A2 hücresindeki tüm boşluk karakterlerini hiçbir şeyle değiştirerek “Tom-Grade1HoustonTexasUS” sonucunu elde edersiniz.
  • UZUNLUK(YERİNEKOY(A2;" ";""): Bu UZUNLUK işlevi, YERİNEKOY işlevi tarafından döndürülen ve boşluksuz metin dizesinin karakter sayısını verir. 24 sayısını elde edersiniz.
  • LEN(A2)-LEN(SUBSTITUTE(A2," ",""))=27-24: Metin dizesindeki boşluk sayısını bulmak için A2 hücresinin toplam karakter sayısından boşluksuz karakter sayısını çıkarın. Bu işlem sonucunda 3 sayısı elde edilir.
  • YERİNEKOY(A2;" ";"#";LEN(A2)-LEN(SUBSTITUTE(A2," ","")))= SUBSTITUTE(A2," ","#", 3): Bu YERİNEKOY işlevi, son boşluk karakterini özel bir # karakteriyle değiştirir. Sonuç: “Tom-Grade1 Houston Texas#US”.
  • FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1=FIND("#", "Tom-Grade1 Houston Texas#US ")-1=25-1: Bu BUL işlevi, YERİNEKOY işlevinin döndürdüğü metin dizesindeki özel # karakterinin konumunu belirler; buradan 1 çıkarılması, boşluk karakterini dahil etmemek içindir. Böylece sonuç 24 olarak elde edilir.

2. LEFT(A2,FIND("#",SUBSTITUTE(A2," ","#",LEN(A2)-LEN(SUBSTITUTE(A2," ",""))))-1)=LEFT(A2, 24): Son olarak, bu SOLDAN fonksiyonu, A2 hücresindeki metin dizesinin solundan 24 karakteri almak için kullanılır.

Kullanılan ilgili fonksiyonlar:

  • LEFT:
  • SOL işlevi, belirtilen dizenin sol tarafından istediğiniz sayıda karakteri çıkarır.
  • RIGHT:
  • SAĞ işlevi, bir metin dizesinin sağ tarafından belirli sayıda karakteri ayıklamak için kullanılır.
  • FIND:
  • BUL işlevi, bir dizenin başka bir dize içindeki başlangıç konumunu bulmak ve döndürmek için kullanılır.
  • SEARCH:
  • ARA işlevi, verilen metin dizesinde belirli bir karakterin veya alt dizenin konumunu bulmanıza yardımcı olur.
  • SUBSTITUTE:
  • Excel’de YERİNEKOY işlevi, bir metin dizesi içindeki belirtilen metni veya karakterleri başka bir metin ya da karakterle değiştirir.
  • LEN:
  • UZUNLUK işlevi, bir metin dizesindeki karakter sayısını verir.

Daha fazla makale:

En İyi Office Verimlilik Araçları

Kutools for Excel – Sizi Kalabalıktan Ayırır

🤖KUTOOLS AI Yardımcısı: Şuna göre Veri Analizi’i devrimleştirin:Akıllı Yürütme   |  Kod Oluştur|  özel formüller Oluştur  |  Verileri Analiz Et ve Grafikler Oluştur|  Geliştirilmiş İşlevler'yi Çağır…
Popüler Özellikler:Bul, Vurgula veya Yinelenenleri İşaretle  |  Boş Satırları Sil  |  Veri Kaybetmeden Sütunları Birleştir veya Hücreleri  |  Formül kullanmadan yuvarlama…
Süper VLookup:Çoklu Kriter  |  Çoklu Değer  |  Çoklu Sayfalarda Arama  |  Bulanık Eşleme…
Gelişmiş Açılır Liste:Kolay Açılır Liste  |  Bağımlı Açılır Liste  |  Çoklu Seçimli Açılır Liste…
Sütun Yöneticisi:Belirli Sayıda Sütun Ekle  |  Sütunları Taşı  |  Gizli Sütunların Görünürlük Durumunu Aç/Kapat  |Sütunları Karşılaştırarak Aynı/Farklı Hücreleri Seç…
Öne Çıkan Özellikler:Izgara Odaklama  |  Tasarım Görünümü  |  Gelişmiş formül çubuğu  |  Çalışma Kitabı ve Sayfa Yöneticisi|Kaynaklar(Otomatik Metin)|  Tarih Seçici  |  Çalışma Sayfalarını Birleştir  |  Şifrele/Hücreleri Şifre Çöz  |  Listeye Göre E-posta Gönder  |  Süper Filtre  |  Özel Filtre(Kalın Yazılı Hücreleri Filtrele/italik/üstü çizili…) …
En İyi 15 Araç Setleri:12 MetinAraçları(Metin Ekle,Belirli Karakterleri Sil…)|  50+GrafikTürleri(Gantt Grafiği…)|  40+ Pratik Formüller(Doğum tarihine dayanarak yaş hesapla…)|  19 EklemeAraçları(QR Kodu Ekle,Yoldan Resim Ekle…)|  12 DönüştürmeAraçları(Kelimeye Dönüştür,Döviz Kuru Dönüşümü…)|  7 Birleştir ve AyırAraçları(Gelişmiş Satırları Birleştir,Excel Hücrelerini Böl…)|… ve daha fazlası
Kutools’u tercih ettiğiniz dilde kullanın – İngilizce, İspanyolca, Almanca, Fransızca, Çince ve 40+ başka dil desteği sunar!

Kutools for Excel 300’den Fazla Özelliğe Sahiptir,İhtiyacınız Olan Her Şeyin Bir Tık Uzakta Olduğundan Emin Olun…

Office Tab – Microsoft Office’te (Excel dahil) Sekmeli Okuma ve Düzenlemeyi Etkinleştirir

  • Onlarca açık belge arasında geçiş yapmak için sadece bir saniye!
  • Her gün sizin için yüzlerce fare tıklamasını azaltır; artık fare elinizden kurtulun.
  • Birden fazla belgeyi görüntüleyip düzenlerken verimliliğinizi %50 artırır.
  • Chrome, Edge ve Firefox gibi tarayıcılar, Office’e (Excel dahil) verimlilik kazandırır.