Boyutları ayrı uzunluk, yükseklik ve genişliğe bölme

Bu makale, bir hücredeki boyutların uzunluk, yükseklik ve genişlik olmak üzere üç ayrı parçaya nasıl ayrılacağını açıklar.

Boyutlar üç parçaya nasıl bölünür?

Boyutları uzunluk, yükseklik ve genişlik olarak ayırmak için üç farklı formülü ayrı ayrı uygulamanız gerekir.

İlk boyutu çıkarma genel formülü

=LEFT(text,FIND("char",text)-1)

İkinci boyutu çıkarma genel formülü

=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))

Üçüncü boyutu çıkarma genel formülü

=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))

Yukarıdaki formüllerin bağımsız değişkenleri

Bu formüller nasıl kullanılır?

Öncelikle ilk boyutu elde etmemiz gerekiyor.

1. İlk boyutun çıktısını almak için boş bir hücre seçin.

2. Aşağıdaki formülü hücresine girin ve EnterTuşuna basın. Sonuç hücresini seçip Doldurma Kulpu’nu sürükleyerek formülü ihtiyacınız kadar diğer hücrelere uygulayın.

=LEFT(B5,FIND("x",B5)-1)

Ardından, ikinci boyutu aşağıda gösterildiği gibi böleceğiz.

1. İkinci boyutun çıktısını almak için boş bir hücre seçin.

2. Aşağıdaki formülü içine girin ve Entertuşuna basın. Sonuç hücresini seçip Doldurma Kulpu'nu sürükleyerek formülü ihtiyacınız kadar diğer hücrelere uygulayın.

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

Son olarak, son boyutu alın

1. Son boyutun çıktısını almak için boş bir hücre seçin.

2. Aşağıdaki formülü girin ve EnterTuşuna basın. Sonuç hücresini seçip Doldurma Kulpu’nu sürükleyerek formülü ihtiyaç duyduğunuz kadar diğer hücrelere uygulayın.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

Bu formüller nasıl çalışıyor?

=LEFT(B5,FIND("x",B5)-1)

1. FIND("x",B5)-1: BUL işlevi, B5 hücresindeki ilk "x" karakterinin konumunu belirler. İlk boyutu "x" olmadan almak için bu değerden 1 çıkarılır. Sonuç: 4-1=3.
2. LEFT(B5,3): SOL işlevi, B5 hücresinin solundan itibaren 3 karakteri alır ve sonucu "100" olarak döndürür.

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

1. FIND("x",B5)+1BUL işlevi, B5 hücresindeki ilk "x" karakterinin konumunu bulur. İkinci boyutu ilk "x"ten hemen sonra almanız gerektiğinden, buraya 1 eklenmelidir. Böylece sonuç 4+1=5 olur.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2): SUBSTITUTE işlevi, B5 hücresindeki ikinci "x" karakterini "@" ile değiştirir ve sonucu 100x50@300 olarak döndürür;
• FIND("@",100x50@300)FIND işlevi, "100x50@300" metnindeki "@" karakterinin konumunu belirler ve sonucu 7 olarak döndürür.

3. (BUL("x",B5)+1): Yukarıdaki 1. adımda belirtildiği gibi, BUL işlevi burada B5 hücresindeki ilk "x" karakterinin konumunu bulur ve buna 1 ekleyerek sonucu 5 olarak döndürür.
4. PARÇAAL(B5,5,7-(5)): PARÇAAL işlevi, B5 hücresindeki metnin beşinci karakterinden başlayarak iki karakter (7-5=2) alır ve nihai sonucu "50" olarak döndürür.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

1. LEN(B5): UZUNLUK işlevi, B5 hücresindeki toplam Dizi Uzunluğuna Göre Filtrele sayısını hesaplar ve sonucu 10 olarak döndürür;
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2): SUBSTITUTE işlevi, B5 hücresindeki ikinci "x" karakterini "@" ile değiştirir ve sonucu 100x50@300 olarak döndürür;
• FIND("@",100x50@300)FIND işlevi, "100x50@300" metnindeki "@" karakterinin konumunu belirler ve sonucu 7 olarak döndürür.

3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)): B5 hücresindeki metin dizesinin toplam uzunluğundan ilk 7 karakter çıkarılır ve sonuç 3 olarak döndürülür (10-7).
4. RIGHT(B5,3): Ardından SAĞ işlevi, B5 hücresinin sağ tarafından başlayarak 3 karakter alır ve üçüncü boyutu "300" olarak döndürür.

İlgili işlevler

İlgili formüller