Excel'de bir hücrede belirli bir karakterde metin dizesini bölme

Bu öğretici, Excel'de formüller kullanarak belirli bir karakterde metin dizesini ayrı sütun hücrelerine nasıl böleceğinizi açıklar.

Excel'de bir hücrede belirli bir karakterde metin dizesini nasıl bölersiniz?

Aşağıdaki ekran görüntüsünde olduğu gibi sütun B'de bir metin dizesi listeniz olduğunu ve "-" karakterinde metinleri bölmek ve bunları üç ayrı sütunda çıkarmak istediğinizi varsayalım. Bu durumda, aşağıdaki formüller size yardımcı olabilir.

Genel formüller

Sol metni bölmek için genel formül

=SOL(text_string,BUL("Char", text_string)-1)

Orta metni bölmek için genel formül

=ORTA(text_string, BUL("Char", text_string) + 1, BUL("Char", text_string,BUL("Char", text_string)+1) - BUL("Char", text_string) - 1)

Sağ metni bölmek için genel formül

=SAĞ(text_string,UZUNLUK(text_string) - BUL("Char", text_string, BUL("Char", text_string) + 1))

Yukarıdaki formüllerin argümanları

Bu formülleri nasıl kullanılır?

Öncelikle, belirli bir karaktere göre ilk metin dizesini bölme

1. Sonucu çıkarmak için boş bir hücre seçin. Burada C3'ü seçiyorum.

2. Aşağıdaki formülü içine girin ve Enter tuşuna basın. Ardından LEFT formülünüzle hücreyi sürükleyerek diğer hücrelere uygulayın.

=SOL(B3,BUL("-",B3)-1)

İkinci olarak, belirli bir karaktere göre orta metin dizesini bölme

1. Sonucu çıkarmak için D3 gibi boş bir hücre seçin.

2. Aşağıdaki formülü içine girin ve Enter tuşuna basın. Sonuç hücresini seçin, Doldurma Tutamacını aşağı doğru sürükleyerek formülü diğer hücrelere uygulayın.

=ORTA(B3, BUL("-",B3) + 1, BUL("-",B3,BUL("-",B3)+1) - BUL("-",B3) - 1)

Son olarak, belirli bir karaktere göre son metin dizesini bölme

1. Sonucu çıkarmak için E3 gibi boş bir hücre seçin.

2. Aşağıdaki formülü içine girin ve Enter tuşuna basın. Sonuç hücresini seçin, Doldurma Tutamacını aşağı doğru sürükleyerek formülü diğer hücrelere uygulayın.

=SAĞ(B3,UZUNLUK(B3) - BUL("-", B3, BUL("-", B3) + 1))

Şimdi sütun B'deki her hücredeki metin dizesi üç parçaya bölünmüştür.

İpuçları: Eğer metin dizesini yalnızca iki parçaya bölmek istiyorsanız, yukarıdaki SOL formülü ile ilk kısmı böldükten sonra, ikinci kısmı çıkarmak için aşağıdaki SAĞ formülünü uygulayabilirsiniz, aşağıdaki ekran görüntüsünde gösterildiği gibi.

=SAĞ(B3,UZUNLUK(B3)-BUL("-",B3))

Bu formüller nasıl çalışıyor?

=SOL(B3,BUL("-",B3)-1)

• BUL("-",B3): BUL fonksiyonu, KTE-Oca-359 metin dizesindeki "-" karakterinin başlangıç pozisyonunu döndürür. Sonuç 4'tür.
• SOL(B3,4-1): SOL fonksiyonu, KTE-Oca-359 metin dizesinin sol tarafından 3 karakter (4-1=3) çıkarır. Buradaki sonuç KTE'dir.
  Not: İlk "-" karakteri metin dizesinin 4. pozisyonunda olduğundan, onu çıkarmak için 1 çıkarmalısınız. 

=ORTA(B3, BUL("-",B3) + 1, BUL("-",B3,BUL("-",B3)+1) - BUL("-",B3) - 1)

• BUL("-",B3) + 1: BUL fonksiyonu, KTE-Oca-359 metin dizesindeki "-" karakterinin başlangıç pozisyonunu döndürür. Buradaki sonuç 4'tür.
  Not: İlk "-" karakteri metin dizesinin 4. pozisyonunda olduğundan, ondan sonra gelen metinleri çıkarmak için 4'e 1 eklemeniz gerekir ve sonuç olarak 4+1=5 elde ederiz.
• BUL("-",B3,BUL("-",B3)+1) burada BUL("-",KTE-Oca-359,4+1) olarak gösterilmiştir: FIND fonksiyonu, KTE-Oca-359'daki 5. karakterden başlayarak "-" karakterinin konumunu bulur. Ve sonucu 8 olarak döndürür.
• ORTA(B3, 5, 8 - 4 - 1): ORTA(KTE-Oca-359,5,3) yani ORTA fonksiyonu, KTE-Oca-359 metin dizesindeki 5. karakterden başlayarak 3 karakter çıkarır. Ve sonuç Oca'dır.

=SAĞ(B3,UZUNLUK(B3) - BUL("-", B3, BUL("-", B3) + 1))

• UZUNLUK(B3): UZUNLUK fonksiyonu, KTE-Oca-359 metin dizesinin toplam uzunluğunu hesaplar ve sonucu 11 olarak döndürür.
• BUL("-",B3,BUL("-",B3)+1): BUL fonksiyonu, KTE-Oca-359'daki 5. karakterden başlayarak "-" karakterinin konumunu bulur. Ve sonucu 8 olarak döndürür.
• SAĞ(B3,11 - 8)): SAĞ fonksiyonu, KTE-Oca-359'un sağ tarafından 3 (11-8) karakter çıkarır. Buradaki sonuç 359'dur.

İlgili fonksiyonlar

İlgili formüller