Excel'de bir hücredeki metin dizisini belirli bir karakterde bölme

Bu öğretici, Excel'de metin dizilerini belirli bir karaktere göre ayrı sütunlara nasıl böleceğinizi formül kullanarak açıklar.

Excel'de bir hücredeki metin dizisini belirli bir karaktere göre nasıl bölerim?

Aşağıdaki ekran görüntüsünde gösterildiği gibi, B sütununda bir metin dizisi listeniz olduğunu ve bu metinleri "-" karakterine göre bölerek üç ayrı sütuna dağıtmak istediğinizi varsayalım. Bu durumda aşağıdaki formüller işinize yarayacaktır.

Genel formüller

Sol metni bölmek için genel formül

=LEFT(text_string,FIND("Char", text_string)-1)

Orta metni bölmek için genel formül

=MID(text_string, FIND("Char", text_string) + 1, FIND("Char", text_string,FIND("Char", text_string)+1) - FIND("Char", text_string) - 1)

Sağ metni bölmek için genel formül

=RIGHT(text_string,LEN(text_string) - FIND("Char", text_string, FIND("Char", text_string) + 1))

Yukarıdaki formüllerin bağımsız değişkenleri

Bu formüller nasıl kullanılır?

İlk olarak, ilk metin dizisini belirli bir karaktere göre bölme

1. Sonucun görüntüleneceği boş bir hücre seçin. Ben C3’ü seçtim.

2. Aşağıdaki formülü girin ve Enter tuşuna basın. Ardından, formülünüzün bulunduğu hücreyi aşağı doğru sürükleyerek diğer hücrelere uygulayın.

=LEFT(B3,FIND("-",B3)-1)

İkinci olarak, orta metin dizisini belirli bir karaktere göre bölme

1. Sonucun görüntüleneceği D3 gibi boş bir hücre seçin.

2. Aşağıdaki formülü girin ve Enter tuşuna basın. Sonuç hücresini seçip formülü diğer hücrelere uygulamak için Dolgu Tutamacı'nı aşağı sürükleyin.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

Son olarak, son metin dizisini belirli bir karaktere göre bölme

1. Sonucun görüntüleneceği boş bir hücre (örneğin E3) seçin.

2. Aşağıdaki formülü girin ve Entertuşuna basın. Sonuç hücresini seçip, formülü diğer hücrelere uygulamak için Dolgu Tutamacı'nı aşağı sürükleyin.

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

Artık B sütunundaki her hücredeki metin dizisi üç parçaya ayrıldı.

İpuçları: Metin dizisini yalnızca iki parçaya bölmek istiyorsanız, yukarıdaki SOL formülünü kullanarak ilk kısmı ayırdıktan sonra, aşağıdaki SAĞ formülünü kullanarak ikinci parçayı aşağıdaki ekran görüntüsünde gösterildiği gibi çıkarabilirsiniz.

=RIGHT(B3,LEN(B3)-FIND("-",B3))

Bu formüller nasıl çalışıyor?

=LEFT(B3,FIND("-",B3)-1)

• FIND("-",B3)BUL işlevi, "-" karakterinin "KTE-Oca-359" metin dizisindeki başlangıç konumunu döndürür; sonuç 4'tür.
• LEFT(B3,4-1): SOL işlevi, "KTE-Oca-359" metin dizisinin solundan 3 karakter (4–1=3) alır. Sonuç: KTE.
  Not: İlk "-" karakteri metin dizisinin 4. konumunda yer aldığı için, bu karakter dahil edilmemek üzere alınacak karakter sayısından 1 çıkarmanız gerekir.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

• FIND("-",B3) + 1: BUL işlevi, "-" karakterinin KTE-Oca-359 metin dizisindeki başlangıç konumunu döndürür. Sonuç burada 4’tür.
  Not: İlk "-" karakteri metin dizisinin 4. konumunda yer aldığı için, Metni Çıkart işlemi yapabilmek üzere 4’e 1 eklemeniz gerekir; böylece 4+1=5 sonucuna ulaşılır.
• FIND("-",B3,FIND("-",B3)+1)Burada FIND("-", "KTE-Oca-359", 4+1) işlevi gösterilmiştir: Bu işlev, "KTE-Oca-359" metninde 5. karakterden itibaren "-" işaretinin konumunu arar ve sonucu 8 olarak döndürür.
• MID(B3, 5, 8 - 4 - 1): MID(KTE-Oca-359;5;3) işlevi, "KTE-Oca-359" metin dizisinde 5. karakterden başlayarak 3 karakter çıkarır. Sonuç "Oca"dır.

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

• LEN(B3)UZUNLUK işlevi, "KTE-Oca-359" metin dizisinin toplam uzunluğunu hesaplar ve sonucu 11 olarak döndürür.
• FIND("-",B3,FIND("-",B3)+1)Bul işlevi, KTE-Oca-359 metninde 5. karakterden itibaren "-" işaretinin konumunu arar ve sonucu 8 olarak verir.
• RIGHT(B3,11 - 8))SAĞ işlevi, "KTE-Oca-359" metin dizisinin sağından 3 (11–8) karakter alır. Sonuç, 359’dur.

İlgili işlevler

İlgili formüller