Note: The other languages of the website are Google-translated. Back to English

Metin dizelerinden sayısal karakterleri soyun veya kaldırın

Tüm sayıları yalnızca bir metin dizesi listesinden kaldırmak, ancak diğer sayısal olmayan karakterleri korumak istiyorsanız, Excel'de size bir iyilik yapabilecek bazı formüller olabilir.


Excel'de metin dizelerindeki tüm sayıları soyun veya kaldırın

Alfasayısal dizelerden yalnızca sayıları kaldırmak için METİNBİRLEŞTİR, ORTA, SATIR, EĞER, ISERR, UZUNLUK ve DOLAYLI işlevlerini birleştiren karmaşık bir dizi formülü size yardımcı olabilir. (not: Bu formül yalnızca Excel 2019 ve Office 365'te iyi çalışır.) Genel sözdizimi şöyledir:

=TEXTJOIN("",TRUE,IF(ISERR(MID(text,ROW(INDIRECT("1:"&LEN(text))),1)+0),MID(text,ROW(INDIRECT("1:"&LEN(text))),1),""))
  • text: tüm sayıları kaldırmak istediğiniz metin dizesi veya hücre değeri.

1. Lütfen aşağıdaki formülü, sonucun çıktısını almak istediğiniz boş bir hücreye kopyalayın veya girin:

=TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),""))

2. Daha sonra, tuşuna basın. Ctrl + Üst Karakter + Enter ilk sonucu almak için aynı anda tuşları, ekran görüntüsüne bakın:

3. Ve sonra, formül hücresini seçin, doldurma tutamacını kullanmak istediğiniz hücrelere sürükleyin, tüm sayılar metin dizelerinden çıkarıldı, ekran görüntüsüne bakın:


Formülün açıklaması:

SATIR (DOLAYLI ("1:" & UZUNLUK (A2))): SATIR işlevi içindeki DOLAYLI işlevi, uzunluğu aşağıdaki gibi A2 hücresinin uzunluğu olan bir dizi listesi döndürür ve bu bölüm, ORTA işlevinde başlangıç_sayısı olarak tanınır.
{1;2;3;4;5;6;7;8;9;10;11;12;13;14;15;16;17;18;19;20;21}

ORTA (A2, SATIR (DOLAYLI ("1:" & UZUNLUK (A2))), 1): Bu MID işlevi, bir karakter elde etmek için A2 hücresinden metin çıkarmak için kullanılır ve aşağıdaki gibi dizi döndürür:
{"5"; "0"; "0"; ""; "K"; "u"; "t"; "o"; "o"; "l"; "s"; ""; "f" ; "o"; "r"; ""; "E"; "x"; "c"; "e"; "l"}

MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0: Metni bir sayıya zorlamak için bu dizi kullanıldıktan sonra 0 değeri eklendiğinde, sayısal metin değeri sayıya dönüştürülecek ve sayısal olmayan değerler şu şekilde # DEĞER hata değeri olarak görüntülenecektir:
{"5"; "0"; "0"; # DEĞER!; # DEĞER!; # DEĞER!; # DEĞER!; # DEĞER!; # DEĞER! !; # DEĞER! !; # DEĞER! ...}

IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),""): EĞER işlevi, MID işlevi tarafından döndürülen dizinin hata değerleri olup olmadığını kontrol etmek için kullanılır. Bir hata değeriyse, ikinci MID işlevini kullanarak sayısal olmayan karakteri alın, aksi takdirde boş dizeler şu şekilde görüntülenir:
{""; ""; ""; ""; "K"; "u"; "t"; "o"; "o"; "l"; "s"; ""; "f"; "o ";" r ";" ";" E ";" x ";" c ";" e ";" l "}

TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),"")): Son olarak, TEXTJOIN işlevi tüm değerleri birleştirecek ve sonucu almak için boş dizeyi yok sayacaktır.


Notlar:

1. Sayısal karakterleri kaldırırken, fazladan boşluk karakterleri kalmış olabilir, tüm fazla boşlukları kaldırmak için formülü aşağıdaki gibi KIRP işlevine sarmalısınız:

=TRIM(TEXTJOIN("",TRUE,IF(ISERR(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)+0),MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1),"")))

2. Excel'in önceki sürümlerinde metin dizelerinden sayıları kaldırmak için lütfen aşağıdaki formülü uygulayın:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,1,""),2,""),3,""),4,""),5,""),6,""),7,""),8,""),9,""),0,"")


Kullanılan göreceli işlevler:

  • TEXTJOIN:
  • METİNBİRLEŞTİR işlevi, bir satırdan, sütundan veya belirli bir sınırlayıcıya sahip bir hücre aralığındaki birden çok değeri birleştirir.
  • MID:
  • MID işlevi, belirli bir metin dizesinin ortasından belirli sayıda karakteri bulup döndürmek için kullanılır.
  • ROW:
  • Excel SATIR işlevi, bir başvurunun satır numarasını döndürür.
  • INDIRECT:
  • Excel DOLAYLI işlevi, bir metin dizesini geçerli bir başvuruya dönüştürür.
  • LEN:
  • UZUNLUK işlevi, bir metin dizesindeki karakter sayısını döndürür.
  • IF:
  • IF işlevi, karşılaştırma sonucuna bağlı olarak basit bir mantıksal test gerçekleştirir ve sonuç DOĞRU ise bir değer veya sonuç YANLIŞ ise başka bir değer döndürür.
  • ISERR:
  • ISERR işlevi, #YOK hatası dışında herhangi bir hata türü için DOĞRU döndürmek için kullanılır.

Daha fazla makale:


En İyi Ofis Üretkenliği Araçları

Kutools for Excel - Kalabalıktan Ayrılmanıza Yardımcı Olur

Günlük işlerinizi hızlı ve kusursuz bir şekilde tamamlamak ister misiniz? Kutools for Excel, 300 güçlü gelişmiş özellik getiriyor (Çalışma kitaplarını birleştir, renge göre topla, hücre içeriğini böl, tarihi dönüştür, vb.) ve senin için% 80 zamandan tasarruf et.

  • 1500 çalışma senaryosu için tasarlanmış olup, Excel problemlerinin %80'ini çözmenize yardımcı olur.
  • Her gün binlerce klavye ve fare tıklamasını azaltın, yorgun gözlerinizi ve ellerinizi rahatlatın.
  • 3 dakikada bir Excel uzmanı olun. Artık acı veren formülleri ve VBA kodlarını hatırlamanıza gerek yok.
  • 30 günlük sınırsız ücretsiz deneme. 60 günlük para iade garantisi. 2 yıl boyunca ücretsiz yükseltme ve destek.
Excel şeridi (Kutools for Excel yüklü)

Office Sekmesi - Microsoft Office'te Sekmeli Okuma ve Düzenlemeyi Etkinleştir (Excel dahil)

  • Düzinelerce açık belge arasında geçiş yapmak için bir saniye!
  • Her gün yüzlerce fare tıklamasını azaltın, fare eline veda edin.
  • Birden çok belgeyi görüntülerken ve düzenlerken üretkenliğinizi% 50 artırır.
  • Office'e (Excel dahil), Chrome, Firefox ve Yeni Internet Explorer gibi Verimli Sekmeler Getirir.
Excel'in Ekran Görüntüsü (Office Tab yüklü)
Yorumları sıralama ölçütü
Yorumlar (0)
Henüz derecelendirme yok. İlk değerlendiren siz olun!
Buraya henüz hiç yorum yapılmamış
Lütfen yorum yazın
Misafir olarak yayınlama
×
Bu gönderiyi değerlendirin:
0   Karakterler
Önerilen Konumlar

Bizi takip et

Telif Hakkı © 2009 - www.extendoffice.com. | Tüm hakları Saklıdır. Tarafından desteklenmektedir ExtendOffice. | | | Site Haritası
Microsoft ve Office logosu, Microsoft Corporation'ın Amerika Birleşik Devletleri ve / veya diğer ülkelerdeki ticari markaları veya tescilli ticari markalarıdır.
Sectigo SSL ile korunmaktadır