KutoolsforOffice — Tek çözüm, beş güçlü araç.Daha az çabayla daha fazlasını başarmak.

Excel'de hafta numarasına veya haftanın gününe göre değerleri toplayın

YazarSiluvia Değiştirme Tarihi

Bu öğretici, Excel’de belirtilen hafta numarasına veya haftanın gününe göre belirli bir aralıktaki değerleri toplamanız için formülleri adım adım açıklar.

Excel'de Hafta numarası'ye göre değerleri nasıl toplarsınız?
Excel'de haftanın gününe göre değerleri nasıl toplarsınız?

Excel'de hafta numarasına göre değerleri nasıl toplarsınız?

Aşağıdaki ekran görüntüsünde gösterildiği gibi, Tutar sütunundaki değerleri belirtilen Hafta numarasının kapsadığı tarihlere göre toplamak için iki formül sunuyoruz.

doc-sum-by-week-number-weekday-1

Genel Formüller

=SUMIFS( value_range, helper_column_range, week_number)

=SUMPRODUCT(--(WEEKNUM(date_range+0,1)=week_number),value_range)

Bağımsız Değişkenler

Değer_aralığı: Hafta numarası'a göre toplamak istediğiniz değerlerin aralığı;
Yardımcı_sütun_aralığı: Tarihten çıkarılan Hafta numarası'lerin aralığı;
Hafta_numarası: Değerleri toplamak için kriter olarak kullanılan Hafta numarası.

Bu formülü nasıl kullanırsınız?

SUMIFS formülü ve yardımcı sütun kullanarak

SUMIFS formülünü kullanmak için öncelikle Tarih sütunundaki tarihlerin ilgili Hafta numarasını hesaplamak üzere WEEKNUM işlevini kullanarak bir yardımcı sütun oluşturmanız gerekir.

=WEEKNUM (serial_num, [return_type])

WEEKNUM işlevi, belirtilen tarihin yıl içindeki hafta numarasını verir.

1. Bu örnekte, Tutar sütunundaki ilk değerin yanındaki bir hücreyi (F5) seçiyorum.

2. Aşağıdaki formülü hücresine girin ve ilk tarihin Hafta numarası değerini almak için Enter tuşuna basın. Sonuç hücresini seçip diğer Hafta numarası değerlerini almak için Otomatik Doldurma İşlemini aşağı doğru sürükleyin. Ekran görüntüsüne bakın:

=WEEKNUM(C5)

doc-sum-by-week-number-weekday-2

3. Toplam tutarı görüntülemek için bir hücre seçin, aşağıdaki formülü girin ve Entertuşuna basın. Ardından bu sonuç hücresini seçin ve diğer sonuçları almak için Otomatik Doldurma İşaretçisini aşağı doğru sürükleyin.

=SUMIFS($E$5:$E$14, $F$5:$F$14, H6)

doc-sum-by-week-number-weekday-3

SUMPRODUCT formülünü kullanarak

SUMPRODUCT formülünü kullanarak bu sorunu çözmek için yardımcı bir sütun oluşturma gereksinimi duymazsınız.

1. Boş bir hücre seçin, aşağıdaki formülü içine girin ve Entertuşuna basın.

=SUMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

2. Sonuç hücresini seçin ve ihtiyaçlarınıza göre diğer sonuçları alın.Otomatik Doldurma Siparişini aşağı doğru sürükleyin.

doc-sum-by-week-number-weekday-4

Formülün açıklaması

=SUMIFS($E$5:$E$14, $F$5:$F$14, H6)

WEEKNUM işleviyle Hafta numarası hesaplandıktan sonra, SUMIFS işlevi E5:E14 aralığında değerleri toplar; bu değerlerin yardımcı sütundaki F5:F14 aralığındaki Hafta numarası değerleri H6 hücresindeki belirtilen hafta numarasıyla eşleşiyorsa.

=SUMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

WEEKNUM($C$5:$C$14+0,1): WEEKNUM işlevi, C5:C14 aralığındaki tarihlerin her birinin Hafta numarası değerini hesaplar ve şöyle bir dizi döndürür: {1;1;5;6;6;9;11;11;13;14};
{1;1;5;6;6;9;11;11;13;14}=G6: Burada dizideki her Hafta numarası değeri G6 hücresindeki belirtilen Hafta numarası ile karşılaştırılır ve yeni bir dizi döndürülür: {TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE};
--{TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE}: Bu iki eksi işareti “TRUE” ve “FALSE” değerlerini 1 ve 0'lara dönüştürür. Böylece {1;1;0;0;0;0;0;0;0;0} şeklinde yeni bir dizi elde edersiniz;
{1;1;0;0;0;0;0;0;0;0},{1428;2010;2288;1831;2069;1728;1325;1469;1023;1100}: Dizilerdeki her çift değer birbiriyle çarpılır ve {1428;2010;0;0;0;0;0;0;0;0} sonucu döndürülür;
SUMPRODUCT({1428;2010;0;0;0;0;0;0;0;0}): SUMPRODUCT işlevi, dizideki tüm sayıları toplar ve nihai sonucu 1428+2010=3438 şeklinde döndürür.

Excel'de haftanın gününe göre değerleri nasıl toplarsınız?

Aşağıdaki ekran görüntüsünde gösterildiği gibi, Excel’de Tutar sütunundaki değerleri belirli bir haftanın gününe göre toplamak için SUMPRODUCT işlevini WEEKDAY işleviyle birlikte kullanabilirsiniz.

Bu örnekte, her haftanın günü için toplam tutarı toplamamız gerektiğinden, formülü uygulamadan önce Pazartesi'den Pazar'a kadar günleri ayrı ayrı belirtmek üzere 1 ile 7 arasındaki sayıları içeren bir yardımcı sütun oluşturuyoruz.

doc-sum-by-week-number-weekday-6

Genel formül

=SUMPRODUCT((WEEKDAY(date_range,2)=weekday_number)*value_range)

Bağımsız Değişkenler

Tarih_aralığı: Belirtilen haftanın günlerini değerlendirmek istediğiniz Tarih Aralığı;
Değer_aralığı: Haftanın gününe göre toplamak istediğiniz değerlerin aralığı;
2: 2 sayısı, 1 (Pazartesi) ile 7 (Pazar) arasındaki günleri temsil eder;
Haftanın_günü_numarası: Değerleri toplamak için kriter olarak kullanılan haftanın günü numarası. Bu Bir hücre başvurusu olabilir veya 1 ile 7 arasında bir sayıdır.

Bu formülü nasıl kullanırsınız?

1. Sayı 1 hücresinin yanındaki bir hücreyi seçin; örneğin I6'yı seçiyorum.

2. Aşağıdaki formülü kopyalayın veya doğrudan girin ve EnterTuşuna basın. Sonuç hücresini seçin ve diğer hafta günleri için sonuçları almak üzere Otomatik Doldurma İşlecini aşağı doğru sürükleyin.

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=H6)*$E$5:$E$14)

doc-sum-by-week-number-weekday-7

Not: Yalnızca Cuma gibi tek bir haftanın gününe göre değerleri toplamanız gerekiyorsa, formülde doğrudan 5 sayısını aşağıdaki gibi kullanabilirsiniz.

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=5)*$E$5:$E$14)

Formülün açıklaması

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=H6)*$E$5:$E$14)

WEEKDAY($C$5:$C$14,2): WEEKDAY işlevi, C5:C14 aralığında Pazartesi'den Pazar'a kadar olan günleri temsil etmek üzere Hafta değerlerini 1 ile 7 arasında tam sayılar olarak döndürür: {5;7;1;3;6;7;1;5;5;6};
{5;7;1;3;6;7;1;5;5;6}=H6: Burada dizideki her Hafta değeri H6 hücresindeki belirtilen haftanın günü numarasıyla karşılaştırılır ve {FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE} şeklinde yeni bir dizi döndürülür;
{FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE}*$E$5:$E$14: Burada TRUE ve FALSE değerleri 1 ve 0'lara dönüştürülür ve ardından E5:E14 aralığındaki değerlerle çarpılarak {0;0;2288;0;0;0;1325;0;0;0} şeklinde bir dizi döndürülür;
SUMPRODUCT{0;0;2288;0;0;0;1325;0;0;0}: SUMPRODUCT işlevi, dizideki tüm sayıları toplar ve nihai sonucu 2288+1325=3613 şeklinde döndürür.

İlgili işlevler

Excel WEEKNUM işlevi
Excel WEEKNUM işlevi, belirtilen tarihin yıl içindeki hafta numarasını döndürür; hafta sayımı 1 Ocak’tan itibaren 1’den başlar.

Excel SUMPRODUCT işlevi
Excel SUMPRODUCT işlevi, iki veya daha fazla sütun ya da diziyi birbiriyle çarparak sonuçların toplamını almanızı sağlar.

Excel WEEKDAY işlevi
Excel WEEKDAY işlevi, belirtilen bir tarihin haftanın gününü temsil etmek üzere 1 ile 7 arasında bir tam sayı döndürür.

İlgili formüller

Sum values by month (with or without year)
Bu öğretici, Excel'de değerleri belirli bir ay ve yıla veya yalnızca aya göre toplamak için iki formülü adım adım ayrıntılı şekilde açıklar.

Belirtilen bir tarihin haftasına göre değerleri toplayın
Bu öğretici, belirtilen bir tarihin düştüğü haftaya göre değerlerin nasıl toplanacağını adım adım gösterir.

Bir aralıktaki her n satırı veya sütunu toplayın
Bu öğretici, Excel'de sınırlı bir aralıkta her n satırı veya sütunu toplamak için SUM ve OFFSET işlevlerine dayalı iki formülü açıklar.

Bir aralıktaki her n. satırı veya sütunu toplayın
Bu öğretici, Excel'de bir aralıkta her n. satırı veya sütunu toplamak için SUMPRODUCT, MOD ve COLUMN işlevlerini kullanan etkili bir formül oluşturmanızı gösterecektir.

En İyi Office Verimlilik Araçları

Kutools for Excel - Kalabalıktan sıyrılmanıza yardımcı olur

🤖KUTOOLS AI Yardımcısı: Şuna göre Veri Analizi'i devrimleştirin:Akıllı Yürütme   |  Kod Oluştur|  özel formüller Oluştur  |  Verileri Analiz Et ve Grafikler Oluştur|  Geliştirilmiş İşlevler Çağrısı Yap…
Popüler Özellikler:Bul, Vurgula veya Yinelenenleri İşaretle  |  Boş Satırları Sil  |  Veri Kaybetmeden Sütunları Birleştir veya Hücreleri  |  Formül kullanmadan yuvarlama…
Süper VLookup:Birden Fazla Kriter  |  Birden Fazla Değer  |  Çoklu Sayfalar Arasında  |  Bulanık Eşleme…
Gelişmiş Açılır Liste:Kolay Açılır Liste  |  Bağımlı Açılır Liste  |  Çoklu Seçimli Açılır Liste…
Sütun Yöneticisi:Belirli Sayıda Sütun Ekle  |  Sütunları Taşı  |  Gizli Sütunların Görünürlük Durumunu Aç/Kapat  |Sütunları Karşılaştırarak Aynı/Farklı Hücreleri Seç…
Öne Çıkan Özellikler:Izgara Odaklama  |  Tasarım Görünümü  |  Gelişmiş formül çubuğu  |  Çalışma Kitabı ve Sayfa Yöneticisi|Kaynaklar(Otomatik Metin)|  Tarih Seçici  |  Çalışma Sayfalarını Birleştir  |  Şifrele/Hücreleri Şifre Çöz  |  Listeye Göre E-posta Gönder  |  Süper Filtre  |  Özel Filtre(Kalın Yazılı Hücreleri Filtrele/italik/üstü çizili…) …
15 Araç Setlerinin En İyileri:12 MetinAraçları(Metin Ekle,Belirli Karakterleri Sil…)|  50+GrafikTürleri(Gantt Grafiği…)|  40+ Pratik Formüller(Doğum tarihine dayanarak yaş hesapla…)|  19 EklemeAraçları(QR Kodu Ekle,Yoldan Resim Ekle…)|  12 DönüştürmeAraçları(Kelimeye Dönüştür,Döviz Kuru Dönüşümü…)|  7 Birleştir ve AyırAraçları(Gelişmiş Satırları Birleştir,Excel Hücrelerini Böl…)|… ve daha fazlası
Kutools’u tercih ettiğiniz dilde kullanın – İngilizce, İspanyolca, Almanca, Fransızca, Çince ve 40+ diğer dilleri destekler!

Kutools for Excel 300’den fazla özelliğe sahiptir,İhtiyacınız olan şeyin her zaman bir tıklama uzaklığında olmasını sağlar…

Office Tab - Microsoft Office’te (Excel dahil) Sekmeli Okuma ve Düzenlemeyi Etkinleştirir

  • Onlarca açık belge arasında geçiş yapmak için sadece bir saniye!
  • Her gün sizin için yüzlerce fare tıklamasını ortadan kaldırır; fareye elveda deyin.
  • Birden fazla belgeyi görüntüleyip düzenlerken verimliliğinizi %50 artırır.
  • Chrome, Edge ve Firefox gibi tarayıcılarda olduğu gibi, Office’e (Excel dahil) verimli sekmeler getirir.