Skip to main content

Bugün Kutools for Outlook'un yeni, ücretsiz versiyonunu keşfedin!

Hücreler x veya y içeriyorsa veya eşitse Excel'de toplama yapın

Author: Siluvia Last Modified: 2025-06-10

Hücreleri, bir değere ya da diğerine eşit veya içeren durumlarda toplamak için, bu öğretici sorunları çözmeye yardımcı olmak üzere iki formül sunmaktadır.

Excel'de hücreler x veya y içeriyorsa nasıl toplanır?
Excel'de hücreler x veya y'ye eşitse nasıl toplanır?

Excel'de hücreler x veya y içeriyorsa nasıl toplanır?

Aşağıdaki ekran görüntüsünde gösterildiği gibi, sütun C'deki hücreler "elma" veya "litchi" içeriyorsa sütun D'deki hücreleri toplamak için, SUMPRODUCT, ISNUMBER ve SEARCH işlevlerine dayalı bir formülü uygulayabilirsiniz.

doc-sum-if-cells-contain-either-x-or-y-1

Genel Formüller

=SUMPRODUCT(--((ISNUMBER(SEARCH("kriter1",rng1)) + ISNUMBER(SEARCH("kriter2",rng2)))>0),toplam_aralığı)

Argümanlar

Kriter_aralık1: Kriter1 tarafından değerlendirilmesini istediğiniz hücre aralığı;
Kriter_aralık2: Kriter2 tarafından değerlendirilmesini istediğiniz hücre aralığı;
Kriter1: Kriter_aralık1'deki hangi hücrelerin ekleneceğini tanımlamak için kullanılan kriter;
Kriter2: Kriter_aralık2'deki hangi hücrelerin ekleneceğini tanımlamak için kullanılan kriter.
Toplam_aralık: Toplanacak hücre aralığı;

Bu formülü nasıl kullanılır?

Boş bir hücre seçin, aşağıdaki formülü kopyalayın veya girin ve sonucu almak için Enter tuşuna basın.

=SUMPRODUCT(--((ISNUMBER(SEARCH(G4,C5:C12))+ISNUMBER(SEARCH(G5,C5:C12)))>0),D5:D12)

doc-sum-if-cells-contain-either-x-or-y-2

Notlar: Bu formülde G4 ve G5, iki koşulu içeren hücrelerdir. Alternatif olarak, çift tırnak içinde gerçek metin değerlerini doğrudan yazabilirsiniz.

=SUMPRODUCT(--((ISNUMBER(SEARCH("elma",C5:C12))+ISNUMBER(SEARCH("litchi",C5:C12)))>0),D5:D12)

Formülün açıklaması

=SUMPRODUCT(--((ISNUMBER(SEARCH("elma",C5:C12))+ISNUMBER(SEARCH("litchi",C5:C12)))>0),D5:D12)

ISNUMBER(SEARCH("elma",C5:C12))
> SEARCH("elma",C5:C12): SEARCH fonksiyonu, "elma"nın ilk karakterinin C5:C12 aralığındaki her hücredeki konumunu bulur ve şu şekilde bir dizi döndürür: {#DEĞER!;#DEĞER!;1;9;1;#DEĞER!;#DEĞER!;18}. #DEĞER!'ler, "elma"nın ilgili hücrede bulunmadığı anlamına gelir;
> ISNUMBER({#DEĞER!;#DEĞER!;1;9;1;#DEĞER!;#DEĞER!;18}): Burada ISNUMBER fonksiyonu, dizideki referans edilen değerin sayısal olup olmadığını kontrol eder. Eğer değer parametresi sayısal ise "TRUE", değilse "FALSE" döner. Sonuç olarak şu yeni dizi elde edilir: {FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;FALSE;TRUE}.
ISNUMBER(SEARCH("litchi",C5:C12)): Bu bölümün açıklaması yukarıdakiyle aynıdır. Burada ISNUMBER fonksiyonu şu şekilde bir dizi döndürür: {FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;TRUE};
{FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;FALSE;TRUE} + {FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;TRUE}: Ardından bu dizileri toplarız ve matematik işlemi TRUE ve FALSE değerlerini 1'ler ve 0'lara dönüştürür. Sonuç olarak şu sayı dizisini elde ederiz: {0;0;1;2;1;0;1;2};
({0;0;1;2;1;0;1;2}) > 0: Dizideki her sayı 0 ile karşılaştırılır ve şu şekilde bir TRUE ve FALSE dizisi döner: {FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;TRUE;TRUE};
--({FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;TRUE;TRUE}): Bu iki eksi işareti "TRUE"yu 1'e ve "FALSE"u 0'a dönüştürür. Burada şu yeni dizi elde edilir: {0;0;1;1;1;0;1;1};
SUMPRODUCT({0;0;1;1;1;0;1;1},D5:D12) = SUMPRODUCT({0;0;1;1;1;0;1;1},{2000;1600;980;1200;600;900;150;300}): SUMPRODUCT fonksiyonu iki dizinin karşılık gelen bileşenlerini çarpar ve {0;0;980;1200;600;0;150;300} şeklinde bir dizi döndürür, ardından dizideki tüm sonuçları toplar ve nihayetinde 3230'u döndürür.

Excel'de hücreler x veya y'ye eşitse nasıl toplanır?

Yukarıdaki bölümde, hücreleri bir değer veya başka bir değer içeriyorsa toplamak için formülü tanıttık. Bu bölümde, iki SUMIF fonksiyonunu bir araya getirerek hücreleri x veya y'ye eşit olduğunda toplamayı göstereceğiz.

Aşağıdaki örnek, ürün "elma" veya "litchi"ye eşitse satışları toplamaktadır.

doc-sum-if-cells-contain-either-x-or-y-3

Genel formül

=SUMIF(kriter_aralık1,"kriter1",toplam_aralık)+SUMIF(kriter_aralık2,"kriter2",toplam_aralık)

Argümanlar

Kriter_aralık1: Kriter1 tarafından değerlendirilmesini istediğiniz hücre aralığı;
Kriter_aralık2: Kriter2 tarafından değerlendirilmesini istediğiniz hücre aralığı;
Kriter1: Kriter_aralık1'deki hangi hücrelerin ekleneceğini tanımlayan kriter.
Kriter2: Kriter_aralık2'deki hangi hücrelerin ekleneceğini tanımlayan kriter.
Toplam_aralık: Toplanacak hücre aralığı;

Bu formülü nasıl kullanılır?

Boş bir hücre seçin, aşağıdaki formülü içine kopyalayın veya girin ve sonucu almak için Enter tuşuna basın.

=SUMIF(C5:C12,G4,D5:D12)+SUMIF(C5:C12,G5,D5:D12)

doc-sum-if-cells-contain-either-x-or-y-4

Not: Bu formül, iki koşulu içeren G4 ve G5 hücrelerine atıfta bulunur. Koşulları formüle çift tırnak içinde doğrudan metin değerleri olarak yazabilirsiniz.

=SUMIF(C5:C12,"elma",D5:D12)+SUMIF(C5:C12,"litchi",D5:D12)

Bu formülün açıklaması

=SUMIF(C5:C12,"elma",D5:D12)+SUMIF(C5:C12,"litchi",D5:D12)

İlk SUMIF fonksiyonu "elma" satışlarını toplar, ikinci SUMIF fonksiyonu "litchi" satışlarını toplar. Bu iki sonuç daha sonra toplanarak toplam satış miktarını verir.

İlgili fonksiyonlar

Excel SUMPRODUCT fonksiyonu
Excel SUMPRODUCT fonksiyonu, iki veya daha fazla sütunu veya diziyi birlikte çarpmak ve ardından ürünlerin toplamını almak için kullanılabilir.

Excel ISNUMBER fonksiyonu
Excel ISNUMBER fonksiyonu, bir hücre sayı içerdiğinde TRUE, içermiyorsa FALSE döndürür.

Excel SEARCH fonksiyonu
Excel SEARCH fonksiyonu, belirli bir karakterin veya alt dizenin verilen metin dizisindeki konumunu bulmanıza yardımcı olabilir.

Excel SUMIFS fonksiyonu
Excel SUMIF fonksiyonu, birden fazla kritere göre hücre değerlerini toplamanıza yardımcı olabilir.

İlgili formüller

Hücreler bir yıldız işareti içeriyorsa toplama
Bir yıldız işaretini joker karakter yerine gerçek bir karakter olarak kabul eden hücreleri toplamak için, bu öğretici SUMIF fonksiyonu ve tilde (~) işareti temelli bir formülü açıklamaktadır.

Hücreler hem x hem de y içeriyorsa toplama
Bu adım adım öğretici, SUMIFS fonksiyonunu kullanarak karşılık gelen hücreler hem x hem de y içeriyorsa bir hücre aralığını toplamayı göstermektedir.

Hücreler iki tarih arasında ise toplama
Bu öğretici, SUMIFS fonksiyonuna dayalı bir formül kullanarak Excel'de belirli bir tarih aralığındaki değerleri toplamayı göstermektedir.

Hücreler belirli bir değere eşit veya eşit değilse toplama
Bu adım adım öğretici, SUMIF fonksiyonuna dayalı olarak belirli bir değere eşit veya eşit olmayan bir hücre aralığını toplamak için iki formülü açıklamaktadır.

En İyi Ofis Üretkenlik Araçları

Kutools for Excel - Kalabalıktan Sıyrılmaya Yardımcı Olur

🤖 Kutools AI Asistanı: Akıllı Çalışma Yöntemine Dayalı Veri Analizini Devrimleştirin   |  Kod Oluştur  |  Özel Formüller Oluşturun  |  Verileri Analiz Edin ve Grafikler Oluşturun  |  Kutools İşlevlerini Çağırın…
Popüler Özellikler: Yinelenenleri Bul, Vurgula veya Belirle  |  Boş Satırları Sil  |  Veri Kaybı Olmadan Sütunları veya Hücreleri Birleştirin  |  Formül Kullanmadan Yuvarla ...
Süper VLookup: Çoklu Kriter  |  Çoklu Değer  |  Çoklu Sayfalar Arası  |  Bulanık Eşleme...
Gelişmiş Açılır Liste: Kolay Açılır Liste  |  Bağımlı Açılır Liste  |  Çoklu Seçimli Açılır Liste...
Sütun Yöneticisi: Belirli Sayıda Sütun Ekle  |  Sütunları Taşı  |  Gizli Sütunların Görünürlük Durumunu Değiştir  |  Sütunları Karşılaştırarak Aynı ve Farklı Hücreleri Seç ...
Öne Çıkan Özellikler: Izgara Odaklama  |  Tasarım Görünümü  |  Gelişmiş Formül Çubuğu  |  Çalışma Kitabı ve Sayfa Yöneticisi | Otomatik Metin Kütüphanesi (Kaynak Kütüphanesi)  |  Tarih Seçici  |  Çalışma Sayfalarını Birleştir  |  Hücreleri Şifrele/Şifresini Çöz  |  Listeye Göre E-posta Gönder  |  Süper Filtre  |  Özel Filtre (kalın/italik/üstü çizili hücreleri filtrele...) ...
En İyi 15 Araç Seti:  12 Metin Aracı (Metin Ekle, Belirli Karakterleri Sil ...)  |  50+ Grafik Türü (Gantt Grafiği ...)  |  40+ Pratik Formül (Doğum tarihine dayanarak yaş hesapla ...)  |  19 Ekleme Aracı (QR Kodu Ekle, Yoldan Resim Ekle ...)  |  12 Dönüştürme Aracı (Kelimeye Dönüştür, Para Birimi Dönüştürme ...)  |  7 Birleştirme ve Bölme Aracı (Gelişmiş Satırları Birleştir, Excel Hücrelerini Böl ...)  |  ... ve daha fazlası

Kutools for Excel, İhtiyacınız Olan Her Şeyin Tek Tıklama Uzağında Olduğundan Emin Olmak İçin 300'den Fazla Özelliğe Sahiptir...

Office Tab - Microsoft Office'de (Excel dahil) Sekmeli Okuma ve Düzenlemeyi Etkinleştir

  • Bir saniyede, onlarca açık belge arasında geçiş yapın!
  • Her gün yüzlerce fare tıklamasından kurtulun, fare eline veda edin.
  • Birden fazla belgeyi görüntülediğinizde ve düzenlediğinizde üretkenliğinizi %50 artırır.
  • Ofis'e (Excel dahil) Chrome, Edge ve Firefox gibi etkili sekmeler getirir.