Excel VLOOKUP Fonksiyonu

Excel'deki VLOOKUP işlevi, bir tablonun veya aralığın ilk sütununda dikey olarak belirtilen bir değeri aramanıza ve aynı satırdaki başka bir sütundan karşılık gelen değeri döndürmenize yardımcı olan güçlü bir araçtır. VLOOKUP son derece yararlı olsa da, bazen yeni başlayanlar için kavranması zor olabilir. Bu öğretici, VLOOKUP işlevini ustaca kullanmanızı hedefler ve size bağımsız değişkenlerin adım adım açıklaması, faydalı örnekler ve yaygın hatalara yönelik çözümler sunar.

• Bağımsız değişkenlerin adım adım açıklaması
• Sözdizimi ve bağımsız değişkenler
• VLOOKUP Örnekleri
  Tam eşleşme ile yaklaşık eşleşme|Çoklu koşullu VLOOKUP
• VLOOKUP Yaygın hatalar ve çözümleri
  #N/A hatası|#VALUE hatası|#REF hatası|Geçersiz değer

VLOOKUP örnekleri .xlsx VLOOKUP hataları .xlsx

İlgili Videolar

Bağımsız değişkenlerin adım adım açıklaması

Yukarıdaki ekran görüntüsünde gösterildiği gibi, VLOOKUP işlevi belirli bir kimlik numarasına karşılık gelen e-posta adresini bulmak için kullanılır. Şimdi bu örnekte VLOOKUP’un nasıl uygulandığını, her bağımsız değişkeni adım adım inceleyerek detaylı şekilde açıklayacağım.

Adım 1: VLOOKUP işlevini başlatın

Sonucun görüntüleneceği bir hücreyi seçin (bu örnekte H6), ardından Formül Çubuğu’na aşağıdaki içeriği yazarak VLOOKUP işlevini başlatın.

=VLOOKUP(

Adım 2: Arama değerini belirtin

Önce VLOOKUP işlevinde arama değerini belirtin (yani neyi aradığınızı). Burada, 1005 kimlik numarasını içeren G6 hücresine başvuruyorum.

=VLOOKUP(G6

Adım 3: Tablo dizisini belirtin

Ardından, aradığınız değeri ve döndürmek istediğiniz değeri içeren hücre aralığını belirtin. Bu örnekte B6:E12 aralığını seçiyorum. Formül şu şekilde görünüyor:

=VLOOKUP(G6,B6:E12

=VLOOKUP(G6,$B$6:$E$12

Adım 4: Değer döndürmek istediğiniz sütunu belirtin

Ardından, değer döndürmek istediğiniz sütunu belirtin.

Bu örnekte, bir kimlik numarasına göre e-postayı döndürmem gerektiğinden, VLOOKUP fonksiyonuna veri aralığı içindeki dördüncü sütundan değer almasını sağlamak için 4 sayısını giriyorum.

=VLOOKUP(G6,B6:E12,4

Adım 5: Yaklaşık eşleşme mi yoksa tam eşleşme mi arayacağınızı belirleyin

Son olarak, yaklaşık eşleşme mi yoksa tam eşleşme mi istediğinizi belirleyin.

• Bir tam eşleşme bulmak için son bağımsız değişken olarak YANLIŞ kullanmanız gerekir.
• Bir yaklaşık eşleşme bulmak için, son bağımsız değişken olarak DOĞRU kullanın veya boş bırakın.

Bu örnekte, tam eşleşme için FALSE kullanıyorum, formül şu hâle gelir:

=VLOOKUP(G6,B6:E12,4,FALSE

Sonucu almak için Enter tuşuna basın

Yukarıdaki örnekte her bağımsız değişken tek tek açıklandığı için VLOOKUP işlevinin söz dizimi ve bağımsız değişkenleri artık çok daha kolay anlaşılır hale geldi.

Sözdizimi ve bağımsız değişkenler

=VLOOKUP (lookup_value, table_array, col_index, [range_lookup])

• Arama_değeri (zorunlu): Aradığınız değer (gerçek bir değer veya bir hücre başvurusu). Bu değerin, tablo_dizisi'nin ilk sütununda yer alması gerektiğini unutmayın.
• Tablo_dizisi (zorunlu): Arama değeri sütununu ve Dönüş değeri sütununu içeren hücre aralığı.
• Sütun_indeksi (zorunlu): Dönüş değerini içeren sütunun numarasını belirten bir tam sayıdır. En soldaki sütun, Tablo_dizisi'nde 1 olarak başlar.
• Aralık_araması(isteğe bağlı): VLOOKUP işlevinin yaklaşık eşleşme mi yoksa tam eşleşme mi bulmasını istediğinizi belirleyen mantıksal bir değer.
  • Yaklaşık eşleşme – Bu bağımsız değişkeni DOĞRU, 1 olarak ayarlayın ya da boş bırakın.
    Önemli: Yaklaşık eşleşme bulmak için tablo_dizisi’nin ilk sütunundaki değerlerin artan sırada sıralı olması gerekir, aksi takdirde DÜŞEYARA yanlış sonuç döndürebilir.
  • Tam eşleşme – Bu bağımsız değişkeni YANLIŞ veya 0 olarak ayarlayın.

Örnekler

Bu bölüm, VLOOKUP işlevini daha kapsamlı bir şekilde anlamanıza yardımcı olacak bazı örnekler sunar.

Örnek 1: VLOOKUP’ta tam eşleşme ile yaklaşık eşleşme karşılaştırması

VLOOKUP kullanırken tam eşleşme ve yaklaşık eşleşme konusunda kafanız karışıyorsa, bu bölüm bu karışıklığı gidermenize yardımcı olabilir.

VLOOKUP’ta Tam Eşleşme

Bu örnekte, E6:E8 aralığında listelenen puanlara karşılık gelen isimleri bulacağım. Bu nedenle F6 hücresine aşağıdaki formülü girip otomatik doldurma tutamacını F8’e kadar aşağı çekiyorum. Formülde, son bağımsız değişkenin tam eşleşme araması yapması için FALSE olarak belirtilmiştir.

=VLOOKUP(E6,$B$6:$C$12,2,FALSE)

Ancak 98 puanı Veri Aralığı tablosunun ilk sütununda bulunmadığı için VLOOKUP #N/A hata sonucunu döndürür.

VLOOKUP’ta Yaklaşık Eşleşme

Yukarıdaki örneği kullanmaya devam ederek, son bağımsız değişkeni TRUE olarak değiştirirseniz, VLOOKUP yaklaşık eşleşme araması yapar. Eşleşme bulunamazsa, arama değerinden küçük olan en büyük değeri tespit eder ve karşılık gelen sonucu döndürür.

=VLOOKUP(E6,$B$6:$C$12,2,TRUE)

98 puanı bulunmadığı için VLOOKUP, 98’den küçük olan en büyük değeri —yani 95’i— bulur ve bu puanın karşılık geldiği ismi en yakın sonuç olarak döndürür.

Örnek 2: VLOOKUP’u birden fazla ölçütle kullanma

Bu bölüm, Excel’de VLOOKUP’u birden fazla koşulla nasıl kullanacağınızı gösterir. Aşağıdaki ekran görüntüsünde gösterildiği gibi, sağlanan bir isme (H5 hücresinde) ve departmana (H6 hücresinde) göre maaşı bulmaya çalışıyorsanız, bunu gerçekleştirmek için aşağıdaki adımları izleyin.

Adım 1: Arama sütunlarındaki değerleri birleştirmek için yardımcı bir sütun ekleyin

Bu durumda, İsim sütunu ile Departman sütunundaki değerleri birleştirmek için bir yardımcı sütun oluşturmanız gerekir.

1. Veri Aralığı'nizin soluna bir yardımcı sütun ekleyin ve bu sütuna bir başlık verin. Ekran görüntüsüne bakın:
   
   
2. Bu yardımcı sütunda, başlığın hemen altındaki ilk hücreyi seçin, aşağıdaki formülü Formül Çubuğu'na girin ve Enter tuşuna basın.
   

   =C6&," "&,D6

   
   Notlar: Bu formülde, iki sütundaki metni birleştirip tek bir metin parçası oluşturmak için "ve işareti" (&,) kullanıyoruz.

   • C6, birleştirilecek Ad sütununun ilk adıdır, D6 ise birleştirilecek Departman sütununun ilk departmanıdır.
   • Bu iki hücrenin değerleri, aralarında bir boşluk olacak şekilde birleştirilir.
3. Bu sonuç hücresini seçin, ardından formülü aynı sütundaki diğer hücrelere uygulamak için Otomatik Doldurma Sapını aşağı doğru sürükleyin.
   
   

Adım 2: Belirtilen ölçütlerle VLOOKUP işlevini uygulayın

Sonucun görüntüleneceği bir hücreyi seçin (ben I7’yi seçtim), ardından Formül Çubuğuna aşağıdaki formülü girip Enter tuşuna basın.

=VLOOKUP(I5&, " "&,I6,B6:F12,5,FALSE)

Sonuç

Yaygın VLOOKUP hataları ve çözümleri

Bu bölüm, VLOOKUP kullanırken karşılaşabileceğiniz yaygın hataları sıralar ve bu sorunları çözmek için etkili çözümler sunar.

#N/A hatası dönüyor

VLOOKUP ile karşılaşılan en yaygın hata #N/A hatasıdır, bu hata, Excel’in aradığınız değeri bulamadığını gösterir. VLOOKUP’un #N/A hatası döndürmesinin bazı nedenleri şunlardır.

Neden 1: Arama değeri, tablo_dizisi’nin ilk sütununda değil

Excel’de VLOOKUP fonksiyonunun temel sınırlamalarından biri, yalnızca soldan sağa doğru arama yapmanıza izin vermesidir. Bu yüzden arama değerinizin bulunduğu aralık, tablo_dizisi’nin ilk sütununda yer almalıdır.

Aşağıdaki ekran görüntüsünde gösterildiği gibi, belirtilen İş Ünvanı’na göre bir isim döndürmek istiyorum. Ancak arama değeri ()satış müdürü) Tablo_dizisi’nin ikinci sütununda yer aldığı ve dönüş değeri arama sütununun solunda olduğundan, VLOOKUP işlevi #N/A hatası veriyor.

Çözümler

Bu hatayı düzeltmek için aşağıdaki çözümlerden herhangi birini uygulayabilirsiniz.

• Sütunları yeniden düzenleyin
  
  Tablo_dizisi içinde arama sütununu ilk sütuna taşımak için sütunları yeniden düzenleyebilirsiniz.
• INDEX ve MATCH işlevlerini birlikte kullanın
  
  Bu sorunu çözmek için VLOOKUP alternatifi olarak burada INDEX ve MATCH işlevlerini birlikte kullanıyoruz.

  =INDEX(B6:B12,MATCH(F6,C6:C12,0))

  
• XLOOKUP işlevini kullanın (Excel 365, Excel 2021 ve sonraki sürümlerde mevcuttur)
  

  =XLOOKUP(F6,C6:C12,B6:B12)

Neden 2: The lookup value is not found in the lookup column (exact match)

VLOOKUP’un #N/A hatası döndürmesinin en yaygın nedenlerinden biri, aradığınız değerin bulunamamasıdır.

Aşağıdaki örnekte görüldüğü gibi, E6’daki 98 puanına göre ismi bulmaya çalışıyoruz. Ancak bu puan Veri Aralığı tablosunun ilk sütununda bulunmadığı için VLOOKUP #N/A hata sonucunu döndürür.

Çözümler

Bu hatayı düzeltmek için aşağıdaki çözümlerden birini deneyebilirsiniz.

• VLOOKUP’un arama değerinden küçük olan en büyük değeri bulmasını istiyorsanız, son bağımsız değişkeni YANLIŞ (tam eşleşme) yerine DOĞRU (yaklaşık eşleşme) olarak ayarlayın. Daha fazla bilgi için bkz. Örnek 1: VLOOKUP ile tam eşleşme ve yaklaşık eşleşme karşılaştırması.
• Son bağımsız değişkeni değiştirmemek ve arama değeri bulunamadığında bir uyarı almak için VLOOKUP işlevini IFERROR işlevi içine alın:
  

  =IFERROR(VLOOKUP(E8,$B$6:$C$12,2,FALSE),"Not found")

Neden 3: The lookup value is smaller than the smallest value in the lookup column (approximate match)

Aşağıdaki ekran görüntüsünde gösterildiği gibi, yaklaşık eşleşme araması yapıyorsunuz. Aradığınız değer (bu örnekte 1001 kimlik numarası), arama sütunundaki en küçük değer olan 1002’den daha küçük olduğundan VLOOKUP #N/A hatası döndürür.

Çözümler

Size iki çözüm sunuyoruz.

• Arama değeri, arama sütunundaki en küçük değerden büyük veya ona eşit olduğundan emin olun.
• Excel'in arama değerinin bulunamadığını size hatırlatmasını istiyorsanız, aşağıdaki gibi VLOOKUP işlevini IFERROR işlevi içine alın:
  

  =IFERROR(VLOOKUP(G6,B6:E12,4,TRUE),"Not found")

Neden 4: Sayılar metin olarak biçimlendirilmiş

Aşağıdaki ekran görüntüsünde görüldüğü gibi, bu örnekteki #N/A hata sonucu, arama hücresi (G6) ile orijinal tablonun and the lookup column (B6:B12) arasındaki veri türü uyumsuzluğundan kaynaklanmaktadır. Burada G6’daki değer bir sayı iken, B6:B12 aralığındaki değerler metin olarak biçimlendirilmiş sayılardır.

Çözümler

Bu sorunu çözmek için arama değerini tekrar sayıya dönüştürmeniz gerekir. Size iki yöntem sunuyoruz.

• Sayıya Dönüştür özelliğini uygulayın
  
  Dönüştürmek istediğiniz hücreye tıklayın, hücrenin yanındaki bu düğmeyi seçin ve ardından Sayıya Dönüştür'ü seçin.
  
• Toplu Metin ile Sayılar Arasındaki Dönüşüm yapmak için kullanışlı bir araç uygulayın
  
  Metin ile Sayılar Arasındaki Dönüşümözelliği,Kutools for Excelsayesinde bir hücre aralığını Metinden Sayıya arasında kolayca dönüştürmenize yardımcı olur.Şimdi 30 günlük tam özellikli ücretsiz denemeyi alın!

Neden 5: VLOOKUP formülünü diğer hücrelere sürüklerken tablo_dizisi sabitlenmemiş

Aşağıdaki ekran görüntüsünde gösterildiği gibi, E6 ve E7 hücrelerinde iki adet arama değeri aralığı bulunmaktadır. F6 hücresinde ilk sonuç alındıktan sonra VLOOKUP formülünü F6’dan F7’ye sürüklediğinizde #N/A hatası döndürüldü. Bunun nedeni, hücre başvurularının (B6:C12) varsayılan olarak göreli olması ve formülü aşağıya doğru kopyalarken bu başvuruların otomatik olarak satır satır kaydırılmasıdır. Böylece tablo dizisi B7:C13 konumuna kaymış ve artık 73 puanını içermemektedir.

Çözüm

Tablo dizisini sabit tutmak için hücre başvurularındaki satır ve sütunlardan önce $ işareti ekleyerek bunları kilitlemeniz gerekir. Excel’de mutlak başvuru hakkında daha fazla bilgi edinmek için şu öğreticiye göz atın: Excel mutlak başvurusu (nasıl yapılır ve kullanılır).

#VALUE hatası döndürülüyor

Aşağıdaki koşullar, VLOOKUP’un #VALUE hatası döndürmesine neden olabilir.

Neden 1: Arama değeri 255 karakteri aşmaktadır

Aşağıdaki ekran görüntüsünde görüldüğü gibi, H4 hücresindeki arama değeri 255 karakteri aştığı için VLOOKUP işlevi bir #DEĞER! hatası verir.

Çözümler

Bu sınırlamayı aşmak için daha uzun dizgileri işleyebilen alternatif bir arama fonksiyonu kullanabilirsiniz. Aşağıdaki formüllerden birini deneyin.

• INDEX ve MATCH:
  

  =INDEX(E5:E11, MATCH(TRUE, INDEX(B5:B11=H4, 0), 0))

  
• XLOOKUP işlevi(Excel 365, Excel 2021 ve sonraki sürümlerde mevcuttur):
  

  =XLOOKUP(H4,B5:B11,E5:E11)

Neden 2: col_index bağımsız değişkeni 1’den küçüktür

Sütun indeksi, döndürmek istediğiniz değeri içeren tablo dizisindeki sütun numarasını belirtir ve bu bağımsız değişken, tablo dizisinde geçerli bir sütuna karşılık gelen pozitif bir sayı olmalıdır.

Eğer sütun indeksi olarak 1’den küçük (yani sıfır veya negatif) bir değer girerseniz, VLOOKUP işlevi tablo dizisinde ilgili sütunu bulamaz.

Çözüm

Bu sorunu çözmek için VLOOKUP formülünüzdeki sütun indeksi bağımsız değişkeninin, tablo dizisinde geçerli bir sütuna karşılık gelen pozitif bir sayı olduğundan emin olun.

#REF hatası döndürülüyor

Bu bölüm, VLOOKUP’un #REF hatası vermesinin bir nedenini açıklar ve bu soruna yönelik çözümler sunar.

Neden: col_index bağımsız değişkeni sütun sayısından büyüktür

Aşağıdaki ekran görüntüsünde görüldüğü gibi, tablo dizisinin yalnızca 4 sütunu vardır. Ancak VLOOKUP formülünde belirttiğiniz sütun indeksi 5’dir ve bu, tablo dizisindeki sütun sayısından daha büyüktür. Sonuç olarak VLOOKUP ilgili sütunu bulamaz ve #REF hatası döndürür.

Çözümler

• Doğru sütun numarasını belirtin
  VLOOKUP formülünüzdeki sütun indeksi bağımsız değişkeninin, tablo dizisinde geçerli bir sütuna karşılık gelen bir sayı olduğundan emin olun.
• Belirtilen sütun başlığına göre sütun numarasını otomatik olarak alın
  VLOOKUP

  =VLOOKUP(G6,B6:E12,MATCH("Email",B5:E5,0),FALSE)

  Not: Yukarıdaki formülde, MATCH("Email",B5:E5,0) işlevi, arama alanınız olan B6:E12 aralığındaki "E-posta" sütununun sütun numarasını belirlemek için kullanılır. Bu örnekte sonuç 4’tür ve bu değer, VLOOKUP işlevinde sütun_indeksi_numarası olarak yer alır.

Yanlış değer döndürülüyor

VLOOKUP’un doğru sonucu döndürmediğini fark ederseniz, bunun aşağıdaki nedenlerden kaynaklanmış olabilir

Neden 1: Arama sütunu artan düzende sıralanmamıştır

Son bağımsız değişkeni yaklaşık eşleşme için DOĞRUolarak ayarladıysanız (veya)boş bıraktıysanız) ve arama sütunu artan düzende sıralanmamışsa, sonuç yanlış olabilir.

Çözüm

Bu sorunu çözmek için arama sütununu artan düzende sıralayın. Bunu yapmak için aşağıdaki adımları izleyin:

1. Arama sütunundaki veri hücrelerini seçin, Veri sekmesine gidin ve Sırala ve Filtrele grubunda yer alan En küçükten en büyüğe Sırala düğmesine tıklayın.
2. Sıralama Uyarısı iletişim kutusunda, Seçimi genişlet seçeneğini işaretleyin ve Tamam'a tıklayın.

Neden 2: Bir sütun eklendi veya kaldırıldı

Aşağıdaki ekran görüntüsünde gösterildiği gibi, başlangıçta döndürmek istediğim değer tablo dizisinin dördüncü sütunundaydı; bu yüzden col_index_num değerini 4 olarak belirttim. Yeni bir sütun eklendiğinde ise sonuç sütunu, tablo dizisinin beşinci sütunu haline geldi ve bu da VLOOKUP fonksiyonunun yanlış sütundan sonuç döndürmesine neden oldu.

Çözümler

Size iki çözüm sunuyoruz.

• Dönüş sütunu konumunu eşleştirmek için sütun indeksi numarasını manuel olarak değiştirebilirsiniz. Buradaki formül şu şekilde değiştirilmelidir:

  =VLOOKUP(H6,B6:F12,5,FALSE)

• Her zaman belirli bir sütundan sonuç döndürmek istiyorsanız, örneğin bu örnekte E-posta sütunu gibi. Aşağıdaki formül, tablo dizisine sütun eklenip çıkarılsa bile verilen sütun başlığına göre sütun indeksini otomatik olarak eşleştirmenize yardımcı olabilir.

  =VLOOKUP(H6,B6:F12,MATCH("Email",B5:E5,0),FALSE)

Diğer işlev notları

• VLOOKUP yalnızca soldan sağa değer arar.
  Arama değeri en soldaki sütunda yer almalı ve sonuç değeri, arama sütununun sağındaki herhangi bir sütunda olabilir.
• Son bağımsız değişkeni boş bırakırsanız, VLOOKUP varsayılan olarak yaklaşık eşleşmeyi kullanır.
• VLOOKUP büyük/küçük harfe duyarlı olmayan bir arama gerçekleştirir.
• Birden fazla eşleşme durumunda, VLOOKUP tablo dizisindeki satır sırasına göre yalnızca bulduğu ilk eşleşmeyi döndürür.

İlgili Makaleler