Excel'deki formüllerden hücre başvurularını nasıl çıkarabilirsiniz?

Diyelim ki uzun formülleriniz var ve şimdi aşağıdaki ekran görüntüsünde gösterildiği gibi bu formüllerden tüm hücre başvurularını çıkarmak istiyorsunuz. Formüllerden hücre başvurularını mümkün olduğunca hızlı bir şekilde nasıl çıkarabilirsiniz?

Kullanıcı Tanımlı Fonksiyon ile formüllerden hücre başvurularını çıkarma

Kullanıcı Tanımlı Fonksiyon ile formüllerden hücre başvurularını çıkarma

Formüllerden hücre başvurularını çıkarmak için aşağıdaki VBA kodu size yardımcı olabilir. Lütfen şu adımları izleyin:

1. Microsoft Visual Basic for Applications penceresini açmak için ALT + F11 tuşlarına basın.

2. Ekle Insert > Modül seçeneğine tıklayın ve aşağıdaki kodu Modül Penceresine yapıştırın.

VBA Kodu: Formüllerden hücre başvurularını çıkarma:

Function ExtractCellRefs(Rg As Range) As String
'Updateby Extendoffice
    Dim xRetList As Object
    Dim xRegEx As Object
    Dim I As Long
    Dim xRet As String
    Application.Volatile
    Set xRegEx = CreateObject("VBSCRIPT.REGEXP")
    With xRegEx
        .Pattern = "('?[a-zA-Z0-9\s\[\]\.]{1,99})?'?!?\$?[A-Z]{1,3}\$?[0-9]{1,7}(:\$?[A-Z]{1,3}\$?[0-9]{1,7})?"
        .Global = True
        .MultiLine = True
        .IgnoreCase = False
    End With
    Set xRetList = xRegEx.Execute(Rg.Formula)
    If xRetList.Count > 0 Then
        For I = 0 To xRetList.Count - 1
            xRet = xRet & xRetList.Item(I) & ", "
        Next
        ExtractCellRefs = Left(xRet, Len(xRet) - 2)
    Else
        ExtractCellRefs = "No Matches"
    End If
End Function

3. Kodu yapıştırdıktan sonra, kodu kaydedin ve çalışma sayfasına geri dönün, ardından şu formülü girin: =extractcellrefs(G2) (G2, hücre başvurularını çıkarmak istediğiniz formülü içeren hücredir) ve Sonuç almak istediğiniz hücreye yazdıktan sonra Enter tuşuna basın, formüldeki tüm hücre başvuruları çıkarılmış olacaktır, aşağıdaki ekran görüntüsüne bakınız: