Excel kullanarak Pdf dosyalarındaki sayfa sayısını nasıl sayarsınız?

Bir klasörde birden fazla PDF dosyanız varsa ve bunların dosya adlarını Excel'de sayfa sayılarıyla birlikte listelemeniz gerekiyorsa, bunu basit bir VBA makrosu ile kolayca yapabilirsiniz. Bu öğretici, size PDF dosya adlarını ve ilgili sayfa numaralarını bir Excel çalışma sayfasında hızlıca çıkarmak ve görüntülemek için gerekli adımları gösterecektir.

VBA ile Excel'de PDF dosya adlarını ve sayfa numaralarını görüntüleme

VBA ile Excel'de PDF dosya adlarını ve sayfa numaralarını görüntüleme

Aşağıdaki VBA kodu, tüm PDF dosya adlarını ve sayfa numaralarını bir çalışma sayfasında görüntülemenize yardımcı olabilir. Lütfen şu adımları izleyin:

1. Pdf dosyalarını ve sayfa numaralarını almak istediğiniz bir çalışma sayfasını açın.

2. "ALT" + "F11" tuşlarına basılı tutun, bu işlem "Microsoft Visual Basic for Applications" penceresini açar.

3. "Ekle" > "Modül" seçeneğine tıklayın ve aşağıdaki makroyu "Modül" Penceresine yapıştırın.

VBA kodu: Tüm Pdf dosya adlarını ve sayfa numaralarını çalışma sayfasında listeleme:

Sub Test()
    Dim I As Long
    Dim xRg As Range
    Dim xStr As String
    Dim xFd As FileDialog
    Dim xFdItem As Variant
    Dim xFileName As String
    Dim xFileNum As Long
    Dim RegExp As Object
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    If xFd.Show = -1 Then
        xFdItem = xFd.SelectedItems(1) & Application.PathSeparator
        xFileName = Dir(xFdItem & "*.pdf", vbDirectory)
        Set xRg = Range("A1")
        Range("A:B").ClearContents
        Range("A1:B1").Font.Bold = True
        xRg = "File Name"
        xRg.Offset(0, 1) = "Pages"
        I = 2
        xStr = ""
        Do While xFileName <> ""
            Cells(I, 1) = xFileName
            Set RegExp = CreateObject("VBscript.RegExp")
            RegExp.Global = True
            RegExp.Pattern = "/Type\s*/Page[^s]"
            xFileNum = FreeFile
            Open (xFdItem & xFileName) For Binary As #xFileNum
                xStr = Space(LOF(xFileNum))
                Get #xFileNum, , xStr
            Close #xFileNum
            Cells(I, 2) = RegExp.Execute(xStr).Count
            I = I + 1
            xFileName = Dir
        Loop
        Columns("A:B").AutoFit
    End If
End Sub

4. Kodu yapıştırdıktan sonra "F5" tuşuna basarak bu kodu çalıştırın, ardından bir "Gözat" penceresi açılacak, lütfen sayfa sayılarını listelemek istediğiniz Pdf dosyalarını içeren klasörü seçin, ekran görüntüsüne bakın:

5. Ardından, "Tamam" düğmesine tıklayın, tüm Pdf dosya adları ve sayfa numaraları geçerli çalışma sayfasına listelenir, ekran görüntüsüne bakın: