Outlook'ta klasör listesi nasıl alınır?

Bazı durumlarda, Gezinme bölmesindeki tüm posta klasörlerinin (kişisel olarak oluşturulanlar dahil) ağaç yapısı, Outlook kullanıcılarının iş akışını kolaylaştırabilir. Tüm bu yapıyı hızlıca listelemek için VBA kodundan yararlanabilirsiniz. Bu öğreticide, VBA koduyla klasör listesini nasıl kolayca alabileceğinizi öğreneceksiniz.

Outlook'ta VBA koduyla klasör listesi alın

---

Outlook'ta VBA koduyla klasör listesi alın

Outlook'ta VBA koduyla klasör listesi almak için aşağıdaki adımları izleyin.

1. "Microsoft Visual Basic for Applications" penceresini açmak için klavyeden "Alt" + "F11" tuşlarına basın.

2. Ardından "Project1" > "Microsoft Outlook Nesnesi" > "ThisOutlookSession" öğelerine çift tıklayarak "Project1 – ThisOutlookSession" penceresini açın. Ekran görüntüsüne göz atın:

3. Daha sonra aşağıdaki VBA kodunu "Project1 – ThisOutlookSession" penceresine kopyalayıp yapıştırın.

VBA: Outlook'ta klasör listesi alın

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. VBA kodunu çalıştırmak için klavyeden "F5" tuşuna basın.

5. Şimdi bir "Makro" iletişim kutusu açılacak; lütfen "Çalıştır" düğmesine tıklayarak işleme başlayın.

6. Makronun çalışmasını bekleyin. Ardından tüm e-posta klasörlerinizin listesi, yeni bir ileti penceresinde hemen karşınıza çıkar. Bu listeyi kolayca yazdırabilirsiniz. Ekran görüntüsüne göz atın:

Not: Bu VBA kodu, Outlook 2007, 2010 ve 2013 sürümlerinde kullanılabilir.