Outlook takviminde randevu konusunu nasıl arar ve değiştirirsiniz?

Author: Siluvia Last Modified: 2025-08-07

Outlook takviminde randevu konusunu bulup değiştirmek, bazı konuların toplu olarak aynı metinlerle değiştirilmesi gerektiğinde veya Outlook'ta veri içe aktarma işleminden sonra konu alanında Copy kelimesini değiştirmek istediğinizde yardımcı olur. Bu makale, birden fazla randevu konusunu aramak ve değiştirmek için size VBA kodu sağlar. Daha fazla ayrıntı için lütfen göz atın.

VBA kodu ile randevu konusunu arayın ve değiştirin

VBA kodu ile randevu konusunu arayın ve değiştirin

Bu bölümde, aşağıdaki gibi VBA kodu kullanarak randevu konusunu arayabilir ve değiştirebilirsiniz.

1. Öncelikle Outlook'unuzdaki makro ayarlarını düşük seviyeye getirmeniz gerekir.

1) Outlook 2010 ve 2013'te "Dosya" > "Seçenekler"'e tıklayın. "Outlook Seçenekleri" iletişim kutusunda, sol çubuktan "Güvenlik Merkezi"ni tıklayın, ardından "Güvenlik Merkezi Ayarları" düğmesine tıklayın.

"Güvenlik Merkezi" iletişim kutusunda, sol çubuktan "Makro Ayarları"na tıklayın, ardından "Makro Ayarları" bölümünde "Tüm makroları etkinleştir" seçeneğini işaretleyin ve "Tamam" düğmesine tıklayın. Ekran görüntüsüne bakın:

2) Outlook 2007'de lütfen "Araçlar" > "Güvenlik Merkezi"'ne tıklayın. "Güvenlik Merkezi" iletişim kutusunda, sol çubuktan "Makro Ayarları"na tıklayın, ardından "Makrolar için güvenlik kontrolü yapma" seçeneğini işaretleyin ve "Tamam" düğmesine tıklayın.

2. "Alt" + "F11" tuşlarına basarak "Microsoft Visual Basic for Applications" penceresini açın.

3. "Microsoft Visual Basic for Applications" penceresinde, "proje1" > "Microsoft Outlook Nesneleri" > "ThisOutlookSession" öğelerini genişletmek için çift tıklayın ve VBA düzenleyicisini açın. Ekran görüntüsüne bakın:

4. Aşağıdaki VBA kodunu VBA düzenleyicisine kopyalayıp yapıştırın. Ardından kodu çalıştırmak için "F5" tuşuna basın.

VBA: randevu konusunu bul ve değiştir

Sub FindReplaceAppointment()
    Dim oApp As Outlook.Application
    Dim oCalFolder As Outlook.MAPIFolder
    Dim oAppt As Outlook.AppointmentItem
    Dim sOldText As String
    Dim sNewText As String
    Dim iCalChangedCount As Integer
    Set oApp = Outlook.Application
    MsgBox ("This script will perform a find/replace in the subject line of all appointments in a specified calendar.")
    sOldText = InputBox("What is the text string that you would like to replace?")
    sNewText = InputBox("With what would you like to replace it?")
    ' Check to be sure a Calendar folder was selected
    Do
    If Not (oCalFolder Is Nothing) Then
        If (oCalFolder.DefaultItemType = olAppointmentItem) Then Exit Do
    End If
    MsgBox ("Please select a calendar folder from the following list.")
    Set oCalFolder = Application.Session.PickFolder
    On Error GoTo ErrHandler:
    Loop Until oCalFolder.DefaultItemType = olAppointmentItem
    ' Loop through appointments in calendar, change text where necessary, keep count
    iCalChangedCount = 0
    For Each oAppt In oCalFolder.Items
        If InStr(oAppt.Subject, sOldText) <> 0 Then
            Debug.Print "Changed: " & oAppt.Subject & " - " & oAppt.Start
            oAppt.Subject = Replace(oAppt.Subject, sOldText, sNewText)
            oAppt.Save
            iCalChangedCount = iCalChangedCount + 1
        End If
    Next
    ' Display results and clear table
    MsgBox (iCalChangedCount & " appointments had text in their subjects changed from '" & sOldText & "' to '" & sNewText & "'.")
    Set oAppt = Nothing
    Set oCalFolder = Nothing
Exit Sub
ErrHandler:
    MsgBox ("Macro terminated.")
End Sub

5. Kodu çalıştırdıktan sonra bir "Microsoft Outlook" iletişim kutusu açılır. "Tamam" düğmesine tıklayın.

6. İkinci "Microsoft Outlook" iletişim kutusunda, değiştirmek istediğiniz metni girin ve ardından "Tamam" düğmesine tıklayın.

7. Üçüncü "Microsoft Outlook" iletişim kutusunda, değiştirme olarak kullanmak istediğiniz metni girin ve "Tamam"'a tıklayın.

Not: Eğer belirli bir takvimdeki konulardan tüm "Copy" kelimelerini kaldırmak istiyorsanız, lütfen bu kutuyu boş bırakın.

8. Aşağıdaki iletişim kutusundaki "Tamam" düğmesine tıklayın.

9. "Klasör Seçin" iletişim kutusunda, belirli e-posta hesabınız altında takviminizi seçin ve ardından "Tamam" düğmesine tıklayın. Ekran görüntüsüne bakın: