Outlook’ta belirli günlerden daha eski olan okunmamış e-postaları otomatik olarak nasıl okundu olarak işaretleyebilirim?

Gelen Kutusu klasörünüzde birden fazla okunmamış e-posta varsa, normalde bunları “Tümünü Okundu Olarak İşaretle” özelliğini kullanarak manuel olarak okundu olarak işaretleyebilirsiniz. Peki ya her seferinde manuel işlem yapmadan, belirli bir gün sayısından daha eski olan okunmamış e-postaları Outlook’ta otomatik olarak okundu olarak işaretlemeyi denediniz mi?

Belirli günlerden daha eski okunmamış e-postaları VBA koduyla otomatik olarak okundu olarak işaretleme

---

Belirli günlerden daha eski okunmamış e-postaları VBA koduyla otomatik olarak okundu olarak işaretleme

Belirli günlerden daha eski tüm okunmamış e-postaları otomatik olarak okundu olarak işaretlemek için aşağıdaki VBA kodu size yardımcı olabilir:

1. Microsoft Visual Basic for Applications penceresini açmak için ALT + F11 tuşlarına basılı tutun.

2.Microsoft Visual Basic for Applicationspenceresinde, modu açmak için sol bölmedeki ThisOutlookSessionöğesine çift tıklayın ve ardından aşağıdaki kodu boş modüle kopyalayıp yapıştırın.Project1(VbaProject.OTM)

VBA kodu: Belirli günlerden daha eski okunmamış e-postaları otomatik olarak okundu olarak işaretleme:

Private Sub Application_Startup()
        Call MarkOldUnreadEmailsAsRead
    End Sub
    Private Sub MarkOldUnreadEmailsAsRead()
    Dim xInboxFld As Outlook.Folder
    Dim xAccount As Account
    On Error GoTo L1
    For Each xAccount In Outlook.Application.Session.Accounts
        Set xInboxFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderInbox)
        Call Processfolders(xInboxFld)
    Next xAccount
L1:     Exit Sub
    End Sub
    Private Sub Processfolders(ByVal InboxFld As Outlook.Folder)
    Dim xItems As Outlook.Items
    Dim i As Long
    Dim xSubFld As Outlook.Folder
    On Error Resume Next
    Set xItems = InboxFld.Items
    For i = 1 To xItems.Count
        If DateDiff("d", xItems(i).ReceivedTime, Now) >= 15 Then
           If xItems(i).UnRead = True Then
              xItems(i).UnRead = False
              xItems(i).Save
           End If
        End If
    Next
    If InboxFld.Folders.Count > 0 Then
       For Each xSubFld In InboxFld.Folders
           Call Processfolders(xSubFld)
       Next
    End If
End Sub

Not: Yukarıdaki kodda şu satırdaki gün sayısını kendi ihtiyacınıza göre değiştirebilirsiniz:If DateDiff("d", xItems(i).ReceivedTime, Now) >= 15Then

3. Ardından bu kod penceresini Kaydet ve Kapat. Bundan sonra, Outlook’u her başlattığınızda önceden tanımlanmış gün sayısından daha eski olan tüm okunmamış e-postalar otomatik olarak bir seferde Okundu olarak işaretlenecektir.

Not: Bu kod yalnızca varsayılan veri hesabınızda kullanılabilir.