Outlook'ta e-postalardan belirli türdeki ekler nasıl kaldırılır?

Outlook'ta dosya türüne göre birden çok seçilen e-postadaki ekleri kaldırmayı hiç denediniz mi? Örneğin, tüm docx veya png ek dosyalarını seçilen e-postalardan kaldırmak gibi. Outlook'ta bu işi nasıl çözebilirsiniz?

VBA kodu ile e-postalardan belirli türdeki ekleri kaldırın

VBA kodu ile e-postalardan belirli türdeki ekleri kaldırın

Seçili e-postalardan belirli türdeki ekleri kaldırmak için aşağıdaki VBA kodu size bir iyilik yapabilir, lütfen şunu yapın:

1. Posta listesinden belirli türdeki eklerini kaldırmak istediğiniz e-postaları seçin.

2. Basılı tutun ALT + F11 tuşlarını açmak için Uygulamalar için Microsoft Visual Basic pencere.

3. Daha sonra, Ekle > modül, aşağıdaki kodu kopyalayıp açılan boş modüle yapıştırın, ekran görüntüsüne bakın:

VBA kodu: Belirli türdeki ekleri e-postalardan kaldırın:

Sub DeleteSpecificTypeOfAttachments()
Dim xSelection As Outlook.Selection
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xAttachment As Outlook.Attachment
Dim xFileType As String
Dim xType As String
Dim xFSO As Scripting.FileSystemObject
Dim I As Integer
On Error Resume Next
Set xSelection = Outlook.Application.ActiveExplorer.Selection
Set xFSO = New Scripting.FileSystemObject
xType = ""
xType = InputBox("Attachment Type:", "Kutools for Outlook", xType, 8)
If Len(Trim(xType)) = 0 Then Exit Sub
For Each xItem In xSelection
    If xItem.Class = olMail Then
        Set xMailItem = xItem
       If xMailItem.Attachments.Count > 0 Then
            For I = xMailItem.Attachments.Count To 1 Step -1
                Set xAttachment = xMailItem.Attachments.Item(I)
                xFileType = xFSO.GetExtensionName(xAttachment.FileName)
                If InStr(xFileType, Trim(xType)) > 0 Then
                    xAttachment.Delete
                End If
            Next I
            xMailItem.Save
        End If
    End If
Next
Set xMailItem = Nothing
Set xFSO = Nothing
End Sub

4. Ve sonra hala Uygulamalar için Microsoft Visual Basic Pencere, tıklayın Tools > Referanslar gitmek için Referanslar-Proje1 iletişim kutusu ve kontrol edin Microsoft Komut Dosyası Çalışma Zamanı seçeneği Mevcut Referanslar liste kutusu, ekran görüntüsüne bakın:

doc türü 1'e göre eki kaldır

5. Sonra tıklayın OK diyaloğu kapatmak için şimdi F5 Bu kodu çalıştırmak için anahtar ve bir komut kutusu açılır, lütfen kaldırmak istediğiniz ek türünü girin, ekran görüntüsüne bakın:

doc türü 2'e göre eki kaldır