Outlook’ta Seç Ad listesi penceresinde faks numarasını nasıl gizleyebilirsiniz?

Outlook’ta “Ad Seç” listesinde veya Adres Defteri’nde E-posta Adresi sütununun yalnızca e-posta adreslerini değil, sizi rahatsız edebilecek faks kayıtlarını da içerdiğini fark etmiş olabilirsiniz. Bu makalede, faks numaranızın gizlenmesine yönelik bazı yöntemleri sizinle paylaşacağım.

Seç Ad listesi penceresinde faks numarasını VBA ile gizleme

---

Seç Ad listesi penceresinde faks numarasını VBA ile gizleme

Seç Ad listesi penceresinde mevcut faks numarasını gizlemek istiyorsanız, şu adımları izleyin:

1. Alt + F11 tuşlarına basarak Microsoft Visual Basic for Applications penceresini açın.

2. Ekle > Modül seçeneğine tıklayarak yeni bir boş modül ekleyin ve aşağıdaki kodu betiğe kopyalayıp yapıştırın.

VBA: Ad Seç penceresinde mevcut faks numarasını gizleme

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3. F5 tuşuna basarak kodu çalıştırın; artık faks numaraları gizlenmiş olacak.

Kişi içindeki faks numarasını gizlemek istiyorsanız, şu adımları izleyin:

1. Alt + F11tuşlarına basarak Microsoft Visual Basic for Applicationspenceresini açın.

2. ThisOutlookSession öğesine Proje-1 bölmesinden çift tıklayarak aşağıdaki kodu betiğe kopyalayıp yapıştırın.

VBA: Yeni Kişi Ekle penceresinde faks numarasını gizleme

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub

3. Kodu kaydedin ve değişikliklerin etkinleşmesi için Outlook'u yeniden başlatın.

Bundan sonra Ad Seç: Kişiler penceresinde yeni oluşturulan tüm kişilerin faks numaraları gizlenecektir.