Excel verilerinden randevu nasıl oluşturulur?

Diyelim ki aşağıdaki ekran görüntüsünde gösterildiği gibi Excel çalışma sayfanızda randevu verilerinizin yer aldığı bir tablonuz var ve bu verileri Outlook takviminize aktarmak istiyorsunuz. Bu işlemi hızlıca nasıl gerçekleştirebilirsiniz?

Excel verilerinden VBA koduyla randevu oluşturun

---

Excel verilerinden VBA koduyla randevu oluşturun

Excel verilerinden randevu oluşturmak için aşağıdaki VBA kodunu kullanabilirsiniz. Lütfen şu adımları izleyin:

1. Outlook’u başlatın ve ALT + F11 tuşlarına basarak Microsoft Visual Basic for Applications penceresini açın.

2. Ekle > Modül seçeneğine tıklayın ve aşağıdaki kodu Modül penceresine yapıştırın.

VBA kodu: Excel verilerini randevuya aktarma:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Hâlâ Microsoft Visual Basic for Applications penceresindeyken, Araçlar > Başvurular seçeneğine tıklayarak Başvurular - Project1 iletişim kutusuna gidin ve Microsoft Excel Nesne Kitaplığı seçeneğini Kullanılabilir Başvurular listesinden işaretleyin; ekran görüntüsüne bakın:

4. Ardından Tamam düğmesine tıklayın. Şimdi, bu kodu çalıştırmak için F5 tuşuna basın. Karşınıza Bir dosya seçin penceresi gelecektir; lütfen Outlook’a aktarmak istediğiniz Excel dosyasını seçin (aşağıdaki ekran görüntüsüne bakın):

5.Ardından Tamamseçeneğine tıklayın; aşağıdaki gibi bir uyarı kutusu açılacaktır:

6. Ardından Tamam düğmesine tıklayın; Excel verileri, aşağıdaki ekran görüntüsünde gösterildiği gibi takvime aktarılacaktır: