Outlook'ta Gönderilen Öğeler klasöründen bir iletiye normal şekilde nasıl yanıt verilir?

Normalde, daha önce gönderdiğiniz kişilere ek bir ileti göndermek için Gönderilen Öğeler klasöründen Yanıt özelliğine tıkladığınızda, kendi e-posta adresiniz aşağıdaki ekran görüntüsünde gösterildiği gibi Alıcı (To) alanına otomatik olarak eklenir. Bu durum, her seferinde adresi değiştirmek zorunda kalmanız nedeniyle can sıkıcı olabilir. Outlook’un kendi adresiniz yerine orijinal alıcının adresini kullanmasını nasıl sağlayabilirsiniz?

Outlook'tan Gönderilen Öğeler klasöründe Tümünü Yanıtla özelliğini kullanarak normal şekilde yanıtlayın

Outlook'tan Gönderilen Öğeler klasöründe VBA koduyla normal şekilde yanıtlayın

---

Outlook'tan Gönderilen Öğeler klasöründe Tümünü Yanıtla özelliğini kullanarak normal şekilde yanıtlayın

Outlook'ta bu sorunu çözmek için Tümünü Yanıtla özelliğini kullanabilirsiniz. Lütfen şu adımları izleyin:

Gönderilen e-postayı yeniden göndererek orijinal alıcının adresini korumanız gerektiğinde lütfen Tümünü Yanıtladüğmesine tıklayın; böylece orijinal alıcının adresi aşağıdaki ekran görüntüsünde gösterildiği gibi Alıcı (To)alanında görünecektir:

---

Outlook'tan Gönderilen Öğeler klasöründe VBA koduyla normal şekilde yanıtlayın

Bazen gönderdiğiniz bir iletiye yanıt verirken Tümünü Yanıtla özelliğini unutabilirsiniz. Bu durumda aşağıdaki VBA kodu, Gönderilen Öğeler klasöründen “Yanıt” özelliğini kullanarak mesajı normal şekilde yanıtlamanıza yardımcı olur. Şu adımları izleyin:

1. Microsoft Visual Basic for Applications penceresini açmak için ALT + F11 tuşlarına basılı tutun.

2. Microsoft Visual Basic for Applications penceresinde, modu açmak için Proje1 (VbaProject.OTM) bölmesinden ThisOutlookSession öğesine çift tıklayın ve ardından aşağıdaki kodu boş modüle kopyalayıp yapıştırın.

VBA kodu: Outlook'tan Gönderilen Öğeler klasöründen normal şekilde yanıtlayın:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Ardından kodu kaydedin ve değişikliklerin etkili olması için Outlook'u yeniden başlatın. Artık Yanıtla düğmesine tıklayarak Gönderilen Öğeler klasöründeki bir e-postayı yeniden gönderdiğinizde, orijinal alıcının adresi ihtiyaç duyduğunuz gibi Alıcı (To) alanında görüntülenecektir.