Outlook'ta e-postaya yanıt verirken veya iletirken kategoriyi nasıl koruyabilirim?

Normalde, kategorilendirilmiş bir e-postaya yanıt verdiğinizde veya onu ilettiğinizde, gönderilen e-postadan kategori otomatik olarak kaldırılır. Giden e-postalarda yanıtlama veya iletme sırasında kategoriyi korumak istiyorsanız, bu makale size bununla başa çıkmak için etkili bir yöntem sunar.

E-postaya yanıt verirken veya iletirken kategoriyi VBA koduyla koruma

---

E-postaya yanıt verirken veya iletirken kategoriyi VBA koduyla koruma

1. Microsoft Visual Basic for Applications penceresini açmak için ALT + F11 tuşlarına basılı tutun.

2. Microsoft Visual Basic for Applications penceresinde, modu açmak için ThisOutlookSession öğesine Project1 (VbaProject.OTM) bölmesinden çift tıklayın ve ardından aşağıdaki kodu boş modüle kopyalayıp yapıştırın.

VBA kodu: E-postaya yanıt verirken veya iletirken kategoriyi koruma:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Ardından bu kod penceresini Kaydet ve Kapat, Outlook'u kapatıp yeniden başlatın. Artık kategorili bir e-postaya yanıt verdiğinizde veya onu ilettiğinizde, kategori giden iletiye —Gönderilen Öğeler dahil— edilecektir; ekran görüntüsüne bakın: