Outlook’ta farklı türdeki Silinmiş Öğeleri otomatik olarak ayrı klasörlere nasıl taşıyabilirsiniz?

Outlook’ta silinen tüm öğeler (e-postalar, görevler, kişiler vb.) varsayılan olarak Silinmiş Öğeler klasörüne taşınır. Aşağıdaki ekran görüntüsünde gösterildiği gibi, bu öğeleri türlerine göre Silinmiş Öğeler klasörü altındaki farklı klasörlere nasıl taşıyabilirsiniz?

---

Farklı türdeki Silinmiş Öğeler öğelerini VBA koduyla otomatik olarak farklı klasörlere taşıyın

Aşağıdaki VBA kodu, Silinmiş Öğeler öğelerini otomatik olarak farklı klasörlere taşımanıza yardımcı olabilir; lütfen şu adımları izleyin:

1. Outlook'u başlatın ve ardından ALT + F11 tuşlarına basarak Microsoft Visual Basic for Applications penceresini açın.

2. Ardından, ThisOutlookSession öğesine Project-Project1 bölmesinden çift tıklayın ve aşağıdaki kodu boş kod penceresine kopyalayıp yapıştırın:

VBA kodu: Farklı türdeki Silinmiş Öğeler öğelerini otomatik olarak farklı klasörlere taşıma

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. Ardından bu kodu kaydedin ve etkinleştirmek için Outlook'u yeniden başlatın.

4. Bundan sonra bir öğeyi sildiğinizde, otomatik olarak Silinmiş Öğeler klasörünün altındaki ilgili türdeki klasöre taşınacaktır.

5. Sonucu görüntülemek için lütfen klasör bölmesinin alt kısmındaki simgesine tıklayın, ardından Klasörler seçeneğine tıklayarak bölmedeki "Tüm klasörleri genişlet" öğesine gidin; ekran görüntüleri aşağıda verilmiştir: