Outlook başlatıldığında “Tüm klasörleri genişlet” işlemi nasıl otomatik olarak gerçekleştirilir?

Genellikle Outlook’un Gezinme Bölümü’nde bir klasörü genişlettikten veya daralttıktan sonra programı kapatırsanız, Outlook’u bir sonraki açışınızda klasör aynı (genişletilmiş ya da daraltılmış) durumda kalır. Peki ya her seferinde Outlook’u başlattığınızda tüm klasörlerin otomatik olarak genişletilmesini ister misiniz? İşte bu makale, tam olarak bunu gerçekleştirmeniz için size pratik bir VBA çözümü sunuyor.

Outlook başlatıldığında VBA kullanarak Tüm klasörleri genişlet işlemini otomatik gerçekleştirme

---

Outlook başlatıldığında VBA kullanarak Tüm klasörleri genişlet işlemini otomatik gerçekleştirme

Bu kılavuz, Outlook’u her başlattığınızda Gezinme bölmesindeki “Tüm klasörleri genişlet” işlemini otomatik olarak gerçekleştirmek için bir VBA betiğinin nasıl kullanılacağını gösterir. VBA betiğini uygulamak için aşağıdaki adımları izleyin:

1. Alt + F11 tuşlarına aynı anda basarak Microsoft Visual Basic for Applications penceresini açın.
2. Proje 1ve Microsoft Outlook Nesneleribölmesinde genişletin,Projebölmesindeki ThisOutlookSessionpenceresini açmak için çift tıklayın ve ardından aşağıdaki VBA kodunu içine yapıştırın.

   

   VBA: Outlook'ta Tüm klasörleri genişlet otomatik olarak

   Public WithEvents GEx As Explorer
   Public GFlag As Boolean
   Private Sub Application_Startup()
     'Update by ExtendOffice 2023/12/08
     Set GEx = Application.ActiveExplorer
     GFlag = False
   End Sub
   
   Private Sub GEx_SelectionChange()
     If GFlag = False Then
       ExpandAllFolders
     End If
     GFlag = True
   End Sub
   
   Public Sub ExpandAllFolders()
     Dim xNameSpace As Outlook.NameSpace
     Dim xFlds As Outlook.Folders
     Dim xCurrFld As Outlook.MAPIFolder
     Dim xFld As Outlook.MAPIFolder
     Dim xExpandDefaultStoreOnly As Boolean
     Dim xModule As NavigationModule
     On Error Resume Next
     xExpandDefaultStoreOnly = False
     Set xNameSpace = Application.Session
     Set xModule = Application.ActiveExplorer.NavigationPane.CurrentModule
     Set xCurrFld = Application.ActiveExplorer.CurrentFolder
     If xExpandDefaultStoreOnly = True Then
       Set xFld = xNameSpace.GetDefaultFolder(olFolderInbox)
       Set xFld = xFld.Parent
       Set xFlds = xFld.Folders
       LoopFolders xFlds, True
     Else
       LoopFolders xNameSpace.Folders, True
       LoopFolders xNameSpace.Folders, False
     End If
     DoEvents
     Set Application.ActiveExplorer.NavigationPane.CurrentModule = xModule
     Set Application.ActiveExplorer.CurrentFolder = xCurrFld
     Set xNameSpace = Nothing
     Set xModule = Nothing
     Set xCurrFld = Nothing
   End Sub
   
   Private Sub LoopFolders(Flds As Outlook.Folders, ByVal All As Boolean)
     Dim xFld As Outlook.MAPIFolder
     On Error Resume Next
     For Each xFld In Flds
       Select Case All
         Case True
           If xFld.DefaultItemType = olMailItem Then
             Set Application.ActiveExplorer.CurrentFolder = xFld
             DoEvents
             If xFld.Folders.Count > 0 Then
               LoopFolders xFld.Folders, All
             End If
           End If
         Case False
           Set Application.ActiveExplorer.CurrentFolder = xFld
           DoEvents
           If xFld.Folders.Count > 0 Then
             LoopFolders xFld.Folders, All
           End If
       End Select
     Next
   End Sub

3. Kodu kaydedin ve Microsoft Visual Basic for Applications penceresini kapatın.

Artık Outlook yeniden başlatıldığında tüm klasörler otomatik olarak genişletilecek.

---

İlgili Makaleler