Outlook’ta bir takvimi birden fazla alıcıya bireysel olarak nasıl gönderirsiniz?

Normalde, Outlook’taki Takvimi E-postayla Gönder özelliğini kullanarak bir takvimi alıcıya hızlı ve kolayca gönderebilirsiniz. Ancak birden fazla kişiye iCalendar dosyası olarak eklenmiş bir takvimi bireysel olarak göndermek istiyorsanız, bunu tek tek yapmanız gerekir. Bu makalede, Outlook’ta bir takvimi birden fazla alıcıya bireysel olarak göndermenin pratik bir yolunu paylaşacağız.

VBA koduyla birden fazla alıcıya takvim gönderme

---

VBA koduyla birden fazla alıcıya takvim gönderme

Bir takvimi birden fazla alıcıya ayrı ayrı göndermek için aşağıdaki VBA kodu size yardımcı olabilir; lütfen şu adımları izleyin:

1. Kişiler bölmesine gidin ve takvim göndermek istediğiniz kişileri seçin.

2. Ardından, ALT + F11 tuşlarına basarak Microsoft Visual Basic for Applications penceresini açın.

3.Ekle>Modülseçeneğine tıklayın, ardından aşağıda verilen kodu açılan boş modüle kopyalayıp yapıştırın; ekran görüntüsüne bakın:

VBA kodu: Takvimi birden fazla alıcıya bireysel olarak gönderme：

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. Kodu ekledikten sonra, bu kodu çalıştırmak için F5 tuşuna basın; ardından bir Klasör Seç iletişim kutusu açılacaktır. Lütfen göndermek istediğiniz takvimi seçin—ekran görüntüsüne bakın:

5.Tamamdüğmesine tıklayın ve ardından takvimi göndermek istediğiniz Tarih Aralığı’yi aşağıdaki uyarı kutularında belirtin; ekran görüntüsüne bakın:

6. Ardından Tamam düğmesine tıklayın; takvim ekiyle birlikte oluşturulan e-postalar aşağıdaki ekran görüntüsünde gösterildiği gibidir. Artık onları tek tek göndermeniz yeterlidir.

---

İlgili Makaleler:

Outlook’ta birden fazla alıcıya bireysel olarak e-posta nasıl gönderilir?

Excel’den Outlook üzerinden bir listeye kişiselleştirilmiş toplu e-postalar nasıl gönderilir?

Outlook’ta birden fazla taslağı aynı anda nasıl gönderirsiniz?

Outlook’ta alıcıların farkında olmadan birden fazla kişiye e-posta nasıl gönderilir?